configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-libcilkrts \
 154                 target-liboffloadmic \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libmpx \
 161                 target-libssp \
 162                 target-libquadmath \
 163                 target-libgfortran \
 164                 target-boehm-gc \
 165                 target-libffi \
 166                 target-libobjc \
 167                 target-libada \
 168                 target-libgo"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 AC_ARG_ENABLE(as-accelerator-for,
 288 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 289                 [build as offload target compiler.
 290                 Specify offload host triple by ARG])])
 291
 292 AC_ARG_ENABLE(offload-targets,
 293 [AS_HELP_STRING([--enable-offload-targets=LIST],
 294                 [enable offloading to devices from comma-separated LIST of
 295                 TARGET[=DIR]. Use optional path to find offload target compiler
 296                 during the build])],
 297 [
 298   if test x"$enable_offload_targets" = x; then
 299     AC_MSG_ERROR([no offload targets specified])
 300   fi
 301 ], [enable_offload_targets=])
 302
 303 # Handle --enable-gold, --enable-ld.
 304 # --disable-gold [--enable-ld]
 305 #     Build only ld.  Default option.
 306 # --enable-gold [--enable-ld]
 307 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 308 #     as "ld.bfd" and "ld".
 309 # --enable-gold=default [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 311 #     install ld as "ld.bfd".
 312 # --enable-gold[=default] --disable-ld
 313 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 314 # --enable-gold --enable-ld=default
 315 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 316 #     and ld.bfd).
 317 #     In other words, ld is default
 318 # --enable-gold=default --enable-ld=default
 319 #     Error.
 320
 321 default_ld=
 322 AC_ARG_ENABLE(gold,
 323 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 324                 [build gold @<:@ARG={default,yes,no}@:>@])],
 325 ENABLE_GOLD=$enableval,
 326 ENABLE_GOLD=no)
 327 case "${ENABLE_GOLD}" in
 328   yes|default)
 329     # Check for ELF target.
 330     is_elf=no
 331     case "${target}" in
 332       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 333       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 334       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 335       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 336         case "${target}" in
 337           *-*-linux*aout* | *-*-linux*oldld*)
 338             ;;
 339           *)
 340             is_elf=yes
 341             ;;
 342         esac
 343     esac
 344
 345     if test "$is_elf" = "yes"; then
 346       # Check for target supported by gold.
 347       case "${target}" in
 348         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 349         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 350           configdirs="$configdirs gold"
 351           if test x${ENABLE_GOLD} = xdefault; then
 352             default_ld=gold
 353           fi
 354           ENABLE_GOLD=yes
 355           ;;
 356       esac
 357     fi
 358     ;;
 359   no)
 360     ;;
 361   *)
 362     AC_MSG_ERROR([invalid --enable-gold argument])
 363     ;;
 364 esac
 365
 366 AC_ARG_ENABLE(ld,
 367 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 368                 [build ld @<:@ARG={default,yes,no}@:>@])],
 369 ENABLE_LD=$enableval,
 370 ENABLE_LD=yes)
 371
 372 case "${ENABLE_LD}" in
 373   default)
 374     if test x${default_ld} != x; then
 375       AC_MSG_ERROR([either gold or ld can be the default ld])
 376     fi
 377     ;;
 378   yes)
 379     ;;
 380   no)
 381     if test x${ENABLE_GOLD} != xyes; then
 382       AC_MSG_WARN([neither ld nor gold are enabled])
 383     fi
 384     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 385     ;;
 386   *)
 387     AC_MSG_ERROR([invalid --enable-ld argument])
 388     ;;
 389 esac
 390
 391 # PR gas/19109
 392 # Decide the default method for compressing debug sections.
 393 # Provide a configure time option to override our default.
 394 AC_ARG_ENABLE(compressed_debug_sections,
 395 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 396                 [Enable compressed debug sections for gas, gold or ld by
 397                  default])],
 398 [
 399   if test x"$enable_compressed_debug_sections" = xyes; then
 400     AC_MSG_ERROR([no program with compressed debug sections specified])
 401   fi
 402 ], [enable_compressed_debug_sections=])
 403
 404 # Configure extra directories which are host specific
 405
 406 case "${host}" in
 407   *-cygwin*)
 408     configdirs="$configdirs libtermcap" ;;
 409 esac
 410
 411 # A target can indicate whether a language isn't supported for some reason.
 412 # Only spaces may be used in this macro; not newlines or tabs.
 413 unsupported_languages=
 414
 415 # Remove more programs from consideration, based on the host or
 416 # target this usually means that a port of the program doesn't
 417 # exist yet.
 418
 419 case "${host}" in
 420   i[[3456789]]86-*-msdosdjgpp*)
 421     noconfigdirs="$noconfigdirs tcl tk itcl"
 422     ;;
 423 esac
 424
 425
 426 AC_ARG_ENABLE(libquadmath,
 427 AS_HELP_STRING([--disable-libquadmath],
 428   [do not build libquadmath directory]),
 429 ENABLE_LIBQUADMATH=$enableval,
 430 ENABLE_LIBQUADMATH=yes)
 431 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 432   noconfigdirs="$noconfigdirs target-libquadmath"
 433 fi
 434
 435
 436 AC_ARG_ENABLE(libquadmath-support,
 437 AS_HELP_STRING([--disable-libquadmath-support],
 438   [disable libquadmath support for Fortran]),
 439 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 440 ENABLE_LIBQUADMATH_SUPPORT=yes)
 441 enable_libquadmath_support=
 442 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 443   enable_libquadmath_support=no
 444 fi
 445
 446
 447 AC_ARG_ENABLE(libada,
 448 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 449 ENABLE_LIBADA=$enableval,
 450 ENABLE_LIBADA=yes)
 451 if test "${ENABLE_LIBADA}" != "yes" ; then
 452   noconfigdirs="$noconfigdirs gnattools"
 453 fi
 454
 455 AC_ARG_ENABLE(libssp,
 456 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 457 ENABLE_LIBSSP=$enableval,
 458 ENABLE_LIBSSP=yes)
 459
 460 AC_ARG_ENABLE(libstdcxx,
 461 AS_HELP_STRING([--disable-libstdcxx],
 462   [do not build libstdc++-v3 directory]),
 463 ENABLE_LIBSTDCXX=$enableval,
 464 ENABLE_LIBSTDCXX=default)
 465 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 466   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 467 fi]
 468
 469 # If this is accelerator compiler and its target is intelmic we enable
 470 # target liboffloadmic by default.  If this is compiler with offloading
 471 # for intelmic we enable host liboffloadmic by default.  Otherwise
 472 # liboffloadmic is disabled by default.
 473 AC_ARG_ENABLE([liboffloadmic],
 474 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 475                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 476 [case "$enableval" in
 477   no | host | target)
 478     enable_liboffloadmic=$enableval ;;
 479   *)
 480     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 481 esac],
 482 [if test x"$enable_as_accelerator_for" != x; then
 483   case "${target}" in
 484     *-intelmic-* | *-intelmicemul-*)
 485       enable_liboffloadmic=target
 486       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 487       ;;
 488     *)
 489       enable_liboffloadmic=no
 490       ;;
 491   esac
 492 else
 493   case "${enable_offload_targets}" in
 494     *-intelmic-* | *-intelmicemul-*)
 495       enable_liboffloadmic=host
 496       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 497       ;;
 498     *)
 499       enable_liboffloadmic=no
 500       ;;
 501     esac
 502 fi])
 503 AC_SUBST(extra_liboffloadmic_configure_flags)
 504
 505 # Enable libgomp by default on hosted POSIX systems, and a few others.
 506 if test x$enable_libgomp = x ; then
 507     case "${target}" in
 508     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 509         ;;
 510     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 511         ;;
 512     *-*-solaris2* | *-*-hpux11*)
 513         ;;
 514     *-*-darwin* | *-*-aix*)
 515         ;;
 516     nvptx*-*-*)
 517         ;;
 518     *)
 519         noconfigdirs="$noconfigdirs target-libgomp"
 520         ;;
 521     esac
 522 fi
 523
 524 # Disable libatomic on unsupported systems.
 525 if test -d ${srcdir}/libatomic; then
 526     if test x$enable_libatomic = x; then
 527         AC_MSG_CHECKING([for libatomic support])
 528         if (srcdir=${srcdir}/libatomic; \
 529                 . ${srcdir}/configure.tgt; \
 530                 test -n "$UNSUPPORTED")
 531         then
 532             AC_MSG_RESULT([no])
 533             noconfigdirs="$noconfigdirs target-libatomic"
 534         else
 535             AC_MSG_RESULT([yes])
 536         fi
 537     fi
 538 fi
 539
 540 # Disable libcilkrts on unsupported systems.
 541 if test -d ${srcdir}/libcilkrts; then
 542     if test x$enable_libcilkrts = x; then
 543         AC_MSG_CHECKING([for libcilkrts support])
 544         if (srcdir=${srcdir}/libcilkrts; \
 545                 . ${srcdir}/configure.tgt; \
 546                 test -n "$UNSUPPORTED")
 547         then
 548             AC_MSG_RESULT([no])
 549             noconfigdirs="$noconfigdirs target-libcilkrts"
 550         else
 551             AC_MSG_RESULT([yes])
 552         fi
 553     fi
 554 fi
 555
 556 # Disable liboffloadmic on unsupported systems.
 557 if test -d ${srcdir}/liboffloadmic; then
 558     if test x$enable_liboffloadmic != xno; then
 559         AC_MSG_CHECKING([for liboffloadmic support])
 560         if (srcdir=${srcdir}/liboffloadmic; \
 561                 . ${srcdir}/configure.tgt; \
 562                 test -n "$UNSUPPORTED")
 563         then
 564             AC_MSG_RESULT([no])
 565             noconfigdirs="$noconfigdirs target-liboffloadmic"
 566         else
 567             AC_MSG_RESULT([yes])
 568         fi
 569     fi
 570 fi
 571
 572 # Disable libitm on unsupported systems.
 573 if test -d ${srcdir}/libitm; then
 574     if test x$enable_libitm = x; then
 575         AC_MSG_CHECKING([for libitm support])
 576         if (srcdir=${srcdir}/libitm; \
 577                 . ${srcdir}/configure.tgt; \
 578                 test -n "$UNSUPPORTED")
 579         then
 580             AC_MSG_RESULT([no])
 581             noconfigdirs="$noconfigdirs target-libitm"
 582         else
 583             AC_MSG_RESULT([yes])
 584         fi
 585     fi
 586 fi
 587
 588 # Disable libsanitizer on unsupported systems.
 589 if test -d ${srcdir}/libsanitizer; then
 590     if test x$enable_libsanitizer = x; then
 591         AC_MSG_CHECKING([for libsanitizer support])
 592         if (srcdir=${srcdir}/libsanitizer; \
 593                 . ${srcdir}/configure.tgt; \
 594                 test -n "$UNSUPPORTED")
 595         then
 596             AC_MSG_RESULT([no])
 597             noconfigdirs="$noconfigdirs target-libsanitizer"
 598         else
 599             AC_MSG_RESULT([yes])
 600         fi
 601     fi
 602 fi
 603
 604 # Disable libvtv on unsupported systems.
 605 if test -d ${srcdir}/libvtv; then
 606     if test x$enable_libvtv = x; then
 607         AC_MSG_CHECKING([for libvtv support])
 608         if (srcdir=${srcdir}/libvtv; \
 609                 . ${srcdir}/configure.tgt; \
 610                 test "$VTV_SUPPORTED" != "yes")
 611         then
 612             AC_MSG_RESULT([no])
 613             noconfigdirs="$noconfigdirs target-libvtv"
 614         else
 615             AC_MSG_RESULT([yes])
 616         fi
 617     fi
 618 fi
 619
 620
 621 # Enable libmpx on supported systems by request.
 622 if test -d ${srcdir}/libmpx; then
 623     if test x$enable_libmpx = x; then
 624        AC_MSG_CHECKING([for libmpx support])
 625        if (srcdir=${srcdir}/libmpx; \
 626                . ${srcdir}/configure.tgt; \
 627                test "$LIBMPX_SUPPORTED" != "yes")
 628        then
 629            AC_MSG_RESULT([no])
 630            noconfigdirs="$noconfigdirs target-libmpx"
 631        else
 632            AC_MSG_RESULT([yes])
 633        fi
 634     fi
 635 fi
 636
 637
 638
 639 # Disable libquadmath for some systems.
 640 case "${target}" in
 641   avr-*-*)
 642     noconfigdirs="$noconfigdirs target-libquadmath"
 643     ;;
 644   # libquadmath is unused on AIX and libquadmath build process use of
 645   # LD_LIBRARY_PATH can break AIX bootstrap.
 646   powerpc-*-aix* | rs6000-*-aix*)
 647     noconfigdirs="$noconfigdirs target-libquadmath"
 648     ;;
 649 esac
 650
 651 # Disable libssp for some systems.
 652 case "${target}" in
 653   avr-*-*)
 654     # No hosted I/O support.
 655     noconfigdirs="$noconfigdirs target-libssp"
 656     ;;
 657   powerpc-*-aix* | rs6000-*-aix*)
 658     noconfigdirs="$noconfigdirs target-libssp"
 659     ;;
 660   rl78-*-*)
 661     # libssp uses a misaligned load to trigger a fault, but the RL78
 662     # doesn't fault for those - instead, it gives a build-time error
 663     # for explicit misaligned loads.
 664     noconfigdirs="$noconfigdirs target-libssp"
 665     ;;
 666   visium-*-*)
 667     # No hosted I/O support.
 668     noconfigdirs="$noconfigdirs target-libssp"
 669     ;;
 670 esac
 671
 672 # Disable libstdc++-v3 for some systems.
 673 # Allow user to override this if they pass --enable-libstdc++-v3
 674 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 675   case "${target}" in
 676     *-*-vxworks*)
 677       # VxWorks uses the Dinkumware C++ library.
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680     arm*-wince-pe*)
 681       # the C++ libraries don't build on top of CE's C libraries
 682       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 683       ;;
 684     avr-*-*)
 685       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 686       ;;
 687     ft32-*-*)
 688       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 689       ;;
 690   esac
 691 fi
 692
 693 # Disable Fortran for some systems.
 694 case "${target}" in
 695   mmix-*-*)
 696     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 697     unsupported_languages="$unsupported_languages fortran"
 698     ;;
 699 esac
 700
 701 # Disable libffi for some systems.
 702 case "${target}" in
 703   powerpc-*-darwin*)
 704     ;;
 705   i[[3456789]]86-*-darwin*)
 706     ;;
 707   x86_64-*-darwin[[912]]*)
 708     ;;
 709   *-*-darwin*)
 710     noconfigdirs="$noconfigdirs target-libffi"
 711     ;;
 712   *-*-netware*)
 713     noconfigdirs="$noconfigdirs target-libffi"
 714     ;;
 715   *-*-phoenix*)
 716     noconfigdirs="$noconfigdirs target-libffi"
 717     ;;
 718   *-*-rtems*)
 719     noconfigdirs="$noconfigdirs target-libffi"
 720     ;;
 721   *-*-tpf*)
 722     noconfigdirs="$noconfigdirs target-libffi"
 723     ;;
 724   *-*-uclinux*)
 725     noconfigdirs="$noconfigdirs target-libffi"
 726     ;;
 727   *-*-vxworks*)
 728     noconfigdirs="$noconfigdirs target-libffi"
 729     ;;
 730   aarch64*-*-freebsd*)
 731     noconfigdirs="$noconfigdirs target-libffi"
 732     ;;
 733   alpha*-*-*vms*)
 734     noconfigdirs="$noconfigdirs target-libffi"
 735     ;;
 736   arm*-*-freebsd*)
 737     noconfigdirs="$noconfigdirs target-libffi"
 738     ;;
 739   arm-wince-pe)
 740     noconfigdirs="$noconfigdirs target-libffi"
 741     ;;
 742   arm*-*-symbianelf*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   cris-*-* | crisv32-*-*)
 746     case "${target}" in
 747       *-*-linux*)
 748         ;;
 749       *) # See PR46792 regarding target-libffi.
 750         noconfigdirs="$noconfigdirs target-libffi";;
 751     esac
 752     ;;
 753   hppa*64*-*-hpux*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   hppa*-hp-hpux11*)
 757     ;;
 758   hppa*-*-hpux*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   ia64*-*-*vms*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   i[[3456789]]86-w64-mingw*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   i[[3456789]]86-*-mingw*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770   x86_64-*-mingw*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   mmix-*-*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   powerpc-*-aix*)
 777     # copied from rs6000-*-* entry
 778     noconfigdirs="$noconfigdirs target-libffi"
 779     ;;
 780   rs6000-*-aix*)
 781     noconfigdirs="$noconfigdirs target-libffi"
 782     ;;
 783   ft32-*-*)
 784     noconfigdirs="$noconfigdirs target-libffi"
 785     ;;
 786   *-*-lynxos*)
 787     noconfigdirs="$noconfigdirs target-libffi"
 788     ;;
 789 esac
 790
 791 # Disable the go frontend on systems where it is known to not work. Please keep
 792 # this in sync with contrib/config-list.mk.
 793 case "${target}" in
 794 *-*-darwin* | *-*-cygwin* | *-*-mingw* | *-*-aix*)
 795     unsupported_languages="$unsupported_languages go"
 796     ;;
 797 esac
 798
 799 # Disable libgo for some systems where it is known to not work.
 800 # For testing, you can easily override this with --enable-libgo.
 801 if test x$enable_libgo = x; then
 802     case "${target}" in
 803     *-*-darwin*)
 804         # PR 46986
 805         noconfigdirs="$noconfigdirs target-libgo"
 806         ;;
 807     *-*-cygwin* | *-*-mingw*)
 808         noconfigdirs="$noconfigdirs target-libgo"
 809         ;;
 810     *-*-aix*)
 811         noconfigdirs="$noconfigdirs target-libgo"
 812         ;;
 813     esac
 814 fi
 815
 816 # Default libgloss CPU subdirectory.
 817 libgloss_dir="$target_cpu"
 818
 819 case "${target}" in
 820   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 821     libgloss_dir=wince
 822     ;;
 823   aarch64*-*-* )
 824     libgloss_dir=aarch64
 825     ;;
 826   arm*-*-*)
 827     libgloss_dir=arm
 828     ;;
 829   cris-*-* | crisv32-*-*)
 830     libgloss_dir=cris
 831     ;;
 832   hppa*-*-*)
 833     libgloss_dir=pa
 834     ;;
 835   i[[3456789]]86-*-*)
 836     libgloss_dir=i386
 837     ;;
 838   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 839     libgloss_dir=m68hc11
 840     ;;
 841   m68*-*-* | fido-*-*)
 842     libgloss_dir=m68k
 843     ;;
 844   mips*-*-*)
 845     libgloss_dir=mips
 846     ;;
 847   powerpc*-*-*)
 848     libgloss_dir=rs6000
 849     ;;
 850   sparc*-*-*)
 851     libgloss_dir=sparc
 852     ;;
 853 esac
 854
 855 # Disable newlib and libgloss for various target OSes.
 856 case "${target}" in
 857   alpha*-dec-osf*)
 858     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 859     ;;
 860   i[[3456789]]86-*-linux*)
 861     # This section makes it possible to build newlib natively on linux.
 862     # If we are using a cross compiler then don't configure newlib.
 863     if test x${is_cross_compiler} != xno ; then
 864       noconfigdirs="$noconfigdirs target-newlib"
 865     fi
 866     noconfigdirs="$noconfigdirs target-libgloss"
 867     # If we are not using a cross compiler, do configure newlib.
 868     # Note however, that newlib will only be configured in this situation
 869     # if the --with-newlib option has been given, because otherwise
 870     # 'target-newlib' will appear in skipdirs.
 871     ;;
 872   i[[3456789]]86-*-rdos*)
 873     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 874     ;;
 875   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 876     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 877     ;;
 878   sparc-*-sunos4*)
 879     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 880     ;;
 881   *-*-aix*)
 882     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 883     ;;
 884   *-*-beos*)
 885     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 886     ;;
 887   *-*-chorusos)
 888     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 889     ;;
 890   *-*-dragonfly*)
 891     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 892     ;;
 893   *-*-freebsd*)
 894     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 895     ;;
 896   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 897     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 898     ;;
 899   *-*-lynxos*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902   *-*-mingw*)
 903     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 904     ;;
 905   *-*-netbsd*)
 906     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 907     ;;
 908   *-*-netware*)
 909     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     ;;
 911   *-*-tpf*)
 912     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 913     ;;
 914   *-*-uclinux*)
 915     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 916     ;;
 917   *-*-vxworks*)
 918     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 919     ;;
 920 esac
 921
 922 case "${target}" in
 923   *-*-chorusos)
 924     ;;
 925   aarch64-*-darwin*)
 926     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 927     noconfigdirs="$noconfigdirs sim target-rda"
 928     ;;
 929   arm-*-darwin*)
 930     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 931     noconfigdirs="$noconfigdirs sim target-rda"
 932     ;;
 933   powerpc-*-darwin*)
 934     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 935     noconfigdirs="$noconfigdirs sim target-rda"
 936     ;;
 937   i[[3456789]]86-*-darwin*)
 938     noconfigdirs="$noconfigdirs ld gprof"
 939     noconfigdirs="$noconfigdirs sim target-rda"
 940     ;;
 941   x86_64-*-darwin[[912]]*)
 942     noconfigdirs="$noconfigdirs ld gas gprof"
 943     noconfigdirs="$noconfigdirs sim target-rda"
 944     ;;
 945   *-*-darwin*)
 946     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 947     noconfigdirs="$noconfigdirs sim target-rda"
 948     ;;
 949   *-*-dragonfly*)
 950     ;;
 951   *-*-freebsd*)
 952     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 953         && test -f /usr/local/include/gmp.h; then
 954       with_gmp=/usr/local
 955     fi
 956     ;;
 957   *-*-kaos*)
 958     # Remove unsupported stuff on all kaOS configurations.
 959     noconfigdirs="$noconfigdirs target-libgloss"
 960     ;;
 961   *-*-netbsd*)
 962     ;;
 963   *-*-netware*)
 964     ;;
 965   *-*-phoenix*)
 966     noconfigdirs="$noconfigdirs target-libgloss"
 967     ;;
 968   *-*-rtems*)
 969     noconfigdirs="$noconfigdirs target-libgloss"
 970     # this is not caught below because this stanza matches earlier
 971     case $target in
 972       or1k*-*-*) noconfigdirs="$noconfigdirs gdb" ;;
 973     esac
 974     ;;
 975     # The tpf target doesn't support gdb yet.
 976   *-*-tpf*)
 977     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 978     ;;
 979   *-*-uclinux*)
 980     noconfigdirs="$noconfigdirs target-rda"
 981     ;;
 982   *-*-vxworks*)
 983     ;;
 984   alpha*-dec-osf*)
 985     # ld works, but does not support shared libraries.
 986     # gas doesn't generate exception information.
 987     noconfigdirs="$noconfigdirs gas ld"
 988     ;;
 989   alpha*-*-*vms*)
 990     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 991     ;;
 992   alpha*-*-*)
 993     # newlib is not 64 bit ready
 994     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 995     ;;
 996   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 997     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 998     ;;
 999   arc*-*-*)
1000     noconfigdirs="$noconfigdirs sim"
1001     ;;
1002   arm-*-pe*)
1003     noconfigdirs="$noconfigdirs target-libgloss"
1004     ;;
1005   arm-*-riscix*)
1006     noconfigdirs="$noconfigdirs ld target-libgloss"
1007     ;;
1008   avr-*-*)
1009     if test x${with_avrlibc} != xno; then
1010       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1011     fi
1012     ;;
1013   c4x-*-* | tic4x-*-*)
1014     noconfigdirs="$noconfigdirs target-libgloss"
1015     ;;
1016   tic54x-*-*)
1017     noconfigdirs="$noconfigdirs target-libgloss gdb"
1018     ;;
1019   d10v-*-*)
1020     noconfigdirs="$noconfigdirs target-libgloss"
1021     ;;
1022   d30v-*-*)
1023     noconfigdirs="$noconfigdirs gdb"
1024     ;;
1025   fr30-*-elf*)
1026     noconfigdirs="$noconfigdirs gdb"
1027     ;;
1028   ft32-*-*)
1029     noconfigdirs="$noconfigdirs target-rda gprof"
1030     ;;
1031   moxie-*-*)
1032     noconfigdirs="$noconfigdirs"
1033     ;;
1034   h8300*-*-*)
1035     noconfigdirs="$noconfigdirs target-libgloss"
1036     ;;
1037   h8500-*-*)
1038     noconfigdirs="$noconfigdirs target-libgloss"
1039     ;;
1040   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1041     ;;
1042   hppa*64*-*-hpux*)
1043     noconfigdirs="$noconfigdirs gdb"
1044     ;;
1045   hppa*-*-hpux11*)
1046     noconfigdirs="$noconfigdirs gdb ld"
1047     ;;
1048   hppa*64*-*-linux*)
1049     ;;
1050   hppa*-*-linux*)
1051     ;;
1052   hppa*-*-*elf* | \
1053   hppa*-*-lites* | \
1054   hppa*-*-openbsd* | \
1055   hppa*64*-*-*)
1056     ;;
1057   hppa*-*-pro*)
1058     ;;
1059   hppa*-*-*)
1060     noconfigdirs="$noconfigdirs ld"
1061     ;;
1062   i960-*-*)
1063     noconfigdirs="$noconfigdirs gdb"
1064     ;;
1065   ia64*-*-elf*)
1066     # No gdb support yet.
1067     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1068     ;;
1069   ia64*-**-hpux*)
1070     # No ld support yet.
1071     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1072     ;;
1073   ia64*-*-*vms*)
1074     # No ld support yet.
1075     noconfigdirs="$noconfigdirs libgui itcl ld"
1076     ;;
1077   i[[3456789]]86-w64-mingw*)
1078     ;;
1079   i[[3456789]]86-*-mingw*)
1080     target_configdirs="$target_configdirs target-winsup"
1081     ;;
1082   *-*-cygwin*)
1083     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1084     noconfigdirs="$noconfigdirs target-libgloss"
1085     # always build newlib if winsup directory is present.
1086     if test -d "$srcdir/winsup/cygwin"; then
1087       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1088     elif test -d "$srcdir/newlib"; then
1089       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1090     fi
1091     ;;
1092   i[[3456789]]86-*-pe)
1093     noconfigdirs="$noconfigdirs target-libgloss"
1094     ;;
1095   i[[3456789]]86-*-sco3.2v5*)
1096     # The linker does not yet know about weak symbols in COFF,
1097     # and is not configured to handle mixed ELF and COFF.
1098     noconfigdirs="$noconfigdirs ld target-libgloss"
1099     ;;
1100   i[[3456789]]86-*-sco*)
1101     noconfigdirs="$noconfigdirs gprof target-libgloss"
1102     ;;
1103   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1104     noconfigdirs="$noconfigdirs target-libgloss"
1105     ;;
1106   i[[3456789]]86-*-sysv4*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   i[[3456789]]86-*-beos*)
1110     noconfigdirs="$noconfigdirs gdb"
1111     ;;
1112   i[[3456789]]86-*-rdos*)
1113     noconfigdirs="$noconfigdirs gdb"
1114     ;;
1115   mmix-*-*)
1116     noconfigdirs="$noconfigdirs gdb"
1117     ;;
1118   mt-*-*)
1119     noconfigdirs="$noconfigdirs sim"
1120     ;;
1121   powerpc-*-aix*)
1122     # copied from rs6000-*-* entry
1123     noconfigdirs="$noconfigdirs gprof"
1124     ;;
1125   powerpc*-*-winnt* | powerpc*-*-pe*)
1126     target_configdirs="$target_configdirs target-winsup"
1127     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1128     # always build newlib.
1129     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1130     ;;
1131     # This is temporary until we can link against shared libraries
1132   powerpcle-*-solaris*)
1133     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1134     ;;
1135   powerpc-*-beos*)
1136     noconfigdirs="$noconfigdirs gdb"
1137     ;;
1138   rs6000-*-lynxos*)
1139     noconfigdirs="$noconfigdirs gprof"
1140     ;;
1141   rs6000-*-aix*)
1142     noconfigdirs="$noconfigdirs gprof"
1143     ;;
1144   rs6000-*-*)
1145     noconfigdirs="$noconfigdirs gprof"
1146     ;;
1147   m68k-apollo-*)
1148     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1149     ;;
1150   microblaze*)
1151     noconfigdirs="$noconfigdirs gprof"
1152     ;;
1153   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1154     if test x$with_newlib = xyes; then
1155       noconfigdirs="$noconfigdirs gprof"
1156     fi
1157     ;;
1158   mips*-*-irix5*)
1159     noconfigdirs="$noconfigdirs gprof target-libgloss"
1160     ;;
1161   mips*-*-irix6*)
1162     noconfigdirs="$noconfigdirs gprof target-libgloss"
1163     ;;
1164   mips*-*-bsd*)
1165     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1166     ;;
1167   mips*-*-linux*)
1168     ;;
1169   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1170   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1171     noconfigdirs="$noconfigdirs ld gas gprof"
1172     ;;
1173   mips*-*-*)
1174     noconfigdirs="$noconfigdirs gprof"
1175     ;;
1176   nvptx*-*-*)
1177     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1178     ;;
1179   or1k*-*-*)
1180     noconfigdirs="$noconfigdirs gdb"
1181     ;;
1182   sh-*-*)
1183     case "${target}" in
1184       sh*-*-elf)
1185          ;;
1186       *)
1187          noconfigdirs="$noconfigdirs target-libgloss" ;;
1188     esac
1189     ;;
1190   sparc-*-sunos4*)
1191     if test x${is_cross_compiler} = xno ; then
1192            use_gnu_ld=no
1193     fi
1194     ;;
1195   tic6x-*-*)
1196     noconfigdirs="$noconfigdirs sim"
1197     ;;
1198   tilepro*-*-* | tilegx*-*-*)
1199     noconfigdirs="$noconfigdirs sim"
1200     ;;
1201   v810-*-*)
1202     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1203     ;;
1204   vax-*-*)
1205     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1206     ;;
1207 esac
1208
1209 # If we aren't building newlib, then don't build libgloss, since libgloss
1210 # depends upon some newlib header files.
1211 case "${noconfigdirs}" in
1212   *target-libgloss*) ;;
1213   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1214 esac
1215
1216 # Work in distributions that contain no compiler tools, like Autoconf.
1217 host_makefile_frag=/dev/null
1218 if test -d ${srcdir}/config ; then
1219 case "${host}" in
1220   i[[3456789]]86-*-msdosdjgpp*)
1221     host_makefile_frag="config/mh-djgpp"
1222     ;;
1223   *-cygwin*)
1224     ACX_CHECK_CYGWIN_CAT_WORKS
1225     host_makefile_frag="config/mh-cygwin"
1226     ;;
1227   *-mingw*)
1228     host_makefile_frag="config/mh-mingw"
1229     ;;
1230   alpha*-linux*)
1231     host_makefile_frag="config/mh-alpha-linux"
1232     ;;
1233   hppa*-hp-hpux10*)
1234     host_makefile_frag="config/mh-pa-hpux10"
1235     ;;
1236   hppa*-hp-hpux*)
1237     host_makefile_frag="config/mh-pa"
1238     ;;
1239   hppa*-*)
1240     host_makefile_frag="config/mh-pa"
1241     ;;
1242   *-*-darwin*)
1243     host_makefile_frag="config/mh-darwin"
1244     ;;
1245   powerpc-*-aix*)
1246     host_makefile_frag="config/mh-ppc-aix"
1247     ;;
1248   rs6000-*-aix*)
1249     host_makefile_frag="config/mh-ppc-aix"
1250     ;;
1251 esac
1252 fi
1253
1254 if test "${build}" != "${host}" ; then
1255   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1256   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1257   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1258   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1259   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1260   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1261   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1262   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1263   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1264   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1265   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1266   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1267   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1268 else
1269   AR_FOR_BUILD="\$(AR)"
1270   AS_FOR_BUILD="\$(AS)"
1271   CC_FOR_BUILD="\$(CC)"
1272   CXX_FOR_BUILD="\$(CXX)"
1273   GCJ_FOR_BUILD="\$(GCJ)"
1274   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1275   GOC_FOR_BUILD="\$(GOC)"
1276   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1277   LD_FOR_BUILD="\$(LD)"
1278   NM_FOR_BUILD="\$(NM)"
1279   RANLIB_FOR_BUILD="\$(RANLIB)"
1280   WINDRES_FOR_BUILD="\$(WINDRES)"
1281   WINDMC_FOR_BUILD="\$(WINDMC)"
1282 fi
1283
1284 AC_PROG_CC
1285 AC_PROG_CXX
1286
1287 # We must set the default linker to the linker used by gcc for the correct
1288 # operation of libtool.  If LD is not defined and we are using gcc, try to
1289 # set the LD default to the ld used by gcc.
1290 if test -z "$LD"; then
1291   if test "$GCC" = yes; then
1292     case $build in
1293     *-*-mingw*)
1294       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1295     *)
1296       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1297     esac
1298     case $gcc_prog_ld in
1299     # Accept absolute paths.
1300     [[\\/]* | [A-Za-z]:[\\/]*)]
1301       LD="$gcc_prog_ld" ;;
1302     esac
1303   fi
1304 fi
1305
1306 # Check whether -static-libstdc++ -static-libgcc is supported.
1307 have_static_libs=no
1308 if test "$GCC" = yes; then
1309   saved_LDFLAGS="$LDFLAGS"
1310
1311   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1312   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1313   AC_LANG_PUSH(C++)
1314   AC_LINK_IFELSE([
1315 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1316 #error -static-libstdc++ not implemented
1317 #endif
1318 int main() {}],
1319     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1320     [AC_MSG_RESULT([no])])
1321   AC_LANG_POP(C++)
1322
1323   LDFLAGS="$saved_LDFLAGS"
1324 fi
1325
1326 ACX_PROG_GNAT
1327 ACX_PROG_CMP_IGNORE_INITIAL
1328
1329 AC_ARG_ENABLE([bootstrap],
1330 [AS_HELP_STRING([--enable-bootstrap],
1331                 [enable bootstrapping @<:@yes if native build@:>@])],,
1332 enable_bootstrap=default)
1333
1334 # Issue errors and warnings for invalid/strange bootstrap combinations.
1335 if test -r $srcdir/gcc/configure; then
1336   have_compiler=yes
1337 else
1338   have_compiler=no
1339 fi
1340
1341 case "$have_compiler:$host:$target:$enable_bootstrap" in
1342   *:*:*:no) ;;
1343
1344   # Default behavior.  Enable bootstrap if we have a compiler
1345   # and we are in a native configuration.
1346   yes:$build:$build:default)
1347     enable_bootstrap=yes ;;
1348
1349   *:*:*:default)
1350     enable_bootstrap=no ;;
1351
1352   # We have a compiler and we are in a native configuration, bootstrap is ok
1353   yes:$build:$build:yes)
1354     ;;
1355
1356   # Other configurations, but we have a compiler.  Assume the user knows
1357   # what he's doing.
1358   yes:*:*:yes)
1359     AC_MSG_WARN([trying to bootstrap a cross compiler])
1360     ;;
1361
1362   # No compiler: if they passed --enable-bootstrap explicitly, fail
1363   no:*:*:yes)
1364     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1365
1366   # Fail if wrong command line
1367   *)
1368     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1369     ;;
1370 esac
1371
1372 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1373 # C++98 compiler can still start the bootstrap.
1374 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1375   CXX="$CXX -std=gnu++98"
1376 fi
1377
1378 # Used for setting $lt_cv_objdir
1379 _LT_CHECK_OBJDIR
1380
1381 # Check for GMP, MPFR and MPC
1382 gmplibs="-lmpc -lmpfr -lgmp"
1383 gmpinc=
1384 have_gmp=no
1385
1386 # Specify a location for mpc
1387 # check for this first so it ends up on the link line before mpfr.
1388 AC_ARG_WITH(mpc,
1389 [AS_HELP_STRING([--with-mpc=PATH],
1390                 [specify prefix directory for installed MPC package.
1391                  Equivalent to --with-mpc-include=PATH/include
1392                  plus --with-mpc-lib=PATH/lib])])
1393 AC_ARG_WITH(mpc-include,
1394 [AS_HELP_STRING([--with-mpc-include=PATH],
1395                 [specify directory for installed MPC include files])])
1396 AC_ARG_WITH(mpc-lib,
1397 [AS_HELP_STRING([--with-mpc-lib=PATH],
1398                 [specify directory for the installed MPC library])])
1399
1400 if test "x$with_mpc" != x; then
1401   gmplibs="-L$with_mpc/lib $gmplibs"
1402   gmpinc="-I$with_mpc/include $gmpinc"
1403 fi
1404 if test "x$with_mpc_include" != x; then
1405   gmpinc="-I$with_mpc_include $gmpinc"
1406 fi
1407 if test "x$with_mpc_lib" != x; then
1408   gmplibs="-L$with_mpc_lib $gmplibs"
1409 fi
1410 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1411   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1412   gmpinc='-I$$s/mpc/src '"$gmpinc"
1413   # Do not test the mpc version.  Assume that it is sufficient, since
1414   # it is in the source tree, and the library has not been built yet
1415   # but it would be included on the link line in the version check below
1416   # hence making the test fail.
1417   have_gmp=yes
1418 fi
1419
1420 # Specify a location for mpfr
1421 # check for this first so it ends up on the link line before gmp.
1422 AC_ARG_WITH(mpfr-dir,
1423 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1424 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1425 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1426
1427 AC_ARG_WITH(mpfr,
1428 [AS_HELP_STRING([--with-mpfr=PATH],
1429                 [specify prefix directory for installed MPFR package.
1430                  Equivalent to --with-mpfr-include=PATH/include
1431                  plus --with-mpfr-lib=PATH/lib])])
1432 AC_ARG_WITH(mpfr-include,
1433 [AS_HELP_STRING([--with-mpfr-include=PATH],
1434                 [specify directory for installed MPFR include files])])
1435 AC_ARG_WITH(mpfr-lib,
1436 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1437                 [specify directory for the installed MPFR library])])
1438
1439 if test "x$with_mpfr" != x; then
1440   gmplibs="-L$with_mpfr/lib $gmplibs"
1441   gmpinc="-I$with_mpfr/include $gmpinc"
1442 fi
1443 if test "x$with_mpfr_include" != x; then
1444   gmpinc="-I$with_mpfr_include $gmpinc"
1445 fi
1446 if test "x$with_mpfr_lib" != x; then
1447   gmplibs="-L$with_mpfr_lib $gmplibs"
1448 fi
1449 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1450   # MPFR v3.1.0 moved the sources into a src sub-directory.
1451   if ! test -d ${srcdir}/mpfr/src; then
1452     AC_MSG_ERROR([dnl
1453 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1454   fi
1455   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1456   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1457   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1458   # Do not test the mpfr version.  Assume that it is sufficient, since
1459   # it is in the source tree, and the library has not been built yet
1460   # but it would be included on the link line in the version check below
1461   # hence making the test fail.
1462   have_gmp=yes
1463 fi
1464
1465 # Specify a location for gmp
1466 AC_ARG_WITH(gmp-dir,
1467 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1468 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1469 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1470
1471 AC_ARG_WITH(gmp,
1472 [AS_HELP_STRING([--with-gmp=PATH],
1473                 [specify prefix directory for the installed GMP package.
1474                  Equivalent to --with-gmp-include=PATH/include
1475                  plus --with-gmp-lib=PATH/lib])])
1476 AC_ARG_WITH(gmp-include,
1477 [AS_HELP_STRING([--with-gmp-include=PATH],
1478                 [specify directory for installed GMP include files])])
1479 AC_ARG_WITH(gmp-lib,
1480 [AS_HELP_STRING([--with-gmp-lib=PATH],
1481                 [specify directory for the installed GMP library])])
1482
1483
1484 if test "x$with_gmp" != x; then
1485   gmplibs="-L$with_gmp/lib $gmplibs"
1486   gmpinc="-I$with_gmp/include $gmpinc"
1487 fi
1488 if test "x$with_gmp_include" != x; then
1489   gmpinc="-I$with_gmp_include $gmpinc"
1490 fi
1491 if test "x$with_gmp_lib" != x; then
1492   gmplibs="-L$with_gmp_lib $gmplibs"
1493 fi
1494 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1495   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1496   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1497   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1498   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1499   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1500   # Do not test the gmp version.  Assume that it is sufficient, since
1501   # it is in the source tree, and the library has not been built yet
1502   # but it would be included on the link line in the version check below
1503   # hence making the test fail.
1504   have_gmp=yes
1505 fi
1506
1507 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1508   have_gmp=yes
1509   saved_CFLAGS="$CFLAGS"
1510   CFLAGS="$CFLAGS $gmpinc"
1511   # Check for the recommended and required versions of GMP.
1512   AC_MSG_CHECKING([for the correct version of gmp.h])
1513   AC_TRY_COMPILE([#include "gmp.h"],[
1514   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1515   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1516   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1517   choke me
1518   #endif
1519   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1520   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1521   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1522   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1523   choke me
1524   #endif
1525   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1526    [AC_MSG_RESULT([no]); have_gmp=no])
1527
1528   # If we have GMP, check the MPFR version.
1529   if test x"$have_gmp" = xyes; then
1530     # Check for the recommended and required versions of MPFR.
1531     AC_MSG_CHECKING([for the correct version of mpfr.h])
1532     AC_TRY_COMPILE([#include <gmp.h>
1533     #include <mpfr.h>],[
1534     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1535     choke me
1536     #endif
1537     ], [AC_TRY_COMPILE([#include <gmp.h>
1538     #include <mpfr.h>],[
1539     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1540     choke me
1541     #endif
1542     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1543      [AC_MSG_RESULT([no]); have_gmp=no])
1544   fi
1545
1546   # Check for the MPC header version.
1547   if test x"$have_gmp" = xyes ; then
1548     # Check for the recommended and required versions of MPC.
1549     AC_MSG_CHECKING([for the correct version of mpc.h])
1550     AC_TRY_COMPILE([#include <mpc.h>],[
1551     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1552     choke me
1553     #endif
1554     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1555     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1556     choke me
1557     #endif
1558     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1559      [AC_MSG_RESULT([no]); have_gmp=no])
1560   fi
1561
1562   # Now check the MPFR library.
1563   if test x"$have_gmp" = xyes; then
1564     saved_LIBS="$LIBS"
1565     LIBS="$LIBS $gmplibs"
1566     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1567     AC_TRY_LINK([#include <mpc.h>],[
1568     mpfr_t n;
1569     mpfr_t x;
1570     mpc_t c;
1571     int t;
1572     mpfr_init (n);
1573     mpfr_init (x);
1574     mpfr_atan2 (n, n, x, GMP_RNDN);
1575     mpfr_erfc (n, x, GMP_RNDN);
1576     mpfr_subnormalize (x, t, GMP_RNDN);
1577     mpfr_clear(n);
1578     mpfr_clear(x);
1579     mpc_init2 (c, 53);
1580     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1581     mpc_cosh (c, c, MPC_RNDNN);
1582     mpc_pow (c, c, c, MPC_RNDNN);
1583     mpc_acosh (c, c, MPC_RNDNN);
1584     mpc_clear (c);
1585     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1586     LIBS="$saved_LIBS"
1587   fi
1588
1589   CFLAGS="$saved_CFLAGS"
1590
1591 # The library versions listed in the error message below should match
1592 # the HARD-minimums enforced above.
1593   if test x$have_gmp != xyes; then
1594     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1595 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1596 their locations.  Source code for these libraries can be found at
1597 their respective hosting sites as well as at
1598 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1599 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1600 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1601 make sure that you have installed both the libraries and the header
1602 files.  They may be located in separate packages.])
1603   fi
1604 fi
1605
1606 # Flags needed for both GMP, MPFR and/or MPC.
1607 AC_SUBST(gmplibs)
1608 AC_SUBST(gmpinc)
1609 AC_SUBST(extra_mpfr_configure_flags)
1610 AC_SUBST(extra_mpc_gmp_configure_flags)
1611 AC_SUBST(extra_mpc_mpfr_configure_flags)
1612 AC_SUBST(extra_isl_gmp_configure_flags)
1613
1614 # Libraries to use for stage1 or when not bootstrapping.
1615 AC_ARG_WITH(stage1-libs,
1616 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1617 [if test "$withval" = "no" -o "$withval" = "yes"; then
1618    stage1_libs=
1619  else
1620    stage1_libs=$withval
1621  fi],
1622 [stage1_libs=])
1623 AC_SUBST(stage1_libs)
1624
1625 # Linker flags to use for stage1 or when not bootstrapping.
1626 AC_ARG_WITH(stage1-ldflags,
1627 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1628 [if test "$withval" = "no" -o "$withval" = "yes"; then
1629    stage1_ldflags=
1630  else
1631    stage1_ldflags=$withval
1632  fi],
1633 [stage1_ldflags=
1634  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1635  # if supported.  But if the user explicitly specified the libraries to use,
1636  # trust that they are doing what they want.
1637  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1638    stage1_ldflags="-static-libstdc++ -static-libgcc"
1639  fi])
1640 AC_SUBST(stage1_ldflags)
1641
1642 # Libraries to use for stage2 and later builds.
1643 AC_ARG_WITH(boot-libs,
1644 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1645 [if test "$withval" = "no" -o "$withval" = "yes"; then
1646    poststage1_libs=
1647  else
1648    poststage1_libs=$withval
1649  fi],
1650 [poststage1_libs=])
1651 AC_SUBST(poststage1_libs)
1652
1653 # Linker flags to use for stage2 and later builds.
1654 AC_ARG_WITH(boot-ldflags,
1655 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1656                 [linker flags for stage2 and later])],
1657 [if test "$withval" = "no" -o "$withval" = "yes"; then
1658    poststage1_ldflags=
1659  else
1660    poststage1_ldflags=$withval
1661  fi],
1662 [poststage1_ldflags=
1663  # In stages 2 and 3, default to linking libstdc++ and libgcc
1664  # statically.  But if the user explicitly specified the libraries to
1665  # use, trust that they are doing what they want.
1666  if test "$poststage1_libs" = ""; then
1667    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1668  fi])
1669 AC_SUBST(poststage1_ldflags)
1670
1671 # GCC GRAPHITE dependency isl.
1672 # Basic setup is inlined here, actual checks are in config/isl.m4
1673
1674 AC_ARG_WITH(isl,
1675   [AS_HELP_STRING(
1676    [--with-isl=PATH],
1677    [Specify prefix directory for the installed isl package.
1678     Equivalent to --with-isl-include=PATH/include
1679     plus --with-isl-lib=PATH/lib])])
1680
1681 # Treat --without-isl as a request to disable
1682 # GRAPHITE support and skip all following checks.
1683 if test "x$with_isl" != "xno"; then
1684   # Check for isl
1685   dnl Provide configure switches and initialize islinc & isllibs
1686   dnl with user input.
1687   ISL_INIT_FLAGS
1688   dnl The versions of isl that work for Graphite
1689   ISL_CHECK_VERSION()
1690   dnl Only execute fail-action, if isl has been requested.
1691   ISL_IF_FAILED([
1692     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1693 fi
1694
1695 # If the isl check failed, disable builds of in-tree variant of isl
1696 if test "x$with_isl" = xno ||
1697    test "x$gcc_cv_isl" = xno; then
1698   noconfigdirs="$noconfigdirs isl"
1699   islinc=
1700 fi
1701
1702 AC_SUBST(isllibs)
1703 AC_SUBST(islinc)
1704
1705 # Check for LTO support.
1706 AC_ARG_ENABLE(lto,
1707 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1708 enable_lto=$enableval,
1709 enable_lto=yes; default_enable_lto=yes)
1710
1711 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1712   build_lto_plugin=yes
1713 ],[if test x"$default_enable_lto" = x"yes" ; then
1714     case $target in
1715       *-apple-darwin9* | *-cygwin* | *-mingw* | *djgpp*) ;;
1716       # On other non-ELF platforms, LTO has yet to be validated.
1717       *) enable_lto=no ;;
1718     esac
1719   else
1720   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1721   # It would also be nice to check the binutils support, but we don't
1722   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1723   # warn during gcc/ subconfigure; unless you're bootstrapping with
1724   # -flto it won't be needed until after installation anyway.
1725     case $target in
1726       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1727       *) if test x"$enable_lto" = x"yes"; then
1728         AC_MSG_ERROR([LTO support is not enabled for this target.])
1729         fi
1730       ;;
1731     esac
1732   fi
1733   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1734   # Build it unless LTO was explicitly disabled.
1735   case $target in
1736     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1737     *) ;;
1738   esac
1739 ])
1740
1741 AC_ARG_ENABLE(linker-plugin-configure-flags,
1742   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1743     [additional flags for configuring linker plugins @<:@none@:>@])],
1744   extra_linker_plugin_configure_flags=$enableval,
1745   extra_linker_plugin_configure_flags=)
1746 AC_SUBST(extra_linker_plugin_configure_flags)
1747 AC_ARG_ENABLE(linker-plugin-flags,
1748   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1749     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1750   extra_linker_plugin_flags=$enableval,
1751   extra_linker_plugin_flags=)
1752 AC_SUBST(extra_linker_plugin_flags)
1753
1754
1755 # By default, C and C++ are the only stage 1 languages.
1756 stage1_languages=,c,
1757
1758 # Target libraries that we bootstrap.
1759 bootstrap_target_libs=,target-libgcc,
1760
1761 # Figure out what language subdirectories are present.
1762 # Look if the user specified --enable-languages="..."; if not, use
1763 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1764 # go away some day.
1765 # NB:  embedded tabs in this IF block -- do not untabify
1766 if test -d ${srcdir}/gcc; then
1767   if test x"${enable_languages+set}" != xset; then
1768     if test x"${LANGUAGES+set}" = xset; then
1769       enable_languages="${LANGUAGES}"
1770         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1771     else
1772       enable_languages=all
1773     fi
1774   else
1775     if test x"${enable_languages}" = x ||
1776        test x"${enable_languages}" = xyes;
1777        then
1778       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1779       exit 1
1780     fi
1781   fi
1782   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1783
1784   # 'f95' is the old name for the 'fortran' language. We issue a warning
1785   # and make the substitution.
1786   case ,${enable_languages}, in
1787     *,f95,*)
1788       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1789       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1790       ;;
1791   esac
1792
1793   # If bootstrapping, C++ must be enabled.
1794   case ",$enable_languages,:$enable_bootstrap" in
1795     *,c++,*:*) ;;
1796     *:yes)
1797       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1798         enable_languages="${enable_languages},c++"
1799       else
1800         AC_MSG_ERROR([bootstrapping requires c++ sources])
1801       fi
1802       ;;
1803   esac
1804
1805   # First scan to see if an enabled language requires some other language.
1806   # We assume that a given config-lang.in will list all the language
1807   # front ends it requires, even if some are required indirectly.
1808   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1809     case ${lang_frag} in
1810       ..) ;;
1811       # The odd quoting in the next line works around
1812       # an apparent bug in bash 1.12 on linux.
1813       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1814       *)
1815         # From the config-lang.in, get $language, $lang_requires, and
1816         # $lang_requires_boot_languages.
1817         language=
1818         lang_requires=
1819         lang_requires_boot_languages=
1820         . ${lang_frag}
1821         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1822           case ,${enable_languages}, in
1823             *,$other,*) ;;
1824             *,all,*) ;;
1825             *,$language,*)
1826               echo " \`$other' language required by \`$language'; enabling" 1>&2
1827               enable_languages="${enable_languages},${other}"
1828               ;;
1829           esac
1830         done
1831         for other in ${lang_requires_boot_languages} ; do
1832           if test "$other" != "c"; then
1833             case ,${enable_stage1_languages}, in
1834               *,$other,*) ;;
1835               *,all,*) ;;
1836               *)
1837                 case ,${enable_languages}, in
1838                   *,$language,*)
1839                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1840                     enable_stage1_languages="$enable_stage1_languages,${other}"
1841                     ;;
1842                 esac
1843                 ;;
1844             esac
1845           fi
1846         done
1847         ;;
1848     esac
1849   done
1850
1851   new_enable_languages=,c,
1852
1853   # If LTO is enabled, add the LTO front end.
1854   if test "$enable_lto" = "yes" ; then
1855     case ,${enable_languages}, in
1856       *,lto,*) ;;
1857       *) enable_languages="${enable_languages},lto" ;;
1858     esac
1859     if test "${build_lto_plugin}" = "yes" ; then
1860       configdirs="$configdirs lto-plugin"
1861     fi
1862   fi
1863
1864   # If we're building an offloading compiler, add the LTO front end.
1865   if test x"$enable_as_accelerator_for" != x ; then
1866     case ,${enable_languages}, in
1867       *,lto,*) ;;
1868       *) enable_languages="${enable_languages},lto" ;;
1869     esac
1870   fi
1871
1872   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1873   potential_languages=,c,
1874
1875   enabled_target_libs=
1876   disabled_target_libs=
1877
1878   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1879     case ${lang_frag} in
1880       ..) ;;
1881       # The odd quoting in the next line works around
1882       # an apparent bug in bash 1.12 on linux.
1883       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1884       *)
1885         # From the config-lang.in, get $language, $target_libs,
1886         # $lang_dirs, $boot_language, and $build_by_default
1887         language=
1888         target_libs=
1889         lang_dirs=
1890         subdir_requires=
1891         boot_language=no
1892         build_by_default=yes
1893         . ${lang_frag}
1894         if test x${language} = x; then
1895           echo "${lang_frag} doesn't set \$language." 1>&2
1896           exit 1
1897         fi
1898
1899         if test "$language" = "c++"; then
1900           boot_language=yes
1901         fi
1902
1903         add_this_lang=no
1904         case ,${enable_languages}, in
1905           *,${language},*)
1906             # Language was explicitly selected; include it
1907             # unless it is C, which is enabled by default.
1908             if test "$language" != "c"; then
1909               add_this_lang=yes
1910             fi
1911             ;;
1912           *,all,*)
1913             # 'all' was selected, select it if it is a default language
1914             if test "$language" != "c"; then
1915               add_this_lang=${build_by_default}
1916             fi
1917             ;;
1918         esac
1919
1920         # Disable languages that need other directories if these aren't available.
1921         for i in $subdir_requires; do
1922           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1923           case ,${enable_languages}, in
1924             *,${language},*)
1925               # Specifically requested language; tell them.
1926               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1927               ;;
1928             *)
1929               # Silently disable.
1930               add_this_lang=unsupported
1931               ;;
1932           esac
1933         done
1934
1935         # Disable Ada if no preexisting GNAT is available.
1936         case ,${enable_languages},:${language}:${have_gnat} in
1937           *,${language},*:ada:no)
1938             # Specifically requested language; tell them.
1939             AC_MSG_ERROR([GNAT is required to build $language])
1940             ;;
1941           *:ada:no)
1942             # Silently disable.
1943             add_this_lang=unsupported
1944             ;;
1945         esac
1946
1947         # Disable a language that is unsupported by the target.
1948         case " $unsupported_languages " in
1949           *" $language "*)
1950             add_this_lang=unsupported
1951             ;;
1952         esac
1953
1954         case $add_this_lang in
1955           unsupported)
1956             # Remove language-dependent dirs.
1957             disabled_target_libs="$disabled_target_libs $target_libs"
1958             noconfigdirs="$noconfigdirs $lang_dirs"
1959             ;;
1960           no)
1961             # Remove language-dependent dirs; still show language as supported.
1962             disabled_target_libs="$disabled_target_libs $target_libs"
1963             noconfigdirs="$noconfigdirs $lang_dirs"
1964             potential_languages="${potential_languages}${language},"
1965             ;;
1966           yes)
1967             new_enable_languages="${new_enable_languages}${language},"
1968             potential_languages="${potential_languages}${language},"
1969             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1970             enabled_target_libs="$enabled_target_libs $target_libs"
1971             case "${boot_language}:,$enable_stage1_languages," in
1972               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1973                 # Add to (comma-separated) list of stage 1 languages.
1974                 case ",$stage1_languages," in
1975                   *,$language,* | ,yes, | ,all,) ;;
1976                   *) stage1_languages="${stage1_languages}${language}," ;;
1977                 esac
1978                 # We need to bootstrap any supporting libraries.
1979                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1980                 ;;
1981             esac
1982             ;;
1983         esac
1984         ;;
1985     esac
1986   done
1987
1988   # Add target libraries which are only needed for disabled languages
1989   # to noconfigdirs.
1990   if test -n "$disabled_target_libs"; then
1991     for dir in $disabled_target_libs; do
1992       case " $enabled_target_libs " in
1993       *" ${dir} "*) ;;
1994       *) noconfigdirs="$noconfigdirs $dir" ;;
1995       esac
1996     done
1997   fi
1998
1999   AC_ARG_ENABLE(stage1-languages,
2000   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2001                   [choose additional languages to build during
2002                   stage1.  Mostly useful for compiler development])],
2003   [case ,${enable_stage1_languages}, in
2004     ,no,|,,)
2005       # Set it to something that will have no effect in the loop below
2006       enable_stage1_languages=c ;;
2007     ,yes,)
2008       enable_stage1_languages=`echo $new_enable_languages | \
2009         sed -e "s/^,//" -e "s/,$//" ` ;;
2010     *,all,*)
2011       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2012         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2013   esac
2014
2015   # Add "good" languages from enable_stage1_languages to stage1_languages,
2016   # while "bad" languages go in missing_languages.  Leave no duplicates.
2017   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2018     case $potential_languages in
2019       *,$i,*)
2020         case $stage1_languages in
2021           *,$i,*) ;;
2022           *) stage1_languages="$stage1_languages$i," ;;
2023         esac ;;
2024       *)
2025         case $missing_languages in
2026           *,$i,*) ;;
2027           *) missing_languages="$missing_languages$i," ;;
2028         esac ;;
2029      esac
2030   done])
2031
2032   # Remove leading/trailing commas that were added for simplicity
2033   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2034   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2035   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2036   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2037
2038   if test "x$missing_languages" != x; then
2039     AC_MSG_ERROR([
2040 The following requested languages could not be built: ${missing_languages}
2041 Supported languages are: ${potential_languages}])
2042   fi
2043   if test "x$new_enable_languages" != "x$enable_languages"; then
2044     echo The following languages will be built: ${new_enable_languages}
2045     enable_languages="$new_enable_languages"
2046   fi
2047
2048   AC_SUBST(stage1_languages)
2049   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2050 fi
2051
2052 # Handle --disable-<component> generically.
2053 for dir in $configdirs $build_configdirs $target_configdirs ; do
2054   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2055   varname=`echo $dirname | sed -e s/+/_/g`
2056   if eval test x\${enable_${varname}} "=" xno ; then
2057     noconfigdirs="$noconfigdirs $dir"
2058   fi
2059 done
2060
2061 # Check for Boehm's garbage collector
2062 AC_ARG_ENABLE(objc-gc,
2063 [AS_HELP_STRING([--enable-objc-gc],
2064                 [enable use of Boehm's garbage collector with the
2065                  GNU Objective-C runtime])],
2066 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
2067   *,objc,*:*:yes:*target-boehm-gc*)
2068     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
2069     ;;
2070 esac])
2071
2072 # Make sure we only build Boehm's garbage collector if required.
2073 case ,${enable_languages},:${enable_objc_gc} in
2074   *,objc,*:yes)
2075     # Keep target-boehm-gc if requested for Objective-C.
2076     ;;
2077   *)
2078     # Otherwise remove target-boehm-gc.
2079     noconfigdirs="$noconfigdirs target-boehm-gc"
2080     ;;
2081 esac
2082
2083 # Disable libcilkrts, libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2084 case ,${enable_languages}, in
2085   *,c++,*)
2086     # Disable libcilkrts, libitm, libsanitizer if we're not building libstdc++
2087     case "${noconfigdirs}" in
2088       *target-libstdc++-v3*)
2089         noconfigdirs="$noconfigdirs target-libcilkrts target-libitm target-libsanitizer"
2090         ;;
2091       *) ;;
2092     esac
2093     ;;
2094   *)
2095     noconfigdirs="$noconfigdirs target-libcilkrts target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2096     ;;
2097 esac
2098
2099 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2100 # $build_configdirs and $target_configdirs.
2101 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2102
2103 notsupp=""
2104 for dir in . $skipdirs $noconfigdirs ; do
2105   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2106   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2107     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2108     if test -r $srcdir/$dirname/configure ; then
2109       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2110         true
2111       else
2112         notsupp="$notsupp $dir"
2113       fi
2114     fi
2115   fi
2116   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2117     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2118     if test -r $srcdir/$dirname/configure ; then
2119       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2120         true
2121       else
2122         notsupp="$notsupp $dir"
2123       fi
2124     fi
2125   fi
2126   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2127     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2128     if test -r $srcdir/$dirname/configure ; then
2129       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2130         true
2131       else
2132         notsupp="$notsupp $dir"
2133       fi
2134     fi
2135   fi
2136 done
2137
2138 # Quietly strip out all directories which aren't configurable in this tree.
2139 # This relies on all configurable subdirectories being autoconfiscated, which
2140 # is now the case.
2141 build_configdirs_all="$build_configdirs"
2142 build_configdirs=
2143 for i in ${build_configdirs_all} ; do
2144   j=`echo $i | sed -e s/build-//g`
2145   if test -f ${srcdir}/$j/configure ; then
2146     build_configdirs="${build_configdirs} $i"
2147   fi
2148 done
2149
2150 configdirs_all="$configdirs"
2151 configdirs=
2152 for i in ${configdirs_all} ; do
2153   if test -f ${srcdir}/$i/configure ; then
2154     configdirs="${configdirs} $i"
2155   fi
2156 done
2157
2158 target_configdirs_all="$target_configdirs"
2159 target_configdirs=
2160 for i in ${target_configdirs_all} ; do
2161   j=`echo $i | sed -e s/target-//g`
2162   if test -f ${srcdir}/$j/configure ; then
2163     target_configdirs="${target_configdirs} $i"
2164   fi
2165 done
2166
2167 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2168 # so we have to add it after the preceding checks.
2169 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2170 then
2171   case " $configdirs " in
2172     *" libiberty "*)
2173       # If we can build libiberty, we can also build libiberty-linker-plugin.
2174       configdirs="$configdirs libiberty-linker-plugin"
2175       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2176         --with-libiberty=../libiberty-linker-plugin";;
2177     *)
2178       AC_MSG_ERROR([libiberty missing]);;
2179   esac
2180 fi
2181
2182 # Sometimes we have special requirements for the host libiberty.
2183 extra_host_libiberty_configure_flags=
2184 extra_host_zlib_configure_flags=
2185 case " $configdirs " in
2186   *" lto-plugin "* | *" libcc1 "*)
2187     # When these are to be built as shared libraries, the same applies to
2188     # libiberty.
2189     extra_host_libiberty_configure_flags=--enable-shared
2190     ;;
2191   *" bfd "*)
2192     # When bfd is to be built as a shared library, the same applies to
2193     # zlib.
2194     if test "$enable_shared" = "yes"; then
2195       extra_host_zlib_configure_flags=--enable-host-shared
2196     fi
2197     ;;
2198 esac
2199 AC_SUBST(extra_host_libiberty_configure_flags)
2200 AC_SUBST(extra_host_zlib_configure_flags)
2201
2202 # Produce a warning message for the subdirs we can't configure.
2203 # This isn't especially interesting in the Cygnus tree, but in the individual
2204 # FSF releases, it's important to let people know when their machine isn't
2205 # supported by the one or two programs in a package.
2206
2207 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2208   # If $appdirs is non-empty, at least one of those directories must still
2209   # be configured, or we error out.  (E.g., if the gas release supports a
2210   # specified target in some subdirs but not the gas subdir, we shouldn't
2211   # pretend that all is well.)
2212   if test -n "$appdirs" ; then
2213     for dir in $appdirs ; do
2214       if test -r $dir/Makefile.in ; then
2215         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2216           appdirs=""
2217           break
2218         fi
2219         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2220           appdirs=""
2221           break
2222         fi
2223       fi
2224     done
2225     if test -n "$appdirs" ; then
2226       echo "*** This configuration is not supported by this package." 1>&2
2227       exit 1
2228     fi
2229   fi
2230   # Okay, some application will build, or we don't care to check.  Still
2231   # notify of subdirs not getting built.
2232   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2233   echo "    ${notsupp}" 1>&2
2234   echo "    (Any other directories should still work fine.)" 1>&2
2235 fi
2236
2237 case "$host" in
2238   *msdosdjgpp*)
2239     enable_gdbtk=no ;;
2240 esac
2241
2242 # To find our prefix, in gcc_cv_tool_prefix.
2243 ACX_TOOL_DIRS
2244
2245 copy_dirs=
2246
2247 AC_ARG_WITH([build-sysroot],
2248   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2249                   [use sysroot as the system root during the build])],
2250   [if test x"$withval" != x ; then
2251      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2252    fi],
2253   [SYSROOT_CFLAGS_FOR_TARGET=])
2254 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2255
2256 AC_ARG_WITH([debug-prefix-map],
2257   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2258                   [map A to B, C to D ... in debug information])],
2259   [if test x"$withval" != x; then
2260      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2261      for debug_map in $withval; do
2262        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2263      done
2264    fi],
2265   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2266 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2267
2268 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2269 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2270 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2271 # We want to ensure that TARGET libraries (which we know are built with
2272 # gcc) are built with "-O2 -g", so include those options when setting
2273 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2274 if test "x$CFLAGS_FOR_TARGET" = x; then
2275   if test "x${is_cross_compiler}" = xyes; then
2276     CFLAGS_FOR_TARGET="-g -O2"
2277   else
2278     CFLAGS_FOR_TARGET=$CFLAGS
2279     case " $CFLAGS " in
2280       *" -O2 "*) ;;
2281       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2282     esac
2283     case " $CFLAGS " in
2284       *" -g "* | *" -g3 "*) ;;
2285       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2286     esac
2287   fi
2288 fi
2289 AC_SUBST(CFLAGS_FOR_TARGET)
2290
2291 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2292   if test "x${is_cross_compiler}" = xyes; then
2293     CXXFLAGS_FOR_TARGET="-g -O2"
2294   else
2295     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2296     case " $CXXFLAGS " in
2297       *" -O2 "*) ;;
2298       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2299     esac
2300     case " $CXXFLAGS " in
2301       *" -g "* | *" -g3 "*) ;;
2302       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2303     esac
2304   fi
2305 fi
2306 AC_SUBST(CXXFLAGS_FOR_TARGET)
2307
2308 AC_SUBST(LDFLAGS_FOR_TARGET)
2309
2310 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2311 # the named directory are copied to $(tooldir)/sys-include.
2312 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2313   if test x${is_cross_compiler} = xno ; then
2314     echo 1>&2 '***' --with-headers is only supported when cross compiling
2315     exit 1
2316   fi
2317   if test x"${with_headers}" != xyes ; then
2318     x=${gcc_cv_tool_prefix}
2319     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2320   fi
2321 fi
2322
2323 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2324 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2325 # are permitted.
2326 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2327   if test x${is_cross_compiler} = xno ; then
2328     echo 1>&2 '***' --with-libs is only supported when cross compiling
2329     exit 1
2330   fi
2331   if test x"${with_libs}" != xyes ; then
2332     # Copy the libraries in reverse order, so that files in the first named
2333     # library override files in subsequent libraries.
2334     x=${gcc_cv_tool_prefix}
2335     for l in ${with_libs}; do
2336       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2337     done
2338   fi
2339 fi
2340
2341 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2342 #
2343 # This is done by determining whether or not the appropriate directory
2344 # is available, and by checking whether or not specific configurations
2345 # have requested that this magic not happen.
2346 #
2347 # The command line options always override the explicit settings in
2348 # configure.ac, and the settings in configure.ac override this magic.
2349 #
2350 # If the default for a toolchain is to use GNU as and ld, and you don't
2351 # want to do that, then you should use the --without-gnu-as and
2352 # --without-gnu-ld options for the configure script.  Similarly, if
2353 # the default is to use the included zlib and you don't want to do that,
2354 # you should use the --with-system-zlib option for the configure script.
2355
2356 if test x${use_gnu_as} = x &&
2357    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2358   with_gnu_as=yes
2359   extra_host_args="$extra_host_args --with-gnu-as"
2360 fi
2361
2362 if test x${use_gnu_ld} = x &&
2363    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2364   with_gnu_ld=yes
2365   extra_host_args="$extra_host_args --with-gnu-ld"
2366 fi
2367
2368 if test x${use_included_zlib} = x &&
2369    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2370   :
2371 else
2372   with_system_zlib=yes
2373   extra_host_args="$extra_host_args --with-system-zlib"
2374 fi
2375
2376 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2377 # can detect this case.
2378
2379 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2380   with_newlib=yes
2381   extra_host_args="$extra_host_args --with-newlib"
2382 fi
2383
2384 # Handle ${copy_dirs}
2385 set fnord ${copy_dirs}
2386 shift
2387 while test $# != 0 ; do
2388   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2389     :
2390   else
2391     echo Copying $1 to $2
2392
2393     # Use the install script to create the directory and all required
2394     # parent directories.
2395     if test -d $2 ; then
2396       :
2397     else
2398       echo >config.temp
2399       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2400     fi
2401
2402     # Copy the directory, assuming we have tar.
2403     # FIXME: Should we use B in the second tar?  Not all systems support it.
2404     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2405
2406     # It is the responsibility of the user to correctly adjust all
2407     # symlinks.  If somebody can figure out how to handle them correctly
2408     # here, feel free to add the code.
2409
2410     echo $1 > $2/COPIED
2411   fi
2412   shift; shift
2413 done
2414
2415 # Determine a target-dependent exec_prefix that the installed
2416 # gcc will search in.  Keep this list sorted by triplet, with
2417 # the *-*-osname triplets last.
2418 md_exec_prefix=
2419 case "${target}" in
2420   i[[34567]]86-pc-msdosdjgpp*)
2421     md_exec_prefix=/dev/env/DJDIR/bin
2422     ;;
2423   *-*-hpux* | \
2424   *-*-nto-qnx* | \
2425   *-*-solaris2*)
2426     md_exec_prefix=/usr/ccs/bin
2427     ;;
2428 esac
2429
2430 extra_arflags_for_target=
2431 extra_nmflags_for_target=
2432 extra_ranlibflags_for_target=
2433 target_makefile_frag=/dev/null
2434 case "${target}" in
2435   spu-*-*)
2436     target_makefile_frag="config/mt-spu"
2437     ;;
2438   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2439     target_makefile_frag="config/mt-sde"
2440     ;;
2441   mipsisa*-*-elfoabi*)
2442     target_makefile_frag="config/mt-mips-elfoabi"
2443     ;;
2444   mips*-*-*linux* | mips*-*-gnu*)
2445     target_makefile_frag="config/mt-mips-gnu"
2446     ;;
2447   nios2-*-elf*)
2448     target_makefile_frag="config/mt-nios2-elf"
2449     ;;
2450   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2451     target_makefile_frag="config/mt-gnu"
2452     ;;
2453   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2454     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2455     # commands to handle both 32-bit and 64-bit objects.  These flags are
2456     # harmless if we're using GNU nm or ar.
2457     extra_arflags_for_target=" -X32_64"
2458     extra_nmflags_for_target=" -B -X32_64"
2459     ;;
2460 esac
2461
2462 alphaieee_frag=/dev/null
2463 case $target in
2464   alpha*-*-*)
2465     # This just makes sure to use the -mieee option to build target libs.
2466     # This should probably be set individually by each library.
2467     alphaieee_frag="config/mt-alphaieee"
2468     ;;
2469 esac
2470
2471 # If --enable-target-optspace always use -Os instead of -O2 to build
2472 # the target libraries, similarly if it is not specified, use -Os
2473 # on selected platforms.
2474 ospace_frag=/dev/null
2475 case "${enable_target_optspace}:${target}" in
2476   yes:*)
2477     ospace_frag="config/mt-ospace"
2478     ;;
2479   :d30v-*)
2480     ospace_frag="config/mt-d30v"
2481     ;;
2482   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2483     ospace_frag="config/mt-ospace"
2484     ;;
2485   no:* | :*)
2486     ;;
2487   *)
2488     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2489     ;;
2490 esac
2491
2492 # Some systems (e.g., one of the i386-aix systems the gas testers are
2493 # using) don't handle "\$" correctly, so don't use it here.
2494 tooldir='${exec_prefix}'/${target_noncanonical}
2495 build_tooldir=${tooldir}
2496
2497 # Create a .gdbinit file which runs the one in srcdir
2498 # and tells GDB to look there for source files.
2499
2500 if test -r ${srcdir}/.gdbinit ; then
2501   case ${srcdir} in
2502     .) ;;
2503     *) cat > ./.gdbinit <<EOF
2504 # ${NO_EDIT}
2505 dir ${srcdir}
2506 dir .
2507 source ${srcdir}/.gdbinit
2508 EOF
2509     ;;
2510   esac
2511 fi
2512
2513 # Make sure that the compiler is able to generate an executable.  If it
2514 # can't, we are probably in trouble.  We don't care whether we can run the
2515 # executable--we might be using a cross compiler--we only care whether it
2516 # can be created.  At this point the main configure script has set CC.
2517 we_are_ok=no
2518 echo "int main () { return 0; }" > conftest.c
2519 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2520 if test $? = 0 ; then
2521   if test -s conftest || test -s conftest.exe ; then
2522     we_are_ok=yes
2523   fi
2524 fi
2525 case $we_are_ok in
2526   no)
2527     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2528     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2529     rm -f conftest*
2530     exit 1
2531     ;;
2532 esac
2533 rm -f conftest*
2534
2535 # Decide which environment variable is used to find dynamic libraries.
2536 case "${host}" in
2537   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2538   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2539   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2540   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2541 esac
2542
2543 # On systems where the dynamic library environment variable is PATH,
2544 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2545 # built executables to PATH.
2546 if test "$RPATH_ENVVAR" = PATH; then
2547   GCC_SHLIB_SUBDIR=/shlib
2548 else
2549   GCC_SHLIB_SUBDIR=
2550 fi
2551
2552 # Adjust the toplevel makefile according to whether bootstrap was selected.
2553 case $enable_bootstrap in
2554   yes)
2555     bootstrap_suffix=bootstrap
2556     BUILD_CONFIG=bootstrap-debug
2557     ;;
2558   no)
2559     bootstrap_suffix=no-bootstrap
2560     BUILD_CONFIG=
2561     ;;
2562 esac
2563
2564 AC_MSG_CHECKING(for default BUILD_CONFIG)
2565
2566 AC_ARG_WITH([build-config],
2567   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2568                   [use config/NAME.mk build configuration])],
2569   [case $with_build_config in
2570    yes) with_build_config= ;;
2571    no) with_build_config= BUILD_CONFIG= ;;
2572    esac])
2573
2574 if test "x${with_build_config}" != x; then
2575   BUILD_CONFIG=$with_build_config
2576 else
2577   case $BUILD_CONFIG in
2578   bootstrap-debug)
2579     if echo "int f (void) { return 0; }" > conftest.c &&
2580        ${CC} -c conftest.c &&
2581        mv conftest.o conftest.o.g0 &&
2582        ${CC} -c -g conftest.c &&
2583        mv conftest.o conftest.o.g &&
2584        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2585       :
2586     else
2587       BUILD_CONFIG=
2588     fi
2589     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2590     ;;
2591   esac
2592 fi
2593 AC_MSG_RESULT($BUILD_CONFIG)
2594 AC_SUBST(BUILD_CONFIG)
2595
2596 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2597 AC_MSG_CHECKING([for --enable-vtable-verify])
2598 AC_ARG_ENABLE(vtable-verify,
2599 [AS_HELP_STRING([--enable-vtable-verify],
2600                 [Enable vtable verification feature])],
2601 [case "$enableval" in
2602  yes) enable_vtable_verify=yes ;;
2603  no)  enable_vtable_verify=no ;;
2604  *)   enable_vtable_verify=no;;
2605  esac],
2606 [enable_vtable_verify=no])
2607 AC_MSG_RESULT($enable_vtable_verify)
2608
2609 # Record target_configdirs and the configure arguments for target and
2610 # build configuration in Makefile.
2611 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2612 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2613 bootstrap_fixincludes=no
2614
2615 # If we are building libgomp, bootstrap it.
2616 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2617   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2618 fi
2619
2620 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2621 # or bootstrap-ubsan, bootstrap it.
2622 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2623   case "$BUILD_CONFIG" in
2624     *bootstrap-asan* | *bootstrap-ubsan* )
2625       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2626       bootstrap_fixincludes=yes
2627       ;;
2628   esac
2629 fi
2630
2631 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2632 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2633    test "$enable_vtable_verify" != no; then
2634   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2635 fi
2636
2637 # If we are building libmpx, bootstrap it.
2638 if echo " ${target_configdirs} " | grep " libmpx " > /dev/null 2>&1; then
2639   bootstrap_target_libs=${bootstrap_target_libs}target-libmpx,
2640 fi
2641
2642 # Determine whether gdb needs tk/tcl or not.
2643 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2644 # and in that case we want gdb to be built without tk.  Ugh!
2645 # In fact I believe gdb is the *only* package directly dependent on tk,
2646 # so we should be able to put the 'maybe's in unconditionally and
2647 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2648 # 100% sure that that's safe though.
2649
2650 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2651 case "$enable_gdbtk" in
2652   no)
2653     GDB_TK="" ;;
2654   yes)
2655     GDB_TK="${gdb_tk}" ;;
2656   *)
2657     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2658     # distro.  Eventually someone will fix this and move Insight, nee
2659     # gdbtk to a separate directory.
2660     if test -d ${srcdir}/gdb/gdbtk ; then
2661       GDB_TK="${gdb_tk}"
2662     else
2663       GDB_TK=""
2664     fi
2665     ;;
2666 esac
2667 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2668 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2669
2670 # Strip out unwanted targets.
2671
2672 # While at that, we remove Makefiles if we were started for recursive
2673 # configuration, so that the top-level Makefile reconfigures them,
2674 # like we used to do when configure itself was recursive.
2675
2676 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2677 # but now we're fixing up the Makefile ourselves with the additional
2678 # commands passed to AC_CONFIG_FILES.  Use separate variables
2679 # extrasub-{build,host,target} not because there is any reason to split
2680 # the substitutions up that way, but only to remain below the limit of
2681 # 99 commands in a script, for HP-UX sed.
2682 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2683
2684 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2685   yes:yes:*\ gold\ *:*,c++,*) ;;
2686   yes:yes:*\ gold\ *:*)
2687     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2688     ;;
2689 esac
2690
2691 extrasub_build=
2692 for module in ${build_configdirs} ; do
2693   if test -z "${no_recursion}" \
2694      && test -f ${build_subdir}/${module}/Makefile; then
2695     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2696     rm -f ${build_subdir}/${module}/Makefile
2697   fi
2698   extrasub_build="$extrasub_build
2699 /^@if build-$module\$/d
2700 /^@endif build-$module\$/d
2701 /^@if build-$module-$bootstrap_suffix\$/d
2702 /^@endif build-$module-$bootstrap_suffix\$/d"
2703 done
2704 extrasub_host=
2705 for module in ${configdirs} ; do
2706   if test -z "${no_recursion}"; then
2707     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2708       if test -f ${file}; then
2709         echo 1>&2 "*** removing ${file} to force reconfigure"
2710         rm -f ${file}
2711       fi
2712     done
2713   fi
2714   case ${module},${bootstrap_fixincludes} in
2715     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2716     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2717   esac
2718   extrasub_host="$extrasub_host
2719 /^@if $module\$/d
2720 /^@endif $module\$/d
2721 /^@if $module-$host_bootstrap_suffix\$/d
2722 /^@endif $module-$host_bootstrap_suffix\$/d"
2723 done
2724 extrasub_target=
2725 for module in ${target_configdirs} ; do
2726   if test -z "${no_recursion}" \
2727      && test -f ${target_subdir}/${module}/Makefile; then
2728     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2729     rm -f ${target_subdir}/${module}/Makefile
2730   fi
2731
2732   # We only bootstrap target libraries listed in bootstrap_target_libs.
2733   case $bootstrap_target_libs in
2734     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2735     *) target_bootstrap_suffix=no-bootstrap ;;
2736   esac
2737
2738   extrasub_target="$extrasub_target
2739 /^@if target-$module\$/d
2740 /^@endif target-$module\$/d
2741 /^@if target-$module-$target_bootstrap_suffix\$/d
2742 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2743 done
2744
2745 # Do the final fixup along with target modules.
2746 extrasub_target="$extrasub_target
2747 /^@if /,/^@endif /d"
2748
2749 # Create the serialization dependencies.  This uses a temporary file.
2750
2751 AC_ARG_ENABLE([serial-configure],
2752 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2753                 [force sequential configuration of
2754                  sub-packages for the host, target or build
2755                  machine, or all sub-packages])])
2756
2757 case ${enable_serial_configure} in
2758   yes)
2759     enable_serial_build_configure=yes
2760     enable_serial_host_configure=yes
2761     enable_serial_target_configure=yes
2762     ;;
2763 esac
2764
2765 # These force 'configure's to be done one at a time, to avoid problems
2766 # with contention over a shared config.cache.
2767 rm -f serdep.tmp
2768 echo '# serdep.tmp' > serdep.tmp
2769 olditem=
2770 test "x${enable_serial_build_configure}" = xyes &&
2771 for item in ${build_configdirs} ; do
2772   case ${olditem} in
2773     "") ;;
2774     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2775   esac
2776   olditem=${item}
2777 done
2778 olditem=
2779 test "x${enable_serial_host_configure}" = xyes &&
2780 for item in ${configdirs} ; do
2781   case ${olditem} in
2782     "") ;;
2783     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2784   esac
2785   olditem=${item}
2786 done
2787 olditem=
2788 test "x${enable_serial_target_configure}" = xyes &&
2789 for item in ${target_configdirs} ; do
2790   case ${olditem} in
2791     "") ;;
2792     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2793   esac
2794   olditem=${item}
2795 done
2796 serialization_dependencies=serdep.tmp
2797 AC_SUBST_FILE(serialization_dependencies)
2798
2799 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2800 # target, nonopt, and variable assignments.  These are the ones we
2801 # might not want to pass down to subconfigures.  The exception being
2802 # --cache-file=/dev/null, which is used to turn off the use of cache
2803 # files altogether, and which should be passed on to subconfigures.
2804 # Also strip program-prefix, program-suffix, and program-transform-name,
2805 # so that we can pass down a consistent program-transform-name.
2806 baseargs=
2807 tbaseargs=
2808 keep_next=no
2809 skip_next=no
2810 eval "set -- $ac_configure_args"
2811 for ac_arg
2812 do
2813   if test X"$skip_next" = X"yes"; then
2814     skip_next=no
2815     continue
2816   fi
2817   if test X"$keep_next" = X"yes"; then
2818     case $ac_arg in
2819       *\'*)
2820         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2821     esac
2822     baseargs="$baseargs '$ac_arg'"
2823     tbaseargs="$tbaseargs '$ac_arg'"
2824     keep_next=no
2825     continue
2826   fi
2827
2828   # Handle separated arguments.  Based on the logic generated by
2829   # autoconf 2.59.
2830   case $ac_arg in
2831     *=* | --config-cache | -C | -disable-* | --disable-* \
2832       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2833       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2834       | -with-* | --with-* | -without-* | --without-* | --x)
2835       separate_arg=no
2836       ;;
2837     -*)
2838       separate_arg=yes
2839       ;;
2840     *)
2841       separate_arg=no
2842       ;;
2843   esac
2844
2845   skip_targ=no
2846   case $ac_arg in
2847 changequote(,)
2848   --with-* | --without-*)
2849     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2850
2851     case $libopt in
2852     *[-_]include)
2853       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2854       ;;
2855     *[-_]lib)
2856       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2857       ;;
2858     *)
2859       lib=$libopt
2860       ;;
2861     esac
2862 changequote([,])
2863
2864     case $lib in
2865     mpc | mpfr | gmp | isl)
2866       # If we're processing --with-$lib, --with-$lib-include or
2867       # --with-$lib-lib, for one of the libs above, and target is
2868       # different from host, don't pass the current argument to any
2869       # target library's configure.
2870       if test x$is_cross_compiler = xyes; then
2871         skip_targ=yes
2872       fi
2873       ;;
2874     esac
2875     ;;
2876   esac
2877
2878   case "$ac_arg" in
2879     --cache-file=/dev/null | \
2880     -cache-file=/dev/null )
2881       # Handled here to avoid the test to skip args below.
2882       baseargs="$baseargs '$ac_arg'"
2883       tbaseargs="$tbaseargs '$ac_arg'"
2884       # Assert: $separate_arg should always be no.
2885       keep_next=$separate_arg
2886       ;;
2887     --no*)
2888       continue
2889       ;;
2890     --c* | \
2891     --sr* | \
2892     --ho* | \
2893     --bu* | \
2894     --t* | \
2895     --program-* | \
2896     -cache_file* | \
2897     -srcdir* | \
2898     -host* | \
2899     -build* | \
2900     -target* | \
2901     -program-prefix* | \
2902     -program-suffix* | \
2903     -program-transform-name* )
2904       skip_next=$separate_arg
2905       continue
2906       ;;
2907     -*)
2908       # An option.  Add it.
2909       case $ac_arg in
2910         *\'*)
2911           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2912       esac
2913       baseargs="$baseargs '$ac_arg'"
2914       if test X"$skip_targ" = Xno; then
2915         tbaseargs="$tbaseargs '$ac_arg'"
2916       fi
2917       keep_next=$separate_arg
2918       ;;
2919     *)
2920       # Either a variable assignment, or a nonopt (triplet).  Don't
2921       # pass it down; let the Makefile handle this.
2922       continue
2923       ;;
2924   esac
2925 done
2926 # Remove the initial space we just introduced and, as these will be
2927 # expanded by make, quote '$'.
2928 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2929
2930 # Add in --program-transform-name, after --program-prefix and
2931 # --program-suffix have been applied to it.  Autoconf has already
2932 # doubled dollar signs and backslashes in program_transform_name; we want
2933 # the backslashes un-doubled, and then the entire thing wrapped in single
2934 # quotes, because this will be expanded first by make and then by the shell.
2935 # Also, because we want to override the logic in subdir configure scripts to
2936 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2937 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2938 ${program_transform_name}
2939 EOF_SED
2940 gcc_transform_name=`cat conftestsed.out`
2941 rm -f conftestsed.out
2942 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2943 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2944 if test "$silent" = yes; then
2945   baseargs="$baseargs --silent"
2946   tbaseargs="$tbaseargs --silent"
2947 fi
2948 baseargs="$baseargs --disable-option-checking"
2949 tbaseargs="$tbaseargs --disable-option-checking"
2950
2951 # Record and document user additions to sub configure arguments.
2952 AC_ARG_VAR([build_configargs],
2953            [additional configure arguments for build directories])
2954 AC_ARG_VAR([host_configargs],
2955            [additional configure arguments for host directories])
2956 AC_ARG_VAR([target_configargs],
2957            [additional configure arguments for target directories])
2958
2959 # For the build-side libraries, we just need to pretend we're native,
2960 # and not use the same cache file.  Multilibs are neither needed nor
2961 # desired.  We can't even use the same cache file for all build-side
2962 # libraries, as they're compiled differently; some with C, some with
2963 # C++ or with different feature-enabling options.
2964 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
2965
2966 # For host modules, accept cache file option, or specification as blank.
2967 case "${cache_file}" in
2968 "") # empty
2969   cache_file_option="" ;;
2970 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2971   cache_file_option="--cache-file=${cache_file}" ;;
2972 *) # relative path
2973   cache_file_option="--cache-file=../${cache_file}" ;;
2974 esac
2975
2976 # Host dirs don't like to share a cache file either, horribly enough.
2977 # This seems to be due to autoconf 2.5x stupidity.
2978 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2979
2980 target_configargs="$target_configargs ${tbaseargs}"
2981
2982 # Passing a --with-cross-host argument lets the target libraries know
2983 # whether they are being built with a cross-compiler or being built
2984 # native.  However, it would be better to use other mechanisms to make the
2985 # sorts of decisions they want to make on this basis.  Please consider
2986 # this option to be deprecated.  FIXME.
2987 if test x${is_cross_compiler} = xyes ; then
2988   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2989 fi
2990
2991 # Special user-friendly check for native x86_64-linux build, if
2992 # multilib is not explicitly enabled.
2993 case "$target:$have_compiler:$host:$target:$enable_multilib" in
2994   x86_64-*linux*:yes:$build:$build:)
2995     # Make sure we have a development environment that handles 32-bit
2996     dev64=no
2997     echo "int main () { return 0; }" > conftest.c
2998     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2999     if test $? = 0 ; then
3000       if test -s conftest || test -s conftest.exe ; then
3001         dev64=yes
3002       fi
3003     fi
3004     rm -f conftest*
3005     if test x${dev64} != xyes ; then
3006       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3007     fi
3008     ;;
3009 esac
3010
3011 # Default to --enable-multilib.
3012 if test x${enable_multilib} = x ; then
3013   target_configargs="--enable-multilib ${target_configargs}"
3014 fi
3015
3016 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3017 # changed from the earlier setting of with_newlib.
3018 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3019   target_configargs="--with-newlib ${target_configargs}"
3020 fi
3021
3022 # Different target subdirs use different values of certain variables
3023 # (notably CXX).  Worse, multilibs use *lots* of different values.
3024 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3025 # it doesn't automatically accept command-line overrides of them.
3026 # This means it's not safe for target subdirs to share a cache file,
3027 # which is disgusting, but there you have it.  Hopefully this can be
3028 # fixed in future.  It's still worthwhile to use a cache file for each
3029 # directory.  I think.
3030
3031 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3032 # We need to pass --target, as newer autoconf's requires consistency
3033 # for target_alias and gcc doesn't manage it consistently.
3034 target_configargs="--cache-file=./config.cache ${target_configargs}"
3035
3036 FLAGS_FOR_TARGET=
3037 case " $target_configdirs " in
3038  *" newlib "*)
3039   case " $target_configargs " in
3040   *" --with-newlib "*)
3041    case "$target" in
3042     *-cygwin*)
3043       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3044       ;;
3045    esac
3046
3047    # If we're not building GCC, don't discard standard headers.
3048    if test -d ${srcdir}/gcc; then
3049      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3050
3051      if test "${build}" != "${host}"; then
3052        # On Canadian crosses, CC_FOR_TARGET will have already been set
3053        # by `configure', so we won't have an opportunity to add -Bgcc/
3054        # to it.  This is right: we don't want to search that directory
3055        # for binaries, but we want the header files in there, so add
3056        # them explicitly.
3057        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3058
3059        # Someone might think of using the pre-installed headers on
3060        # Canadian crosses, in case the installed compiler is not fully
3061        # compatible with the compiler being built.  In this case, it
3062        # would be better to flag an error than risking having
3063        # incompatible object files being constructed.  We can't
3064        # guarantee that an error will be flagged, but let's hope the
3065        # compiler will do it, when presented with incompatible header
3066        # files.
3067      fi
3068    fi
3069
3070    case "${target}-${is_cross_compiler}" in
3071    i[[3456789]]86-*-linux*-no)
3072       # Here host == target, so we don't need to build gcc,
3073       # so we don't want to discard standard headers.
3074       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3075       ;;
3076    *)
3077       # If we're building newlib, use its generic headers last, but search
3078       # for any libc-related directories first (so make it the last -B
3079       # switch).
3080       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3081
3082       # If we're building libgloss, find the startup file, simulator library
3083       # and linker script.
3084       case " $target_configdirs " in
3085         *" libgloss "*)
3086         # Look for startup file, simulator library and maybe linker script.
3087         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3088         # Look for libnosys.a in case the target needs it.
3089         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3090         # Most targets have the linker script in the source directory.
3091         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3092         ;;
3093       esac
3094       ;;
3095    esac
3096    ;;
3097   esac
3098   ;;
3099 esac
3100
3101 case "$target" in
3102   x86_64-*mingw* | *-w64-mingw*)
3103   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3104   # however, use a symlink named 'mingw' in ${prefix} .
3105     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3106     ;;
3107   *-mingw*)
3108   # MinGW can't be handled as Cygwin above since it does not use newlib.
3109     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3110     ;;
3111 esac
3112
3113 # Allow the user to override the flags for
3114 # our build compiler if desired.
3115 if test x"${build}" = x"${host}" ; then
3116   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3117   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3118   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3119 fi
3120
3121 # On Canadian crosses, we'll be searching the right directories for
3122 # the previously-installed cross compiler, so don't bother to add
3123 # flags for directories within the install tree of the compiler
3124 # being built; programs in there won't even run.
3125 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3126   # Search for pre-installed headers if nothing else fits.
3127   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3128 fi
3129
3130 if test "x${use_gnu_ld}" = x &&
3131    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3132   # Arrange for us to find uninstalled linker scripts.
3133   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3134 fi
3135
3136 # Search for other target-specific linker scripts and such.
3137 case "${target}" in
3138   mep*)
3139     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3140     ;;
3141 esac
3142
3143 # Makefile fragments.
3144 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3145 do
3146   eval fragval=\$$frag
3147   if test $fragval != /dev/null; then
3148     eval $frag=${srcdir}/$fragval
3149   fi
3150 done
3151 AC_SUBST_FILE(host_makefile_frag)
3152 AC_SUBST_FILE(target_makefile_frag)
3153 AC_SUBST_FILE(alphaieee_frag)
3154 AC_SUBST_FILE(ospace_frag)
3155
3156 # Miscellanea: directories, flags, etc.
3157 AC_SUBST(RPATH_ENVVAR)
3158 AC_SUBST(GCC_SHLIB_SUBDIR)
3159 AC_SUBST(tooldir)
3160 AC_SUBST(build_tooldir)
3161 AC_SUBST(CONFIGURE_GDB_TK)
3162 AC_SUBST(GDB_TK)
3163 AC_SUBST(INSTALL_GDB_TK)
3164
3165 # Build module lists & subconfigure args.
3166 AC_SUBST(build_configargs)
3167 AC_SUBST(build_configdirs)
3168
3169 # Host module lists & subconfigure args.
3170 AC_SUBST(host_configargs)
3171 AC_SUBST(configdirs)
3172 AC_SUBST(target_configdirs)
3173
3174 # Target module lists & subconfigure args.
3175 AC_SUBST(target_configargs)
3176
3177
3178 # Build tools.
3179 AC_SUBST(AR_FOR_BUILD)
3180 AC_SUBST(AS_FOR_BUILD)
3181 AC_SUBST(CC_FOR_BUILD)
3182 AC_SUBST(CFLAGS_FOR_BUILD)
3183 AC_SUBST(CXXFLAGS_FOR_BUILD)
3184 AC_SUBST(CXX_FOR_BUILD)
3185 AC_SUBST(DLLTOOL_FOR_BUILD)
3186 AC_SUBST(GCJ_FOR_BUILD)
3187 AC_SUBST(GFORTRAN_FOR_BUILD)
3188 AC_SUBST(GOC_FOR_BUILD)
3189 AC_SUBST(LDFLAGS_FOR_BUILD)
3190 AC_SUBST(LD_FOR_BUILD)
3191 AC_SUBST(NM_FOR_BUILD)
3192 AC_SUBST(RANLIB_FOR_BUILD)
3193 AC_SUBST(WINDMC_FOR_BUILD)
3194 AC_SUBST(WINDRES_FOR_BUILD)
3195
3196 # Generate default definitions for YACC, M4, LEX and other programs that run
3197 # on the build machine.  These are used if the Makefile can't locate these
3198 # programs in objdir.
3199 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3200
3201 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3202 case " $build_configdirs " in
3203   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3204 esac
3205
3206 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3207 case " $build_configdirs " in
3208   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3209 esac
3210
3211 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3212 case " $build_configdirs " in
3213   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3214 esac
3215
3216 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3217 case " $build_configdirs " in
3218   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3219   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3220 esac
3221
3222 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3223 case " $build_configdirs " in
3224   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3225 esac
3226
3227 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3228 case " $build_configdirs " in
3229   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3230   *)
3231 changequote(,)
3232     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3233     # higher, else we use the "missing" dummy.
3234     if ${MAKEINFO} --version \
3235        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3236       :
3237     else
3238       MAKEINFO="$MISSING makeinfo"
3239     fi
3240     ;;
3241 changequote([,])
3242 esac
3243
3244 # FIXME: expect and dejagnu may become build tools?
3245
3246 AC_CHECK_PROGS(EXPECT, expect, expect)
3247 case " $configdirs " in
3248   *" expect "*)
3249     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3250     ;;
3251 esac
3252
3253 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3254 case " $configdirs " in
3255   *" dejagnu "*)
3256     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3257     ;;
3258 esac
3259
3260
3261 # Host tools.
3262 NCN_STRICT_CHECK_TOOLS(AR, ar)
3263 NCN_STRICT_CHECK_TOOLS(AS, as)
3264 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3265 NCN_STRICT_CHECK_TOOLS(LD, ld)
3266 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3267 NCN_STRICT_CHECK_TOOLS(NM, nm)
3268 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3269 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3270 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3271 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3272 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3273 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3274 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3275 AC_SUBST(CC)
3276 AC_SUBST(CXX)
3277 AC_SUBST(CFLAGS)
3278 AC_SUBST(CXXFLAGS)
3279
3280 # Target tools.
3281 AC_ARG_WITH([build-time-tools],
3282   [AS_HELP_STRING([--with-build-time-tools=PATH],
3283                   [use given path to find target tools during the build])],
3284   [case x"$withval" in
3285      x/*) ;;
3286      *)
3287        with_build_time_tools=
3288        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3289        ;;
3290    esac],
3291   [with_build_time_tools=])
3292
3293 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3294 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3295 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3296 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3297 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3298 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3299
3300 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3301 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3302 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3303 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3304 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3305 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3306 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3307 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3308 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3309 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3310 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3311 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3312 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3313
3314 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3315
3316 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3317 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3318 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3319 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3320 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3321                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3322                 c++)
3323 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3324                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3325                 c++)
3326 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3327 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3328 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3329                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3330 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3331                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3332 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3333 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3334 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3335 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3336 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3337 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3338 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3339 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3340 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3341 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3342
3343 AC_SUBST(FLAGS_FOR_TARGET)
3344 AC_SUBST(RAW_CXX_FOR_TARGET)
3345
3346 # Certain tools may need extra flags.
3347 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3348 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3349 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3350
3351 # When building target libraries, except in a Canadian cross, we use
3352 # the same toolchain as the compiler we just built.
3353 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3354 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3355 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3356 if test $host = $build; then
3357   case " $configdirs " in
3358     *" gcc "*)
3359       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3360       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3361       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3362       ;;
3363   esac
3364 fi
3365
3366 AC_SUBST(COMPILER_AS_FOR_TARGET)
3367 AC_SUBST(COMPILER_LD_FOR_TARGET)
3368 AC_SUBST(COMPILER_NM_FOR_TARGET)
3369
3370 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3371 AC_ARG_ENABLE(maintainer-mode,
3372 [AS_HELP_STRING([--enable-maintainer-mode],
3373                 [enable make rules and dependencies not useful
3374                  (and sometimes confusing) to the casual installer])],
3375       USE_MAINTAINER_MODE=$enableval,
3376       USE_MAINTAINER_MODE=no)
3377 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3378 AC_SUBST(MAINTAINER_MODE_TRUE)
3379 AC_SUBST(MAINTAINER_MODE_FALSE)
3380 if test "$USE_MAINTAINER_MODE" = yes; then
3381   MAINTAINER_MODE_TRUE=
3382   MAINTAINER_MODE_FALSE='#'
3383 else
3384   MAINTAINER_MODE_TRUE='#'
3385   MAINTAINER_MODE_FALSE=
3386 fi
3387 MAINT=$MAINTAINER_MODE_TRUE
3388 AC_SUBST(MAINT)dnl
3389
3390 # ---------------------
3391 # GCC bootstrap support
3392 # ---------------------
3393
3394 # Stage specific cflags for build.
3395 stage1_cflags="-g"
3396 case $build in
3397   vax-*-*)
3398     case ${GCC} in
3399       yes) stage1_cflags="-g -Wa,-J" ;;
3400       *) stage1_cflags="-g -J" ;;
3401     esac ;;
3402 esac
3403
3404 AC_SUBST(stage1_cflags)
3405
3406 # Enable --enable-checking in stage1 of the compiler.
3407 AC_ARG_ENABLE(stage1-checking,
3408 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3409                 [choose additional checking for stage1 of the compiler])],
3410 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3411 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3412   # For --disable-checking or implicit --enable-checking=release, avoid
3413   # setting --enable-checking=gc in the default stage1 checking for LTO
3414   # bootstraps.  See PR62077.
3415   case $BUILD_CONFIG in
3416     *lto*)
3417       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3418     *)
3419       stage1_checking=--enable-checking=yes,types;;
3420   esac
3421   if test "x$enable_checking" = x && \
3422      test -d ${srcdir}/gcc && \
3423      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3424     stage1_checking=--enable-checking=yes,types,extra
3425   fi
3426 else
3427   stage1_checking=--enable-checking=$enable_checking,types
3428 fi])
3429 AC_SUBST(stage1_checking)
3430
3431 # Enable -Werror in bootstrap stage2 and later.
3432 AC_ARG_ENABLE(werror,
3433 [AS_HELP_STRING([--enable-werror],
3434                 [enable -Werror in bootstrap stage2 and later])], [],
3435 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3436   enable_werror=yes
3437 else
3438   enable_werror=no
3439 fi])
3440 case ${enable_werror} in
3441   yes) stage2_werror_flag="--enable-werror-always" ;;
3442   *) stage2_werror_flag="" ;;
3443 esac
3444 AC_SUBST(stage2_werror_flag)
3445
3446 # Enable --enable-host-shared.
3447 AC_ARG_ENABLE(host-shared,
3448 [AS_HELP_STRING([--enable-host-shared],
3449                 [build host code as shared libraries])],
3450 [host_shared=$enableval], [host_shared=no])
3451 AC_SUBST(host_shared)
3452
3453 # PR jit/64780: Require the user to explicitly specify
3454 # --enable-host-shared if the jit is enabled, hinting
3455 # that they might want to do a separate configure/build of
3456 # the jit, to avoid users from slowing down the rest of the
3457 # compiler by enabling the jit.
3458 if test ${host_shared} = "no" ; then
3459   case "${enable_languages}" in
3460     *jit*)
3461       AC_MSG_ERROR([
3462 Enabling language "jit" requires --enable-host-shared.
3463
3464 --enable-host-shared typically slows the rest of the compiler down by
3465 a few %, so you must explicitly enable it.
3466
3467 If you want to build both the jit and the regular compiler, it is often
3468 best to do this via two separate configure/builds, in separate
3469 directories, to avoid imposing the performance cost of
3470 --enable-host-shared on the regular compiler.])
3471       ;;
3472     *)
3473       ;;
3474   esac
3475 fi
3476
3477 # Specify what files to not compare during bootstrap.
3478
3479 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3480 case "$target" in
3481   hppa*64*-*-hpux*) ;;
3482   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3483   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3484 esac
3485 AC_SUBST(compare_exclusions)
3486
3487 AC_CONFIG_FILES([Makefile],
3488   [sed "$extrasub_build" Makefile |
3489    sed "$extrasub_host" |
3490    sed "$extrasub_target" > mf$$
3491    mv -f mf$$ Makefile],
3492   [extrasub_build="$extrasub_build"
3493    extrasub_host="$extrasub_host"
3494    extrasub_target="$extrasub_target"])
3495 AC_OUTPUT