PATCH/RFA : texinfo bootstrap failure

[Zack Weinberg]

On Mon, Apr 17, 2000 at 02:07:26AM +0200, Philipp Thomas wrote:
> * Jeffrey A . Law (law@cygnus.com) [20000409 15:31]:
> 
> > ie, what happens when the GCC build tries to run makeinfo and it doesn't
> > exist, or is too old to properly handle the gcc texinfo files.
> 
> Hmm, so what would be needed is an autoconf test for makeinfo and its
> version and possibly a config option a la --with-makeinfo= to let the user
> specify a certain version to use, right? 
> 
> I'll see if I can come up with something that'll let us get rid of texinfo
> once and for all.  Of cause the makefiles would also need to be modified to
> make use of that info.

BTW, some time ago I tried deleting the texinfo subdir from my
checked-out source tree.  Everything went just fine - the toplevel
makefile didn't blink, and the gcc makefile picked up makeinfo from
my $PATH without any help.  I have a brand new makeinfo, so that works
for me.

glibc has a check in its configure.in you might be able to use:

AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
  [GNU texinfo.* \([0-9][0-9.]*\)],
  [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t
)
test -n "$aux_missing" && AC_MSG_WARN([
*** An auxiliary program is missing or too old;
*** some features will be disabled.
*** Check the INSTALL file for required versions.])

where AC_CHECK_PROG_VER is defined in aclocal.m4 as:

dnl Locate a program and check that its version is acceptable.
dnl AC_PROG_CHECK_VER(var, namelist, version-switch,
dnl                   [version-extract-regexp], version-glob [, do-if-fail])
AC_DEFUN(AC_CHECK_PROG_VER,
[AC_CHECK_PROGS([$1], [$2])
if test -z "[$]$1"; then
  ac_verc_fail=yes
else
  # Found it, now check the version.
  AC_MSG_CHECKING([version of [$]$1])
changequote(<<,>>)dnl
  ac_prog_version=`<<$>>$1 $3 2>&1 ifelse(<<$4>>,,,
                   <<| sed -n 's/^.*patsubst(<<$4>>,/,\/).*$/\1/p'>>)`
  case $ac_prog_version in
    '') ac_prog_version="v. ?.??, bad"; ac_verc_fail=yes;;
    <<$5>>)
changequote([,])dnl
       ac_prog_version="$ac_prog_version, ok"; ac_verc_fail=no;;
    *) ac_prog_version="$ac_prog_version, bad"; ac_verc_fail=yes;;

  esac
  AC_MSG_RESULT([$ac_prog_version])
fi
ifelse([$6],,,
[if test $ac_verc_fail = yes; then
  $6
fi])
])

zw