Re: 3_0-branch bootstrap failure on i686-pc-linux-gnu

[Alexandre Oliva <aoliva at redhat dot com>]

On May  3, 2001, Alexandre Oliva <aoliva@redhat.com> wrote:

> Please try this patch (note that you'll have to rebuild
> zlib/configure with autoconf) and let me know if it works for you,
> then I'll check it in.

It wouldn't work.  This one probably will, but will require running
aclocal, autoconf and automake.  Please let me know if it does work,
indeed.  Thanks in advance,

Index: zlib/ChangeLog.gcj
from  Alexandre Oliva  <aoliva@redhat.com>

	* acinclude.m4: Use ../libtool.m4.
	* configure.in: Use ${zlib_basedir}/.. for AC_CONFIG_AUX_DIR.
	* acinclude.m4, configure, Makefile.in: Rebuilt.

Index: zlib/acinclude.m4
===================================================================
RCS file: /cvs/gcc/egcs/zlib/acinclude.m4,v
retrieving revision 1.2
diff -u -p -r1.2 acinclude.m4
--- zlib/acinclude.m4 1999/09/28 20:37:20 1.2
+++ zlib/acinclude.m4 2001/05/03 20:19:31
@@ -37,3 +37,12 @@ else
   test "${CFLAGS+set}" = set || CFLAGS="-g"
 fi
 ])
+
+sinclude(../libtool.m4)
+dnl The lines below arrange for aclocal not to bring libtool.m4
+dnl AM_PROG_LIBTOOL into aclocal.m4, while still arranging for automake
+dnl to add a definition of LIBTOOL to Makefile.in.
+ifelse(yes,no,[
+AC_DEFUN([AM_PROG_LIBTOOL],)
+AC_SUBST(LIBTOOL)
+])
Index: zlib/configure.in
===================================================================
RCS file: /cvs/gcc/egcs/zlib/configure.in,v
retrieving revision 1.9
diff -u -p -r1.9 configure.in
--- zlib/configure.in 2000/10/25 18:07:29 1.9
+++ zlib/configure.in 2001/05/03 20:19:31
@@ -1,13 +1,33 @@
 dnl Process this with autoconf to create configure
 
 AC_INIT(zlib.h)
+
+dnl We may get other options which we dont document:
+dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
+
+if test "x[$]{with_target_subdir}" != x && \
+   test "[$]{srcdir}" = "."; then
+  if test "[$]{with_target_subdir}" != "."; then
+    zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}../"
+  else
+    zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}"
+  fi
+else
+  zlib_basedir="[$]{srcdir}/"
+fi
+AC_SUBST(zlib_basedir)
+AC_CONFIG_AUX_DIR($zlib_basedir..)
+if :; then :; else
+  # This overrides the previous occurrence for automake, but not for
+  # autoconf, which is exactly what we want.
+  AC_CONFIG_AUX_DIR(..)
+fi
+
 AC_CANONICAL_SYSTEM
 AM_INIT_AUTOMAKE(zlib, 1.1.3)
 
 AM_MAINTAINER_MODE
 
-AC_CONFIG_AUX_DIR(..)
-
 dnl We use these options to decide which functions to include.
 AC_ARG_WITH(target-subdir,
 [  --with-target-subdir=SUBDIR
@@ -23,21 +43,6 @@ AC_ARG_ENABLE(multilib,
   no)  multilib=no ;;
   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  esac], [test -z "$with_target_subdir" && multilib=no || multilib=yes])dnl
-
-dnl We may get other options which we dont document:
-dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
-
-if test "x[$]{with_target_subdir}" != x && \
-   test "[$]{srcdir}" = "."; then
-  if test "[$]{with_target_subdir}" != "."; then
-    zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}../"
-  else
-    zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}"
-  fi
-else
-  zlib_basedir="[$]{srcdir}/"
-fi
-AC_SUBST(zlib_basedir)
 
 AC_ARG_WITH(system-zlib,
 [  --with-system-zlib      use installed libz])

-- 
Alexandre Oliva   Enjoy Guarana', see http://www.ic.unicamp.br/~oliva/
Red Hat GCC Developer                  aoliva@{cygnus.com, redhat.com}
CS PhD student at IC-Unicamp        oliva@{lsd.ic.unicamp.br, gnu.org}
Free Software Evangelist    *Please* write to mailing lists, not to me