This is the mail archive of the gcc-patches@gcc.gnu.org mailing list for the GCC project.


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]
Other format: [Raw text]

config/tls.m4: Use correct cache IDs


Hello,

 As required by autoconf (and documented in the manual), all cache ID 
variables must have a _cv_ part included in their names.  Failing this, a 
variable is not saved to config.cache at all.  There is also a convention 
defined there to follow.

 We do not follow these rules in config/tls.m4 and therefore the variables 
defined there are not cached.  Here is an obvious fix, which works for me 
(tested for the alpha-linux-gnu host).

config/:
2007-10-15  Maciej W. Rozycki  <macro@linux-mips.org>

	* tls.m4 (GCC_CHECK_TLS): Rename have_tls to gcc_cv_have_tls.
	(GCC_CHECK_CC_TLS): Rename have_cc_tls to gcc_cv_have_cc_tls.

libgomp/:
2007-10-15  Maciej W. Rozycki  <macro@linux-mips.org>

	* configure: Regenerate.

libjava/:
2007-10-15  Maciej W. Rozycki  <macro@linux-mips.org>

	* configure: Regenerate.

libmudflap/:
2007-10-15  Maciej W. Rozycki  <macro@linux-mips.org>

	* configure: Regenerate.

 I am not sure whether the ChangeLog entries for the other directories 
should not be more verbose, given there is no easily visible link to the 
change to config/tls.m4.  I would find it quite reasonable to put 
"Regenerate following changes to ../config/tls.m4." or suchlike there, 
though I cannot immediately see a precedent.  Please let me know if I 
should do so anyway.

 Other than that, OK to apply?

  Maciej

gcc-4.3.0-20071011-cv-tls.patch
diff -up --recursive --new-file gcc-4.3.0-20071011.macro/config/tls.m4 gcc-4.3.0-20071011/config/tls.m4
--- gcc-4.3.0-20071011.macro/config/tls.m4	2007-07-07 06:55:34.000000000 +0000
+++ gcc-4.3.0-20071011/config/tls.m4	2007-10-12 22:23:59.000000000 +0000
@@ -2,7 +2,7 @@ dnl Check whether the target supports TL
 AC_DEFUN([GCC_CHECK_TLS], [
   GCC_ENABLE(tls, yes, [], [Use thread-local storage])
   AC_CACHE_CHECK([whether the target supports thread-local storage],
-		 have_tls, [
+		 gcc_cv_have_tls, [
     AC_RUN_IFELSE([__thread int a; int b; int main() { return a = b; }],
       [dnl If the test case passed with dynamic linking, try again with
        dnl static linking, but only if static linking is supported (not
@@ -11,10 +11,10 @@ AC_DEFUN([GCC_CHECK_TLS], [
       LDFLAGS="-static $LDFLAGS"
       AC_LINK_IFELSE([int main() { return 0; }],
 	AC_RUN_IFELSE([__thread int a; int b; int main() { return a = b; }],
-		      [have_tls=yes], [have_tls=no],[]),
-	[have_tls=yes])
+		      [gcc_cv_have_tls=yes], [gcc_cv_have_tls=no],[]),
+	[gcc_cv_have_tls=yes])
       LDFLAGS="$chktls_save_LDFLAGS"
-      if test $have_tls = yes; then
+      if test $gcc_cv_have_tls = yes; then
 	dnl So far, the binutils and the compiler support TLS.
 	dnl Also check whether the libc supports TLS, i.e. whether a variable
 	dnl with __thread linkage has a different address in different threads.
@@ -58,18 +58,18 @@ AC_DEFUN([GCC_CHECK_TLS], [
 		if (pthread_join (thread, &thread_retval))
 		  return 0;
 		return (a_in_other_thread == a_in_main_thread);])],
-	     [have_tls=yes], [have_tls=no], [])
+	     [gcc_cv_have_tls=yes], [gcc_cv_have_tls=no], [])
 	  CFLAGS="$chktls_save_CFLAGS"
 	fi
       fi],
-      [have_tls=no],
+      [gcc_cv_have_tls=no],
       [dnl This is the cross-compiling case. Assume libc supports TLS if the
        dnl binutils and the compiler do.
        AC_LINK_IFELSE([__thread int a; int b; int main() { return a = b; }],
-		      [have_tls=yes], [have_tls=no])
+		      [gcc_cv_have_tls=yes], [gcc_cv_have_tls=no])
       ]
     )])
-  if test "$enable_tls $have_tls" = "yes yes"; then
+  if test "$enable_tls $gcc_cv_have_tls" = "yes yes"; then
     AC_DEFINE(HAVE_TLS, 1,
 	      [Define to 1 if the target supports thread-local storage.])
   fi])
@@ -78,11 +78,11 @@ dnl Check whether the target assembler s
 AC_DEFUN([GCC_CHECK_CC_TLS], [
   GCC_ENABLE(tls, yes, [], [Use thread-local storage])
   AC_CACHE_CHECK([whether the target asssembler upports thread-local storage],
-		 have_cc_tls, [
+		 gcc_cv_have_cc_tls, [
     AC_COMPILE_IFELSE([__thread int a; int b; int main() { return a = b; }],
-      [have_cc_tls=yes], [have_cc_tls=no])]
+      [gcc_cv_have_cc_tls=yes], [gcc_cv_have_cc_tls=no])]
     )])
-  if test "$enable_tls $have_cc_tls" = "yes yes"; then
+  if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
     AC_DEFINE(HAVE_CC_TLS, 1,
 	      [Define to 1 if the target assembler supports thread-local storage.])
   fi])


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]