texinfo/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id: configure.in,v 1.7 1998/03/26 10:30:41 law Exp $
   3 dnl
   4 AC_INIT(makeinfo/makeinfo.c)
   5 AC_PREREQ(2.12)dnl Minimum Autoconf version required.
   6 AM_CONFIG_HEADER(config.h)
   7
   8 AM_INIT_AUTOMAKE([texinfo], [3.12])
   9
  10 dnl Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_GCC_TRADITIONAL
  13 EGCS_PROG_INSTALL
  14 AC_PROG_RANLIB
  15
  16 # We do this for the sake of a more helpful warning in doc/Makefile.
  17 TEXMF='$(datadir)/texmf'
  18 AC_CHECK_PROG(TEXCONFIG, texconfig, true, false)
  19 $TEXCONFIG && eval `texconfig conf </dev/null | grep '^TEXMF='`
  20 AC_SUBST(TEXMF)
  21
  22 AC_ISC_POSIX
  23 AC_MINIX
  24
  25 dnl CYGNUS LOCAL: Add AM_MAINTAINER_MODE and AM_EXEEXT
  26 AM_MAINTAINER_MODE
  27 AM_EXEEXT
  28
  29 dnl Checks for libraries.
  30 AC_CHECK_HEADERS(zlib.h, [AC_CHECK_LIB(z, gzdopen)])
  31
  32 # Needed on sysV68 for sigblock, sigsetmask.  But check for it in libc first.
  33 AC_CHECK_FUNC(sigblock, , AC_CHECK_LIB(bsd, sigblock))
  34
  35 # Some GNU/Linux systems (e.g., SuSE 4.3, 1996) don't have curses, but
  36 # rather ncurses.  So we check for it.
  37 TERMLIBS=
  38 for termlib in ncurses curses termcap terminfo termlib ; do
  39    AC_CHECK_LIB(${termlib}, tputs,
  40      [TERMLIBS="${TERMLIBS} -l${termlib}"; break])
  41 done
  42 AC_SUBST(TERMLIBS)
  43
  44 dnl Checks for header files.
  45 dnl Do not use <ncurses/termcap.h> unless we're linking with ncurses.
  46 if test "x$termlib" = xncurses; then
  47   dnl Use AC_CHECK_HEADERS so the HAVE_*_H symbol gets defined.
  48   AC_CHECK_HEADERS(ncurses/termcap.h)
  49 fi
  50 AC_HEADER_STDC
  51 AC_CHECK_HEADERS(fcntl.h pwd.h string.h strings.h termcap.h termio.h \
  52   termios.h unistd.h \
  53   sys/fcntl.h sys/file.h sys/ptem.h sys/time.h sys/ttold.h sys/wait.h)
  54
  55 dnl Checks for typedefs, structures, and compiler characteristics.
  56 AC_TYPE_OFF_T
  57 AC_TYPE_SIGNAL
  58 AC_C_CONST
  59 AC_STRUCT_TM
  60
  61 dnl Checks for library functions.
  62 AC_FUNC_ALLOCA
  63 AC_FUNC_VPRINTF
  64 if test "$ac_cv_c_cross" = no; then
  65   AC_FUNC_SETVBUF_REVERSED
  66 fi
  67 AC_CHECK_FUNCS(setvbuf getcwd memset bzero strchr strcasecmp \
  68   sigprocmask sigsetmask)
  69 dnl strcasecmp, strerror, xmalloc, xrealloc, probably others should be added.
  70 AC_REPLACE_FUNCS(memcpy memmove strdup strerror)
  71
  72 dnl Set of available languages and i18n macros.
  73 ALL_LINGUAS="de fr"
  74 AM_GNU_GETTEXT
  75 AC_LINK_FILES($nls_cv_header_libgt, $nls_cv_header_intl)
  76
  77 AC_OUTPUT([Makefile             \
  78            doc/Makefile         \
  79            info/Makefile        \
  80            intl/Makefile        \
  81            lib/Makefile         \
  82            makeinfo/Makefile    \
  83            po/Makefile.in       \
  84            util/Makefile        \
  85            ],
  86           [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in >po/Makefile])