libstdc++-v3/testsuite/lib/libstdc++.exp

   1 # libstdc++ "tool init file" for DejaGNU
   2
   3 # Copyright (C) 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18
  19
  20 # Define callbacks and load other libraries.  This file is loaded relatively
  21 # early, and before any other file we write ourselves.  "load_lib" will
  22 # find anything in the DejaGNU installation tree, or in our lib directory.
  23 # "load_gcc_lib" will search the core compiler's .exp collection instead.
  24 #
  25 # The naming rule is that dg.exp looks for "tool-" and runtest.exp looks
  26 # for "tool_" when finding callbacks.  Utility routines we define for
  27 # our callbacks begin with "v3-".
  28 #
  29 # libstdc++_* callbacks we don't define, but could:
  30 # ..._option_help           prints additional --help output
  31 # ..._option_proc (--foo)   process our own options
  32 # ..._init (normal.exp)     called once per test file
  33 # ..._finish                bracketing function for libstdc++_init
  34 # ...-dg-prune              removing output text, see top of system dg.exp
  35 #
  36 # Useful hook:  if ${hostname}_init exists, it will be called, almost
  37 # the last thing before testing begins.  This can be defined in, e.g.,
  38 # ~/.dejagnurc or $DEJAGNU.
  39
  40 proc load_gcc_lib { filename } {
  41     global srcdir
  42     load_file $srcdir/../../gcc/testsuite/lib/$filename
  43 }
  44
  45 # system routines
  46 load_lib dg.exp
  47 load_lib libgloss.exp
  48 # compiler routines, then ours
  49 load_gcc_lib target-supports.exp
  50 load_gcc_lib target-supports-dg.exp
  51 load_lib prune.exp
  52 load_lib dg-options.exp
  53 load_gcc_lib target-libpath.exp
  54 load_gcc_lib wrapper.exp
  55
  56 # Useful for debugging.  Pass the name of a variable and the verbosity
  57 # threshold (number of -v's on the command line).
  58 proc v3track { var n } {
  59     upvar $var val
  60     verbose "++ $var is $val" $n
  61 }
  62
  63 # Called by v3-init below.  "Static" to this file.
  64 proc v3-copy-files {srcfiles} {
  65     foreach f $srcfiles {
  66         if { [catch { set symlink [file readlink $f] } x] } then {
  67             remote_download target $f
  68         } else {
  69             if { [regexp "^/" "$symlink"] } then {
  70                 remote_download target $symlink
  71             } else {
  72                 set dirname [file dirname $f]
  73                 remote_download target $dirname/$symlink
  74             }
  75         }
  76     }
  77 }
  78
  79 # Called once, during runtest.exp setup.
  80 proc libstdc++_init { testfile } {
  81     global env
  82     global srcdir blddir objdir tool_root_dir
  83     global cxx cxxflags
  84     global includes
  85     global gluefile wrap_flags
  86     global ld_library_path
  87     global target_triplet
  88
  89     # We set LC_ALL and LANG to C so that we get the same error messages as expected.
  90     setenv LC_ALL C
  91     setenv LANG C
  92
  93     set blddir [lookfor_file [get_multilibs] libstdc++-v3]
  94     set flags_file "${blddir}/scripts/testsuite_flags"
  95     v3track flags_file 2
  96
  97     # If a test doesn't have special options, use DEFAULT_CXXFLAGS.
  98     # Use this variable if the behavior
  99     #   1) only applies to libstdc++ testing
 100     #   2) might need to be negated
 101     # In particular, some tests have to be run without precompiled
 102     # headers, or without assertions.
 103     global DEFAULT_CXXFLAGS
 104     if ![info exists DEFAULT_CXXFLAGS] then {
 105         # Set up includes for stdc++.h.gch, the precompiled header file.
 106         if { [file exists $flags_file] } {
 107             set cxxpchflags [exec sh $flags_file --cxxpchflags]
 108         } else {
 109             set cxxpchflags ""
 110         }
 111         set DEFAULT_CXXFLAGS " ${cxxpchflags}"
 112
 113         # Host specific goo here.
 114         if { [string match "powerpc-*-darwin*" $target_triplet] } {
 115             append DEFAULT_CXXFLAGS " -multiply_defined suppress"
 116         }
 117     }
 118     v3track DEFAULT_CXXFLAGS 2
 119
 120     # By default, we assume we want to run program images.
 121     global dg-do-what-default
 122     set dg-do-what-default run
 123
 124     # Copy any required data files.
 125     v3-copy-files [glob -nocomplain "$srcdir/data/*.tst"]
 126     v3-copy-files [glob -nocomplain "$srcdir/data/*.txt"]
 127
 128     # Locate libgcc.a so we don't need to account for different values of
 129     # SHLIB_EXT on different platforms
 130     set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
 131     if {$gccdir != ""} {
 132         set gccdir [file dirname $gccdir]
 133     }
 134     v3track gccdir 3
 135
 136     # Compute what needs to be added to the existing LD_LIBRARY_PATH.
 137     set ld_library_path ""
 138     append ld_library_path ":${gccdir}"
 139     set compiler ${gccdir}/g++
 140     if { [is_remote host] == 0 && [which $compiler] != 0 } {
 141       foreach i "[exec $compiler --print-multi-lib]" {
 142         set mldir ""
 143         regexp -- "\[a-z0-9=/\.-\]*;" $i mldir
 144         set mldir [string trimright $mldir "\;@"]
 145         if { "$mldir" == "." } {
 146           continue
 147         }
 148         if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] >= 1 } {
 149           append ld_library_path ":${gccdir}/${mldir}"
 150         }
 151       }
 152     }
 153     append ld_library_path ":${blddir}/src/.libs"
 154
 155     set_ld_library_path_env_vars
 156     if [info exists env(LD_LIBRARY_PATH)] {
 157       verbose -log "LD_LIBRARY_PATH = $env(LD_LIBRARY_PATH)"
 158     }
 159
 160     # Do a bunch of handstands and backflips for cross compiling and
 161     # finding simulators...
 162     if [is_remote host] {
 163         set header [remote_download host ${blddir}/testsuite/testsuite_hooks.h]
 164         if { $header == "" } {
 165             verbose -log "Unable to download ${blddir}/testsuite/testsuite_hooks.h to host."
 166             return "untested"
 167         }
 168       set cxx [transform "g++"]
 169       set cxxflags "-ggdb3"
 170       set includes "-I./"
 171     } else {
 172         # If we find a testsuite_flags file, we're testing in the build dir.
 173         if { [file exists $flags_file] } {
 174             set cxx [exec sh $flags_file --build-cxx]
 175             set cxxflags [exec sh $flags_file --cxxflags]
 176             set includes [exec sh $flags_file --build-includes]
 177         } else {
 178             set cxx [transform "g++"]
 179             set cxxflags "-ggdb3"
 180             set includes "-I${srcdir}"
 181         }
 182     }
 183
 184     libstdc++_maybe_build_wrapper "${objdir}/testglue.o"
 185 }
 186
 187 # Callback for cleanup routines.
 188 proc libstdc++_exit { } {
 189     global gluefile;
 190
 191     if [info exists gluefile] {
 192         file_on_build delete $gluefile;
 193         unset gluefile;
 194     }
 195 }
 196
 197 # Callback from system dg-test.
 198 proc libstdc++-dg-test { prog do_what extra_tool_flags } {
 199     # Set up the compiler flags, based on what we're going to do.
 200     switch $do_what {
 201         "preprocess" {
 202             set compile_type "preprocess"
 203             set output_file "[file rootname [file tail $prog]].i"
 204         }
 205         "compile" {
 206             set compile_type "assembly"
 207             set output_file "[file rootname [file tail $prog]].s"
 208         }
 209         "assemble" {
 210             set compile_type "object"
 211             set output_file "[file rootname [file tail $prog]].o"
 212         }
 213         "link" {
 214             set compile_type "executable"
 215             set output_file "./[file rootname [file tail $prog]].exe"
 216         }
 217         "run" {
 218             set compile_type "executable"
 219             # FIXME: "./" is to cope with "." not being in $PATH.
 220             # Should this be handled elsewhere?
 221             # YES.
 222             set output_file "./[file rootname [file tail $prog]].exe"
 223             # This is the only place where we care if an executable was
 224             # created or not.  If it was, dg.exp will try to run it.
 225             remote_file build delete $output_file;
 226         }
 227         default {
 228             perror "$do_what: not a valid dg-do keyword"
 229             return ""
 230         }
 231     }
 232     set options ""
 233     if { $extra_tool_flags != "" } {
 234         lappend options "additional_flags=$extra_tool_flags"
 235     }
 236
 237     # There is a libstdc++_compile made for us by default (via the tool-
 238     # and-target file), but the defaults are lacking in goodness.
 239     set comp_output [v3_target_compile "$prog" "$output_file" "$compile_type" $options];
 240     set comp_output [ prune_g++_output $comp_output ];
 241
 242     return [list $comp_output $output_file]
 243 }
 244
 245 # Called from libstdc++-dg-test above.  Calls back into system's
 246 # target_compile to actually do the work.
 247 proc v3_target_compile { source dest type options } {
 248     global gluefile
 249     global wrap_flags
 250     global cxx
 251     global cxxflags
 252     global includes
 253     global blddir
 254
 255     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
 256         lappend options "libs=${gluefile}"
 257         lappend options "ldflags=${wrap_flags}"
 258     }
 259
 260     set cxx_final $cxx
 261     set cxxlibglossflags  [libgloss_link_flags]
 262     set cxx_final [concat $cxx_final $cxxlibglossflags]
 263     set cxx_final [concat $cxx_final $cxxflags]
 264     set cxx_final [concat $cxx_final $includes]
 265
 266     lappend options "compiler=$cxx_final"
 267
 268     # Picks up the freshly-built testsuite library corresponding to the
 269     # multilib under test.
 270     lappend options "ldflags=-L${blddir}/testsuite"
 271     lappend options "libs=-lv3test"
 272
 273     return [target_compile $source $dest $type $options]
 274 }
 275
 276
 277 # Called once, from libstdc++/normal.exp.
 278 proc v3-list-tests { filename } {
 279     global srcdir
 280     global blddir
 281
 282     set tests_file "${blddir}/testsuite/${filename}"
 283     set sfiles ""
 284
 285     verbose -log "In v3-list-tests"
 286     verbose -log "blddir = ${blddir}"
 287     verbose -log "tests_file = $tests_file"
 288
 289     # If there is a testsuite_file, use it.
 290     if { [file exists $tests_file] } {
 291         set f [open $tests_file]
 292         while { ! [eof $f] } {
 293             set t [gets $f]
 294             if { [string length "$t"] != 0 } {
 295                 lappend sfiles  ${srcdir}/${t}
 296             }
 297         }
 298         close $f
 299     } else {
 300         verbose "cannot open $tests_file"
 301     }
 302     return $sfiles
 303 }