libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1994-2018 Free Software Foundation, Inc.
   3 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GCC.
   6 #
   7 #GCC is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 3, or (at your option)
  10 #any later version.
  11 #
  12 #GCC is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GCC; see the file COPYING3.  If not see
  19 #<http://www.gnu.org/licenses/>.
  20
  21 AC_INIT(package-unused, version-unused,, libobjc)
  22 AC_CONFIG_SRCDIR([objc/objc.h])
  23 GCC_TOPLEV_SUBDIRS
  24
  25 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  26 PACKAGE=libobjc
  27 # Version is pulled out to make it a bit easier to change using sed.
  28 VERSION=4:0:0
  29 AC_SUBST(VERSION)
  30
  31 # This works around the fact that libtool configuration may change LD
  32 # for this particular configuration, but some shells, instead of
  33 # keeping the changes in LD private, export them just because LD is
  34 # exported.
  35 ORIGINAL_LD_FOR_MULTILIBS=$LD
  36
  37 # -------
  38 # Options
  39 # -------
  40
  41 # We use these options to decide which functions to include.
  42 AC_ARG_WITH(target-subdir,
  43 [  --with-target-subdir=SUBDIR
  44                            configuring in a subdirectory])
  45 AC_ARG_WITH(cross-host,
  46 [  --with-cross-host=HOST  configuring with a cross compiler])
  47
  48 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  49 AC_ARG_ENABLE(version-specific-runtime-libs,
  50 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  51 [case "$enableval" in
  52  yes) version_specific_libs=yes ;;
  53  no)  version_specific_libs=no ;;
  54  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  55  esac],
  56 [version_specific_libs=no])
  57 AC_MSG_RESULT($version_specific_libs)
  58
  59 # -----------
  60 # Directories
  61 # -----------
  62
  63 # Find the rest of the source tree framework.
  64 AM_ENABLE_MULTILIB(, ..)
  65
  66 AC_CANONICAL_SYSTEM
  67 ACX_NONCANONICAL_TARGET
  68
  69 # Export source directory.
  70 # These need to be absolute paths, yet at the same time need to
  71 # canonicalize only relative paths, because then amd will not unmount
  72 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  73 case $srcdir in
  74   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  75   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  76 esac
  77 AC_SUBST(glibcpp_srcdir)
  78
  79 # Calculate toolexeclibdir
  80 # Also toolexecdir, though it's only used in toolexeclibdir
  81 case ${version_specific_libs} in
  82   yes)
  83     # Need the gcc compiler version to know where to install libraries
  84     # and header files if --enable-version-specific-runtime-libs option
  85     # is selected.
  86     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
  87     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  88     ;;
  89   no)
  90     if test -n "$with_cross_host" &&
  91        test x"$with_cross_host" != x"no"; then
  92       # Install a library built with a cross compiler in tooldir, not libdir.
  93       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
  94       toolexeclibdir='$(toolexecdir)/lib'
  95     else
  96       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
  97       toolexeclibdir='$(libdir)'
  98     fi
  99     multi_os_directory=`$CC -print-multi-os-directory`
 100     case $multi_os_directory in
 101       .) ;; # Avoid trailing /.
 102       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 103     esac
 104     ;;
 105 esac
 106 AC_SUBST(toolexecdir)
 107 AC_SUBST(toolexeclibdir)
 108
 109 # Figure out if we want to name the include directory and the
 110 #  library name changes differently.
 111 includedirname=include
 112 libsuffix=
 113 case "${host}" in
 114   *-darwin*)
 115     # Darwin is the only target so far that needs a different include directory.
 116     includedirname=include-gnu-runtime
 117     libsuffix=-gnu
 118     ;;
 119 esac
 120 AC_SUBST(includedirname)
 121 AC_SUBST(libsuffix)
 122
 123 AC_CONFIG_HEADERS(config.h)
 124
 125 # --------
 126 # Programs
 127 # --------
 128
 129 GCC_NO_EXECUTABLES
 130
 131 # We must force CC to /not/ be a precious variable; otherwise
 132 # the wrong, non-multilib-adjusted value will be used in multilibs.
 133 # As a side effect, we have to subst CFLAGS ourselves.
 134 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 135 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 136 AC_PROG_CC
 137 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 138
 139 # extra LD Flags which are required for targets
 140 ACX_LT_HOST_FLAGS
 141 case "${host}" in
 142   *-darwin*)
 143     # Darwin needs -single_module when linking libobjc
 144     extra_ldflags_libobjc='$(lt_host_flags) -Wl,-single_module'
 145     ;;
 146   *-cygwin*|*-mingw*)
 147     # Tell libtool to build DLLs on Windows
 148     extra_ldflags_libobjc='$(lt_host_flags)'
 149     ;;
 150 esac
 151 AC_SUBST(extra_ldflags_libobjc)
 152
 153 # Add CET specific flags if CET is enabled
 154 GCC_CET_FLAGS(CET_FLAGS)
 155 XCFLAGS="$XCFLAGS $CET_FLAGS"
 156
 157 AC_SUBST(CFLAGS)
 158 AC_SUBST(XCFLAGS)
 159
 160 AC_CHECK_TOOL(AS, as)
 161 AC_CHECK_TOOL(AR, ar)
 162 AC_CHECK_TOOL(RANLIB, ranlib, :)
 163 AC_PROG_INSTALL
 164
 165 AM_MAINTAINER_MODE
 166
 167 # Enable Win32 DLL on MS Windows - FIXME
 168 AC_LIBTOOL_WIN32_DLL
 169
 170 AC_PROG_LIBTOOL
 171
 172 AM_PROG_CC_C_O
 173
 174 AC_PROG_MAKE_SET
 175
 176 # -------
 177 # Headers
 178 # -------
 179
 180 # Sanity check for the cross-compilation case:
 181 AC_CHECK_HEADER(stdio.h,:,
 182   [AC_MSG_ERROR([Can't find stdio.h.
 183 You must have a usable C system for the target already installed, at least
 184 including headers and, preferably, the library, before you can configure
 185 the Objective C runtime system.  If necessary, install gcc now with
 186 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 187
 188 AC_HEADER_STDC
 189
 190 AC_CHECK_HEADERS(sched.h)
 191
 192 # -----------
 193 # Miscellanea
 194 # -----------
 195
 196 # Check if we have thread-local storage
 197 GCC_CHECK_TLS
 198
 199 gt_BITFIELD_TYPE_MATTERS
 200
 201 # -----------
 202 # boehm-gc
 203 # -----------
 204
 205 AC_ARG_ENABLE(objc-gc,
 206 [AS_HELP_STRING([--enable-objc-gc],
 207                 [enable use of Boehm's garbage collector with the
 208                  GNU Objective-C runtime])],,enable_objc_gc=no)
 209 AC_ARG_WITH([target-bdw-gc],
 210 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
 211                 [specify prefix directory for installed bdw-gc package.
 212                  Equivalent to --with-target-bdw-gc-include=PATH/include
 213                  plus --with-target-bdw-gc-lib=PATH/lib])])
 214 AC_ARG_WITH([target-bdw-gc-include],
 215 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
 216                 [specify directories for installed bdw-gc include files])])
 217 AC_ARG_WITH([target-bdw-gc-lib],
 218 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
 219                 [specify directories for installed bdw-gc library])])
 220
 221 case "$enable_objc_gc" in
 222 no)
 223   use_bdw_gc=no
 224   ;;
 225 *)
 226   AC_MSG_CHECKING([for bdw garbage collector])
 227   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
 228     dnl no bdw-gw options, assuming bdw-gc in default locations
 229     BDW_GC_CFLAGS=
 230     BDW_GC_LIBS="-lgc"
 231   else
 232     dnl bdw-gw options passed by configure flags
 233     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
 234       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
 235     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
 236       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
 237     else
 238       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
 239     fi
 240     mldir=`${CC-gcc} --print-multi-directory 2>/dev/null`
 241     bdw_val=
 242     if test "x$with_target_bdw_gc" != x; then
 243       for i in `echo $with_target_bdw_gc | tr ',' ' '`; do
 244         case "$i" in
 245           *=*) sd=${i%%=*}; d=${i#*=} ;;
 246           *) sd=.; d=$i ;;
 247         esac
 248         if test "$mldir" = "$sd"; then
 249           bdw_val=$d
 250         fi
 251       done
 252       if test "x$bdw_val" = x; then
 253         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc])
 254       fi
 255       bdw_inc_dir="$bdw_val/include"
 256       bdw_lib_dir="$bdw_val/lib"
 257     fi
 258     bdw_val=
 259     if test "x$with_target_bdw_gc_include" != x; then
 260       for i in `echo $with_target_bdw_gc_include | tr ',' ' '`; do
 261         case "$i" in
 262           *=*) sd=${i%%=*}; d=${i#*=} ;;
 263           *) sd=.; d=$i; fallback=$i ;;
 264         esac
 265         if test "$mldir" = "$sd"; then
 266           bdw_val=$d
 267         fi
 268       done
 269       if test "x$bdw_val" = x && test "x$bdw_inc_dir" = x && test "x$fallback" != x; then
 270         bdw_inc_dir="$fallback"
 271       elif test "x$bdw_val" = x; then
 272         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 273       else
 274         bdw_inc_dir="$bdw_val"
 275       fi
 276     fi
 277     bdw_val=
 278     if test "x$with_target_bdw_gc_lib" != x; then
 279       for i in `echo $with_target_bdw_gc_lib | tr ',' ' '`; do
 280         case "$i" in
 281           *=*) sd=${i%%=*}; d=${i#*=} ;;
 282           *) sd=.; d=$i ;;
 283         esac
 284         if test "$mldir" = "$sd"; then
 285           bdw_val=$d
 286         fi
 287       done
 288       if test "x$bdw_val" = x; then
 289         AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 290       fi
 291       bdw_lib_dir="$bdw_val"
 292     fi
 293     if test "x$bdw_inc_dir" = x; then
 294       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-include])
 295     fi
 296     if test "x$bdw_lib_dir" = x; then
 297       AC_MSG_ERROR([no multilib path ($mldir) found in --with-target-bdw-gc-lib])
 298     fi
 299     BDW_GC_CFLAGS="-I$bdw_inc_dir"
 300     if test -f $bdw_lib_dir/libgc.la; then
 301       BDW_GC_LIBS="$bdw_lib_dir/libgc.la"
 302     else
 303       BDW_GC_LIBS="-L$bdw_lib_dir -lgc"
 304     fi
 305     AC_MSG_RESULT([found])
 306   fi
 307
 308   case "$BDW_GC_LIBS" in
 309   *libgc.la)
 310     use_bdw_gc=yes
 311     ;;
 312   *)
 313     AC_MSG_CHECKING([for system boehm-gc])
 314     save_CFLAGS=$CFLAGS
 315     save_LIBS=$LIBS
 316     CFLAGS="$CFLAGS $BDW_GC_CFLAGS"
 317     LIBS="$LIBS $BDW_GC_LIBS"
 318     dnl the link test is not good enough for ARM32 multilib detection,
 319     dnl first check to link, then to run
 320     AC_LINK_IFELSE(
 321       [AC_LANG_PROGRAM([#include <gc/gc.h>],[GC_init()])],
 322       [
 323         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 324           #include <gc/gc.h>
 325           int main() {
 326             GC_init();
 327             return 0;
 328           }
 329           ]])],
 330           [system_bdw_gc_found=yes],
 331           [system_bdw_gc_found=no],
 332           dnl assume no system boehm-gc for cross builds ...
 333           [system_bdw_gc_found=no]
 334         )
 335       ],
 336       [system_bdw_gc_found=no])
 337     CFLAGS=$save_CFLAGS
 338     LIBS=$save_LIBS
 339     if test x$enable_objc_gc = xauto && test x$system_bdw_gc_found = xno; then
 340       AC_MSG_WARN([system bdw-gc not found, not building libobjc_gc])
 341       use_bdw_gc=no
 342     elif test x$enable_objc_gc = xyes && test x$system_bdw_gc_found = xno; then
 343       AC_MSG_ERROR([system bdw-gc required but not found])
 344     else
 345       use_bdw_gc=yes
 346       AC_MSG_RESULT([found])
 347     fi
 348   esac
 349 esac
 350
 351 if test "$use_bdw_gc" = no; then
 352   OBJC_GCFLAGS=''
 353   OBJC_BOEHM_GC=''
 354   OBJC_BOEHM_GC_INCLUDES=''
 355   OBJC_BOEHM_GC_LIBS=''
 356 else
 357   OBJC_GCFLAGS='-DOBJC_WITH_GC=1'
 358   OBJC_BOEHM_GC='libobjc_gc$(libsuffix).la'
 359   OBJC_BOEHM_GC_INCLUDES=$BDW_GC_CFLAGS
 360   OBJC_BOEHM_GC_LIBS=$BDW_GC_LIBS
 361 fi
 362 AC_SUBST(OBJC_GCFLAGS)
 363 AC_SUBST(OBJC_BOEHM_GC)
 364 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
 365 AC_SUBST(OBJC_BOEHM_GC_LIBS)
 366
 367 # Determine what GCC version number to use in filesystem paths.
 368 GCC_BASE_VER
 369
 370 # ------
 371 # Output
 372 # ------
 373
 374 if test ${multilib} = yes; then
 375   multilib_arg="--enable-multilib"
 376 else
 377   multilib_arg=
 378 fi
 379
 380 AC_CONFIG_FILES([Makefile])
 381 AC_OUTPUT