libchill/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 1999 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU CC.
   6 #
   7 #GNU CHILL is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU CHILL is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU CHILL; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.13)
  23 AC_INIT(chillrt0.c)
  24
  25 if test "${srcdir}" = "." ; then
  26   if test "${with_target_subdir}" != "." ; then
  27     topsrcdir=${with_multisrctop}../..
  28   else
  29     topsrcdir=${with_multisrctop}..
  30   fi
  31 else
  32   topsrcdir=${srcdir}/..
  33 fi
  34 dnl This is needed for a multilibbed build in the source tree so
  35 dnl that install-sh and config.sub get found.
  36 AC_CONFIG_AUX_DIR($topsrcdir)
  37
  38 # If the language specific compiler does not exist, but the "gcc" directory
  39 # does, we do not build anything. Note, $r is set by the top-level Makefile.
  40 # Note that when we look for the compiler, we search both with and without
  41 # extension to handle cross and canadian cross builds.
  42 compiler_name=cc1chill
  43 rm -f skip-this-dir
  44 AC_MSG_CHECKING(if compiler $compiler_name has been built)
  45 AC_CACHE_VAL(chill_cv_compiler_exists,
  46 [chill_cv_compiler_exists=yes
  47 if test -n "$r"; then
  48   if test -d "$r"/gcc; then
  49     if test -f "$r"/gcc/$compiler_name \
  50        || test -f "$r"/gcc/$compiler_name.exe; then
  51       true
  52     else
  53       chill_cv_compiler_exists=no
  54       echo "rm -f config.cache config.log multilib.out" > skip-this-dir
  55     fi
  56   fi
  57 fi
  58 ])
  59 AC_MSG_RESULT($chill_cv_compiler_exists)
  60 if test x$chill_cv_compiler_exists = xno
  61 then
  62   rm -f Makefile conftest* confdefs* core
  63   exit 0
  64 fi
  65
  66 dnl Checks for programs.
  67 # For chill we'll set CC to point at the built gcc, but this will get it into
  68 # the makefiles
  69 AC_PROG_CC
  70
  71 test "$AR" || AR=ar
  72 AC_SUBST(AR)
  73 AC_PROG_MAKE_SET
  74
  75 dnl Checks for libraries.
  76
  77 dnl Checks for header files.
  78 # Sanity check for the cross-compilation case:
  79 AC_CHECK_HEADER(stdio.h,:,
  80   [AC_MSG_ERROR([Can't find stdio.h.
  81 You must have a usable C system for the target already installed, at least
  82 including headers and, preferably, the library, before you can configure
  83 the Chill runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  84 then the target library, then build with \`LANGUAGES=chill'.])])
  85
  86 AC_HEADER_STDC
  87
  88 AC_MSG_CHECKING(for posix)
  89 AC_CACHE_VAL(chill_cv_header_posix,
  90   AC_EGREP_CPP(yes,
  91   [#include <sys/types.h>
  92 #include <unistd.h>
  93 #ifdef _POSIX_VERSION
  94   yes
  95 #endif
  96 ],
  97   chill_cv_header_posix=yes,
  98   chill_cv_header_posix=no))
  99 AC_MSG_RESULT($chill_cv_header_posix)
 100
 101 # We can rely on the GNU library being posix-ish.  I guess checking the
 102 # header isn't actually like checking the functions, though...
 103 AC_MSG_CHECKING(for GNU library)
 104 AC_CACHE_VAL(chill_cv_lib_gnu,
 105   AC_EGREP_CPP(yes,
 106     [#include <stdio.h>
 107 #ifdef __GNU_LIBRARY__
 108   yes
 109 #endif
 110 ],
 111   chill_cv_lib_gnu=yes, chill_cv_lib_gnu=no))
 112 AC_MSG_RESULT($chill_cv_lib_gnu)
 113
 114 dnl Checks for library functions.
 115 AC_TYPE_SIGNAL
 116 # we'll get atexit by default
 117 if test $ac_cv_header_stdc != yes; then
 118 AC_CHECK_FUNC(atexit,
 119   AC_DEFINE(onexit,atexit),dnl just in case
 120   [AC_DEFINE(NO_ONEXIT)
 121   AC_CHECK_FUNC(onexit,,
 122     [AC_CHECK_FUNC(on_exit,
 123      AC_DEFINE(onexit,on_exit),)])])
 124 else true
 125 fi
 126
 127 # We need multilib support, but only if configuring for the target.
 128 AC_OUTPUT(Makefile,
 129 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 130 if test -n "$CONFIG_FILES"; then
 131   if test -n "${with_target_subdir}"; then
 132     # FIXME: We shouldn't need to set ac_file
 133     ac_file=Makefile
 134     . ${topsrcdir}/config-ml.in
 135   fi
 136 fi],
 137 srcdir=${srcdir}
 138 host=${host}
 139 target=${target}
 140 with_target_subdir=${with_target_subdir}
 141 with_multisubdir=${with_multisubdir}
 142 ac_configure_args="--enable-multilib ${ac_configure_args}"
 143 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 144 topsrcdir=${topsrcdir}
 145 )
 146
 147
 148
 149 dnl Local Variables:
 150 dnl comment-start: "dnl "
 151 dnl comment-end: ""
 152 dnl comment-start-skip: "\\bdnl\\b\\s *"
 153 dnl End: