gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 ACX_PROG_GNAT([-I"$srcdir"/ada])
 280
 281 # autoconf is lame and doesn't give us any substitution variable for this.
 282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 283   NO_MINUS_C_MINUS_O=yes
 284 else
 285   OUTPUT_OPTION='-o $@'
 286 fi
 287 AC_SUBST(NO_MINUS_C_MINUS_O)
 288 AC_SUBST(OUTPUT_OPTION)
 289
 290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 291 # optimizations to be activated explicitly by the toplevel.
 292 case "$CC" in
 293   */prev-gcc/xgcc*) ;;
 294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 295 esac
 296 AC_SUBST(CFLAGS)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 # sizeof(char) is 1 by definition.
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(int)
 310 AC_CHECK_SIZEOF(long)
 311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 313
 314 # ---------------------
 315 # Warnings and checking
 316 # ---------------------
 317
 318 # Check $CC warning features (if it's GCC).
 319 # We want to use -pedantic, but we don't want warnings about
 320 # * 'long long'
 321 # * variadic macros
 322 # * overlong strings
 323 # So, we only use -pedantic if we can disable those warnings.
 324
 325 ACX_PROG_CC_WARNING_OPTS(
 326         [m4_do([-W -Wall -Wwrite-strings -Wstrict-prototypes ],
 327                [-Wmissing-prototypes -Wcast-qual])], [loose_warn])
 328 ACX_PROG_CC_WARNING_OPTS(
 329         [m4_do([-Wold-style-definition -Wc++-compat ],
 330                [-Wmissing-format-attribute])], [strict_warn])
 331 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 332         [m4_do([-Wno-long-long -Wno-variadic-macros ],
 333                [-Wno-overlength-strings])], [strict_warn])
 334 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 335
 336 # The above macros do nothing if the compiler is not GCC.  However, the
 337 # Makefile has more goo to add other flags, so this variabl is used to
 338 # enables warnings only for GCC.
 339 warn_cflags=
 340 if test "x$GCC" = "xyes"; then
 341   warn_cflags='$(GCC_WARN_CFLAGS)'
 342 fi
 343 AC_SUBST(warn_cflags)
 344
 345 # Enable expensive internal checks
 346 is_release=
 347 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 348   is_release=yes
 349 fi
 350
 351 AC_ARG_ENABLE(checking,
 352 [  --enable-checking[=LIST]
 353                           enable expensive run-time checks.  With LIST,
 354                           enable only specific categories of checks.
 355                           Categories are: yes,no,all,none,release.
 356                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 357                           rtlflag,rtl,runtime,tree,valgrind,types.],
 358 [ac_checking_flags="${enableval}"],[
 359 # Determine the default checks.
 360 if test x$is_release = x ; then
 361   ac_checking_flags=yes
 362 else
 363   ac_checking_flags=release
 364 fi])
 365 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 366 for check in release $ac_checking_flags
 367 do
 368         case $check in
 369         # these set all the flags to specific states
 370         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 371                         ac_fold_checking= ; ac_gc_checking=1 ;
 372                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 373                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 374                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 375                         ac_types_checking=1 ;;
 376         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 377                         ac_fold_checking= ; ac_gc_checking= ;
 378                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 379                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 380                         ac_tree_checking= ; ac_valgrind_checking= ;
 381                         ac_types_checking= ;;
 382         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 383                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 384                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 385                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 386                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 387                         ac_types_checking=1 ;;
 388         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 389                         ac_fold_checking= ; ac_gc_checking= ;
 390                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 391                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 392                         ac_tree_checking= ; ac_valgrind_checking= ;
 393                         ac_types_checking= ;;
 394         # these enable particular checks
 395         assert)         ac_assert_checking=1 ;;
 396         df)             ac_df_checking=1 ;;
 397         fold)           ac_fold_checking=1 ;;
 398         gc)             ac_gc_checking=1 ;;
 399         gcac)           ac_gc_always_collect=1 ;;
 400         gimple)         ac_gimple_checking=1 ;;
 401         misc)           ac_checking=1 ;;
 402         rtl)            ac_rtl_checking=1 ;;
 403         rtlflag)        ac_rtlflag_checking=1 ;;
 404         runtime)        ac_runtime_checking=1 ;;
 405         tree)           ac_tree_checking=1 ;;
 406         types)          ac_types_checking=1 ;;
 407         valgrind)       ac_valgrind_checking=1 ;;
 408         *)      AC_MSG_ERROR(unknown check category $check) ;;
 409         esac
 410 done
 411 IFS="$ac_save_IFS"
 412
 413 nocommon_flag=""
 414 if test x$ac_checking != x ; then
 415   AC_DEFINE(ENABLE_CHECKING, 1,
 416 [Define if you want more run-time sanity checks.  This one gets a grab
 417    bag of miscellaneous but relatively cheap checks.])
 418   nocommon_flag=-fno-common
 419 fi
 420 AC_SUBST(nocommon_flag)
 421 if test x$ac_df_checking != x ; then
 422   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 423 [Define if you want more run-time sanity checks for dataflow.])
 424 fi
 425 if test x$ac_assert_checking != x ; then
 426   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 427 [Define if you want assertions enabled.  This is a cheap check.])
 428 fi
 429 if test x$ac_gimple_checking != x ; then
 430   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 431 [Define if you want operations on GIMPLE (the basic data structure of
 432 the high-level optimizers) to be checked for dynamic type safety at
 433 runtime.  This is moderately expensive.])
 434 fi
 435 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 436 if test x$ac_runtime_checking != x ; then
 437   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 438 [Define if you want runtime assertions enabled.  This is a cheap check.])
 439 fi
 440 if test x$ac_tree_checking != x ; then
 441   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 442 [Define if you want all operations on trees (the basic data
 443    structure of the front ends) to be checked for dynamic type safety
 444    at runtime.  This is moderately expensive.  The tree browser debugging
 445    routines will also be enabled by this option.
 446    ])
 447   TREEBROWSER=tree-browser.o
 448 fi
 449 if test x$ac_types_checking != x ; then
 450   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 451 [Define if you want all gimple types to be verified after gimplifiation.
 452    This is cheap.
 453    ])
 454 fi
 455 AC_SUBST(TREEBROWSER)
 456 if test x$ac_rtl_checking != x ; then
 457   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 458 [Define if you want all operations on RTL (the basic data structure
 459    of the optimizer and back end) to be checked for dynamic type safety
 460    at runtime.  This is quite expensive.])
 461 fi
 462 if test x$ac_rtlflag_checking != x ; then
 463   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 464 [Define if you want RTL flag accesses to be checked against the RTL
 465    codes that are supported for each access macro.  This is relatively
 466    cheap.])
 467 fi
 468 if test x$ac_gc_checking != x ; then
 469   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 470 [Define if you want the garbage collector to do object poisoning and
 471    other memory allocation checks.  This is quite expensive.])
 472 fi
 473 if test x$ac_gc_always_collect != x ; then
 474   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 475 [Define if you want the garbage collector to operate in maximally
 476    paranoid mode, validating the entire heap and collecting garbage at
 477    every opportunity.  This is extremely expensive.])
 478 fi
 479 if test x$ac_fold_checking != x ; then
 480   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 481 [Define if you want fold checked that it never destructs its argument.
 482    This is quite expensive.])
 483 fi
 484 valgrind_path_defines=
 485 valgrind_command=
 486
 487 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 488 dnl # an if statement.  This was the source of very frustrating bugs
 489 dnl # in converting to autoconf 2.5x!
 490 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 491
 492 if test x$ac_valgrind_checking != x ; then
 493   # It is certainly possible that there's valgrind but no valgrind.h.
 494   # GCC relies on making annotations so we must have both.
 495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 497     [[#include <valgrind/memcheck.h>
 498 #ifndef VALGRIND_DISCARD
 499 #error VALGRIND_DISCARD not defined
 500 #endif]])],
 501   [gcc_cv_header_valgrind_memcheck_h=yes],
 502   [gcc_cv_header_valgrind_memcheck_h=no])
 503   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 504   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 505   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 506     [[#include <memcheck.h>
 507 #ifndef VALGRIND_DISCARD
 508 #error VALGRIND_DISCARD not defined
 509 #endif]])],
 510   [gcc_cv_header_memcheck_h=yes],
 511   [gcc_cv_header_memcheck_h=no])
 512   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 513   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 514         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 515   if test "x$valgrind_path" = "x" \
 516     || (test $have_valgrind_h = no \
 517         && test $gcc_cv_header_memcheck_h = no \
 518         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 519         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 520   fi
 521   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 522   valgrind_command="$valgrind_path -q"
 523   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 524 [Define if you want to run subprograms and generated programs
 525    through valgrind (a memory checker).  This is extremely expensive.])
 526   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 527     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 528         [Define if valgrind's valgrind/memcheck.h header is installed.])
 529   fi
 530   if test $gcc_cv_header_memcheck_h = yes; then
 531     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 532         [Define if valgrind's memcheck.h header is installed.])
 533   fi
 534 fi
 535 AC_SUBST(valgrind_path_defines)
 536 AC_SUBST(valgrind_command)
 537
 538 # Enable code coverage collection
 539 AC_ARG_ENABLE(coverage,
 540 [  --enable-coverage[=LEVEL]
 541                           enable compiler's code coverage collection.
 542                           Use to measure compiler performance and locate
 543                           unused parts of the compiler. With LEVEL, specify
 544                           optimization. Values are opt, noopt,
 545                           default is noopt],
 546 [case "${enableval}" in
 547   yes|noopt)
 548     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 549     ;;
 550   opt)
 551     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 552     ;;
 553   no)
 554     # a.k.a. --disable-coverage
 555     coverage_flags=""
 556     ;;
 557   *)
 558     AC_MSG_ERROR(unknown coverage setting $enableval)
 559     ;;
 560 esac],
 561 [coverage_flags=""])
 562 AC_SUBST(coverage_flags)
 563
 564 AC_ARG_ENABLE(gather-detailed-mem-stats,
 565 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 566 [enable_gather_detailed_mem_stats=no])
 567 if test x$enable_gather_detailed_mem_stats = xyes ; then
 568   AC_DEFINE(GATHER_STATISTICS, 1,
 569         [Define to enable detailed memory allocation stats gathering.])
 570 fi
 571
 572 # -------------------------------
 573 # Miscenalleous configure options
 574 # -------------------------------
 575
 576 # With stabs
 577 AC_ARG_WITH(stabs,
 578 [  --with-stabs            arrange to use stabs instead of host debug format],
 579 stabs="$with_stabs",
 580 stabs=no)
 581
 582 # Determine whether or not multilibs are enabled.
 583 AC_ARG_ENABLE(multilib,
 584 [  --enable-multilib       enable library support for multiple ABIs],
 585 [], [enable_multilib=yes])
 586 AC_SUBST(enable_multilib)
 587
 588 # Enable __cxa_atexit for C++.
 589 AC_ARG_ENABLE(__cxa_atexit,
 590 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 591 [], [])
 592
 593 # Enable C extension for decimal float if target supports it.
 594 AC_ARG_ENABLE(decimal-float,
 595 [  --enable-decimal-float={no,yes,bid,dpd}
 596                         enable decimal float extension to C.  Selecting 'bid'
 597                         or 'dpd' choses which decimal floating point format
 598                         to use],
 599 [
 600   case $enable_decimal_float in
 601     yes | no | bid | dpd) ;;
 602     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 603 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 604   esac
 605 ],
 606 [
 607   case $target in
 608     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 609       enable_decimal_float=yes
 610       ;;
 611     *)
 612       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 613       enable_decimal_float=no
 614       ;;
 615   esac
 616 ])
 617
 618 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 619 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 620 [Define to 1 to enable decimal float extension to C.])
 621
 622 # x86's use BID format instead of DPD
 623 case x$enable_decimal_float in
 624   xyes)
 625     case $target in
 626       i?86*-*-linux* | x86_64*-*-linux*)
 627         enable_decimal_float=bid
 628         ;;
 629       *)
 630         enable_decimal_float=dpd
 631         ;;
 632     esac
 633     ;;
 634   xno)
 635     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 636     # dependency on libdecnumber.
 637     enable_decimal_float=dpd
 638     ;;
 639 esac
 640 AC_SUBST(enable_decimal_float)
 641
 642 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 643 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 644 [Define to 1 to specify that we are using the BID decimal floating
 645 point format instead of DPD])
 646
 647 # Enable C extension for fixed-point arithmetic.
 648 AC_ARG_ENABLE(fixed-point,
 649 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 650 [
 651 ],
 652 [
 653   case $target in
 654     mips*-*-*)
 655       case $host in
 656         mips*-sgi-irix*)
 657           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 658           enable_fixed_point=no
 659           ;;
 660         *)
 661           enable_fixed_point=yes
 662           ;;
 663       esac
 664       ;;
 665     *)
 666       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 667       enable_fixed_point=no
 668       ;;
 669   esac
 670 ])
 671 AC_SUBST(enable_fixed_point)
 672
 673 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 674 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 675 [Define to 1 to enable fixed-point arithmetic extension to C.])
 676
 677 # Enable threads
 678 # Pass with no value to take the default
 679 # Pass with a value to specify a thread package
 680 AC_ARG_ENABLE(threads,
 681 [  --enable-threads        enable thread usage for target GCC
 682   --enable-threads=LIB    use LIB thread package for target GCC],,
 683 [enable_threads=''])
 684
 685 AC_ARG_ENABLE(tls,
 686 [  --enable-tls            enable or disable generation of tls code
 687                           overriding the assembler check for tls support],
 688 [
 689   case $enable_tls in
 690     yes | no) ;;
 691     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 692 Valid choices are 'yes' and 'no'.]) ;;
 693   esac
 694 ], [enable_tls=''])
 695
 696 AC_ARG_ENABLE(objc-gc,
 697 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 698                           the GNU Objective-C runtime],
 699 if test x$enable_objc_gc = xno; then
 700         objc_boehm_gc=''
 701 else
 702         objc_boehm_gc=1
 703 fi,
 704 objc_boehm_gc='')
 705
 706 AC_ARG_WITH(dwarf2,
 707 [  --with-dwarf2           force the default debug format to be DWARF 2],
 708 dwarf2="$with_dwarf2",
 709 dwarf2=no)
 710
 711 AC_ARG_ENABLE(shared,
 712 [  --disable-shared        don't provide a shared libgcc],
 713 [
 714   case $enable_shared in
 715   yes | no) ;;
 716   *)
 717     enable_shared=no
 718     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 719     for pkg in $enableval; do
 720       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 721         enable_shared=yes
 722       fi
 723     done
 724     IFS="$ac_save_ifs"
 725     ;;
 726   esac
 727 ], [enable_shared=yes])
 728 AC_SUBST(enable_shared)
 729
 730 AC_ARG_WITH(build-sysroot,
 731   [  --with-build-sysroot=sysroot
 732                           use sysroot as the system root during the build])
 733
 734 AC_ARG_WITH(sysroot,
 735 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 736 [
 737  case ${with_sysroot} in
 738  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 739  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 740  esac
 741
 742  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 743  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 744
 745  if test "x$prefix" = xNONE; then
 746   test_prefix=/usr/local
 747  else
 748   test_prefix=$prefix
 749  fi
 750  if test "x$exec_prefix" = xNONE; then
 751   test_exec_prefix=$test_prefix
 752  else
 753   test_exec_prefix=$exec_prefix
 754  fi
 755  case ${TARGET_SYSTEM_ROOT} in
 756  "${test_prefix}"|"${test_prefix}/"*|\
 757  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 758  '${prefix}'|'${prefix}/'*|\
 759  '${exec_prefix}'|'${exec_prefix}/'*)
 760    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 761    TARGET_SYSTEM_ROOT_DEFINE="$t"
 762    ;;
 763  esac
 764 ], [
 765  TARGET_SYSTEM_ROOT=
 766  TARGET_SYSTEM_ROOT_DEFINE=
 767  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 768 ])
 769 AC_SUBST(TARGET_SYSTEM_ROOT)
 770 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 771 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 772
 773 # Build with intermodule optimisations
 774 AC_ARG_ENABLE(intermodule,
 775 [  --enable-intermodule    build the compiler in one step],
 776 [case ${enable_intermodule} in
 777   yes) onestep="-onestep";;
 778   *) onestep="";;
 779 esac],
 780 [onestep=""])
 781 AC_SUBST(onestep)
 782
 783 ACX_PKGVERSION([GCC])
 784 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 785
 786 # Sanity check enable_languages in case someone does not run the toplevel
 787 # configure # script.
 788 AC_ARG_ENABLE(languages,
 789 [  --enable-languages=LIST specify which front-ends to build],
 790 [case ,${enable_languages}, in
 791        ,,|,yes,)
 792                 # go safe -- we cannot be much sure without the toplevel
 793                 # configure's
 794                 # analysis of which target libs are present and usable
 795                 enable_languages=c
 796                 ;;
 797          *,all,*)
 798                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 799                 ;;
 800         *,c,*)
 801                 ;;
 802         *)
 803                 enable_languages=c,${enable_languages}
 804                 ;;
 805 esac],
 806 [enable_languages=c])
 807
 808 # Used by documentation targets
 809 AC_SUBST(datarootdir)
 810 AC_SUBST(docdir)
 811 AC_SUBST(htmldir)
 812
 813 # -------------------------
 814 # Checks for other programs
 815 # -------------------------
 816
 817 AC_PROG_MAKE_SET
 818
 819 # Find some useful tools
 820 AC_PROG_AWK
 821 # We need awk to create options.c and options.h.
 822 # Bail out if it's missing.
 823 case ${AWK} in
 824   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 825 esac
 826
 827 gcc_AC_PROG_LN_S
 828 ACX_PROG_LN($LN_S)
 829 AC_PROG_RANLIB
 830 case "${host}" in
 831 *-*-darwin*)
 832   # By default, the Darwin ranlib will not treat common symbols as
 833   # definitions when  building the archive table of contents.  Other
 834   # ranlibs do that; pass an option to the Darwin ranlib that makes
 835   # it behave similarly.
 836   ranlib_flags="-c"
 837   ;;
 838 *)
 839   ranlib_flags=""
 840 esac
 841 AC_SUBST(ranlib_flags)
 842
 843 gcc_AC_PROG_INSTALL
 844
 845 # See if cmp has --ignore-initial.
 846 gcc_AC_PROG_CMP_IGNORE_INITIAL
 847
 848 # See if we have the mktemp command.
 849 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 850
 851 # See if makeinfo has been installed and is modern enough
 852 # that we can use it.
 853 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 854   [GNU texinfo.* \([0-9][0-9.]*\)],
 855   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 856 if test $gcc_cv_prog_makeinfo_modern = no; then
 857   AC_MSG_WARN([
 858 *** Makeinfo is missing or too old.
 859 *** Info documentation will not be built.])
 860   BUILD_INFO=
 861 else
 862   BUILD_INFO=info
 863 fi
 864 AC_SUBST(BUILD_INFO)
 865
 866 # Is pod2man recent enough to regenerate manpages?
 867 AC_MSG_CHECKING([for recent Pod::Man])
 868 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 869   AC_MSG_RESULT(yes)
 870   GENERATED_MANPAGES=generated-manpages
 871 else
 872   AC_MSG_RESULT(no)
 873   GENERATED_MANPAGES=
 874 fi
 875 AC_SUBST(GENERATED_MANPAGES)
 876
 877 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 878
 879 # How about lex?
 880 dnl Don't use AC_PROG_LEX; we insist on flex.
 881 dnl LEXLIB is not useful in gcc.
 882 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 883
 884 # Bison?
 885 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 886
 887 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 888 # check for build == host before using them.
 889
 890 # NM
 891 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 892   && test -d ../binutils ; then
 893   NM='$(objdir)/../binutils/nm-new'
 894 else
 895   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 896 fi
 897
 898 # AR
 899 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 900   && test -d ../binutils ; then
 901   AR='$(objdir)/../binutils/ar'
 902 else
 903   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 904 fi
 905
 906
 907 # --------------------
 908 # Checks for C headers
 909 # --------------------
 910
 911 # Need to reject headers which give warnings, so that the -Werror bootstrap
 912 # works later. *sigh*  This needs to come before all header checks.
 913 AC_PROG_CPP_WERROR
 914
 915 AC_HEADER_STDC
 916 AC_HEADER_TIME
 917 ACX_HEADER_STRING
 918 AC_HEADER_SYS_WAIT
 919 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 920                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 921                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 922                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 923
 924 # Check for thread headers.
 925 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 926 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 927
 928 # These tests can't be done till we know if we have limits.h.
 929 gcc_AC_C_CHAR_BIT
 930 AC_C_BIGENDIAN
 931
 932 # --------
 933 # UNSORTED
 934 # --------
 935
 936
 937 # These libraries may be used by collect2.
 938 # We may need a special search path to get them linked.
 939 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 940 [save_LIBS="$LIBS"
 941 for libs in '' -lld -lmld \
 942                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 943                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 944 do
 945         LIBS="$libs"
 946         AC_TRY_LINK_FUNC(ldopen,
 947                 [gcc_cv_collect2_libs="$libs"; break])
 948 done
 949 LIBS="$save_LIBS"
 950 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 951 case $gcc_cv_collect2_libs in
 952         "none required")        ;;
 953         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 954 esac
 955 AC_SUBST(COLLECT2_LIBS)
 956
 957 # When building Ada code on Alpha, we need exc_resume which is usually in
 958 # -lexc.  So test for it.
 959 save_LIBS="$LIBS"
 960 LIBS=
 961 AC_SEARCH_LIBS(exc_resume, exc)
 962 GNAT_LIBEXC="$LIBS"
 963 LIBS="$save_LIBS"
 964 AC_SUBST(GNAT_LIBEXC)
 965
 966 # Some systems put ldexp and frexp in libm instead of libc; assume
 967 # they're both in the same place.  jcf-dump needs them.
 968 save_LIBS="$LIBS"
 969 LIBS=
 970 AC_SEARCH_LIBS(ldexp, m)
 971 LDEXP_LIB="$LIBS"
 972 LIBS="$save_LIBS"
 973 AC_SUBST(LDEXP_LIB)
 974
 975 # Use <inttypes.h> only if it exists,
 976 # doesn't clash with <sys/types.h>, and declares intmax_t.
 977 AC_MSG_CHECKING(for inttypes.h)
 978 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 979 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 980 [[#include <sys/types.h>
 981 #include <inttypes.h>]],
 982   [[intmax_t i = -1;]])],
 983   [gcc_cv_header_inttypes_h=yes],
 984   [gcc_cv_header_inttypes_h=no])])
 985 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 986 if test $gcc_cv_header_inttypes_h = yes; then
 987   AC_DEFINE(HAVE_INTTYPES_H, 1,
 988         [Define if you have a working <inttypes.h> header file.])
 989 fi
 990
 991 dnl Disabled until we have a complete test for buggy enum bitfields.
 992 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 993
 994 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 995   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 996   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 997   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 998   putchar_unlocked putc_unlocked)
 999 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1000         sysconf strsignal getrusage nl_langinfo \
1001         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1002         gcc_UNLOCKED_FUNCS)
1003
1004 if test x$ac_cv_func_mbstowcs = xyes; then
1005   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1006 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1007 int main()
1008 {
1009   mbstowcs(0, "", 0);
1010   return 0;
1011 }]])],
1012     [gcc_cv_func_mbstowcs_works=yes],
1013     [gcc_cv_func_mbstowcs_works=no],
1014     [gcc_cv_func_mbstowcs_works=yes])])
1015   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1016     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1017   [Define this macro if mbstowcs does not crash when its
1018    first argument is NULL.])
1019   fi
1020 fi
1021
1022 AC_CHECK_TYPE(ssize_t, int)
1023 AC_CHECK_TYPE(caddr_t, char *)
1024
1025 # Try to determine the array type of the second argument of getgroups
1026 # for the target system (int or gid_t).
1027 AC_TYPE_GETGROUPS
1028 if test "${target}" = "${build}"; then
1029   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1030 else
1031   case "${target}" in
1032         # This condition may need some tweaking.  It should include all
1033         # targets where the array type of the second argument of getgroups
1034         # is int and the type of gid_t is not equivalent to int.
1035         *-*-sunos* | *-*-ultrix*)
1036                 TARGET_GETGROUPS_T=int
1037                 ;;
1038         *)
1039                 TARGET_GETGROUPS_T=gid_t
1040                 ;;
1041   esac
1042 fi
1043 AC_SUBST(TARGET_GETGROUPS_T)
1044
1045 gcc_AC_FUNC_MMAP_BLACKLIST
1046
1047 case "${host}" in
1048 *-*-*vms*)
1049   # Under VMS, vfork works very differently than on Unix. The standard test
1050   # won't work, and it isn't easily adaptable. It makes more sense to
1051   # just force it.
1052   ac_cv_func_vfork_works=yes
1053   ;;
1054 esac
1055 AC_FUNC_FORK
1056
1057 AM_ICONV
1058 # Until we have in-tree GNU iconv:
1059 LIBICONV_DEP=
1060 AC_SUBST(LIBICONV_DEP)
1061
1062 AM_LC_MESSAGES
1063
1064 AM_LANGINFO_CODESET
1065
1066 # We will need to find libiberty.h and ansidecl.h
1067 saved_CFLAGS="$CFLAGS"
1068 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1069 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1070         strsignal strstr strverscmp \
1071         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1072         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1073 #include "ansidecl.h"
1074 #include "system.h"])
1075
1076 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1077 #include "ansidecl.h"
1078 #include "system.h"
1079 #ifdef HAVE_SYS_RESOURCE_H
1080 #include <sys/resource.h>
1081 #endif
1082 ])
1083
1084 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1085 #include "ansidecl.h"
1086 #include "system.h"
1087 #ifdef HAVE_SYS_RESOURCE_H
1088 #include <sys/resource.h>
1089 #endif
1090 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1091 [Define to `long' if <sys/resource.h> doesn't define.])])
1092
1093 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1094 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1095 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1096 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1097 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 #ifdef HAVE_LDFCN_H
1101 #undef FREAD
1102 #undef FWRITE
1103 #include <ldfcn.h>
1104 #endif
1105 ])
1106
1107 gcc_AC_CHECK_DECLS(times, , ,[
1108 #include "ansidecl.h"
1109 #include "system.h"
1110 #ifdef HAVE_SYS_TIMES_H
1111 #include <sys/times.h>
1112 #endif
1113 ])
1114
1115 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1116 #include "ansidecl.h"
1117 #include "system.h"
1118 #include <signal.h>
1119 ])
1120
1121 # More time-related stuff.
1122 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1123 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1124 #include "ansidecl.h"
1125 #include "system.h"
1126 #ifdef HAVE_SYS_TIMES_H
1127 #include <sys/times.h>
1128 #endif
1129 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1130 if test $ac_cv_struct_tms = yes; then
1131   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1132   [Define if <sys/times.h> defines struct tms.])
1133 fi
1134
1135 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1136 # revisit after autoconf 2.50.
1137 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1138 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1139 #include "ansidecl.h"
1140 #include "system.h"
1141 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1142 if test $gcc_cv_type_clock_t = yes; then
1143   AC_DEFINE(HAVE_CLOCK_T, 1,
1144   [Define if <time.h> defines clock_t.])
1145 fi
1146
1147 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1148 CFLAGS="$saved_CFLAGS"
1149
1150 gcc_AC_INITFINI_ARRAY
1151
1152 # mkdir takes a single argument on some systems.
1153 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1154
1155 # File extensions
1156 manext='.1'
1157 objext='.o'
1158 AC_SUBST(manext)
1159 AC_SUBST(objext)
1160
1161 # With Setjmp/Longjmp based exception handling.
1162 AC_ARG_ENABLE(sjlj-exceptions,
1163 [  --enable-sjlj-exceptions
1164                           arrange to use setjmp/longjmp exception handling],
1165 [case $target in
1166   *-*-hpux10*)
1167     if test $enableval != yes; then
1168       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1169       enableval=yes
1170     fi
1171     ;;
1172 esac
1173 force_sjlj_exceptions=yes],
1174 [case $target in
1175   *-*-hpux10*)
1176     force_sjlj_exceptions=yes
1177     enableval=yes
1178     ;;
1179   *)
1180     force_sjlj_exceptions=no
1181     ;;
1182 esac])
1183 if test $force_sjlj_exceptions = yes; then
1184   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1185   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1186     [Define 0/1 to force the choice for exception handling model.])
1187 fi
1188
1189 # For platforms with the unwind ABI which includes an unwind library,
1190 # libunwind, we can choose to use the system libunwind.
1191 AC_ARG_WITH(system-libunwind,
1192 [  --with-system-libunwind use installed libunwind])
1193
1194 # config.gcc also contains tests of with_system_libunwind.
1195 if test x$with_system_libunwind = xyes; then
1196         AC_DEFINE(HAVE_GETIPINFO, 1,
1197 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1198 fi
1199
1200 # --------------------------------------------------------
1201 # Build, host, and target specific configuration fragments
1202 # --------------------------------------------------------
1203
1204 # Collect build-machine-specific information.
1205 . ${srcdir}/config.build
1206
1207 # Collect host-machine-specific information.
1208 . ${srcdir}/config.host
1209
1210 target_gtfiles=
1211
1212 # Collect target-machine-specific information.
1213 . ${srcdir}/config.gcc
1214
1215 extra_objs="${host_extra_objs} ${extra_objs}"
1216 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1217
1218 # Default the target-machine variables that were not explicitly set.
1219 if test x"$tm_file" = x
1220 then tm_file=$cpu_type/$cpu_type.h; fi
1221
1222 if test x"$extra_headers" = x
1223 then extra_headers=; fi
1224
1225 if test x$md_file = x
1226 then md_file=$cpu_type/$cpu_type.md; fi
1227
1228 if test x$out_file = x
1229 then out_file=$cpu_type/$cpu_type.c; fi
1230
1231 if test x"$tmake_file" = x
1232 then tmake_file=$cpu_type/t-$cpu_type
1233 fi
1234
1235 if test x"$dwarf2" = xyes
1236 then tm_file="$tm_file tm-dwarf2.h"
1237 fi
1238
1239 # Say what files are being used for the output code and MD file.
1240 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1241 echo "Using \`$srcdir/config/$md_file' as machine description file."
1242
1243 # If any of the xm_file variables contain nonexistent files, warn
1244 # about them and drop them.
1245
1246 bx=
1247 for x in $build_xm_file; do
1248   if    test -f $srcdir/config/$x
1249   then      bx="$bx $x"
1250   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1251   fi
1252 done
1253 build_xm_file="$bx"
1254
1255 hx=
1256 for x in $host_xm_file; do
1257   if    test -f $srcdir/config/$x
1258   then      hx="$hx $x"
1259   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1260   fi
1261 done
1262 host_xm_file="$hx"
1263
1264 tx=
1265 for x in $xm_file; do
1266   if    test -f $srcdir/config/$x
1267   then      tx="$tx $x"
1268   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1269   fi
1270 done
1271 xm_file="$tx"
1272
1273 count=a
1274 for f in $tm_file; do
1275         count=${count}x
1276 done
1277 if test $count = ax; then
1278         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1279 else
1280         echo "Using the following target machine macro files:"
1281         for f in $tm_file; do
1282                 echo "  $srcdir/config/$f"
1283         done
1284 fi
1285
1286 if test x$need_64bit_hwint = xyes; then
1287         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1288 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1289 fi
1290
1291 if test x$use_long_long_for_widest_fast_int = xyes; then
1292         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1293 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1294 efficiently supported by the host hardware.])
1295 fi
1296
1297 count=a
1298 for f in $host_xm_file; do
1299         count=${count}x
1300 done
1301 if test $count = a; then
1302         :
1303 elif test $count = ax; then
1304         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1305 else
1306         echo "Using the following host machine macro files:"
1307         for f in $host_xm_file; do
1308                 echo "  $srcdir/config/$f"
1309         done
1310 fi
1311 echo "Using ${out_host_hook_obj} for host machine hooks."
1312
1313 if test "$host_xm_file" != "$build_xm_file"; then
1314         count=a
1315         for f in $build_xm_file; do
1316                 count=${count}x
1317         done
1318         if test $count = a; then
1319                 :
1320         elif test $count = ax; then
1321                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1322         else
1323                 echo "Using the following build machine macro files:"
1324                 for f in $build_xm_file; do
1325                         echo "  $srcdir/config/$f"
1326                 done
1327         fi
1328 fi
1329
1330 case ${host} in
1331   powerpc*-*-darwin*)
1332     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1333       gcc_cv_mcontext_underscores,
1334       AC_COMPILE_IFELSE([
1335 #include <sys/cdefs.h>
1336 #include <sys/signal.h>
1337 #include <ucontext.h>
1338 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1339 ],
1340         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1341       if test $gcc_cv_mcontext_underscores = yes; then
1342         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1343           [mcontext_t fields start with __])
1344       fi
1345     ;;
1346 esac
1347
1348 # ---------
1349 # Threading
1350 # ---------
1351
1352 # Check if a valid thread package
1353 case ${enable_threads} in
1354   "" | no)
1355     # No threads
1356     target_thread_file='single'
1357     ;;
1358   yes)
1359     # default
1360     target_thread_file='single'
1361     ;;
1362   aix | dce | gnat | irix | posix | posix95 | rtems | \
1363   single | solaris | vxworks | win32 | mipssde)
1364     target_thread_file=${enable_threads}
1365     ;;
1366   *)
1367     echo "${enable_threads} is an unknown thread package" 1>&2
1368     exit 1
1369     ;;
1370 esac
1371
1372 if test x${thread_file} = x; then
1373   # No thread file set by target-specific clauses in config.gcc,
1374   # so use file chosen by default logic above
1375   thread_file=${target_thread_file}
1376 fi
1377
1378 # Make gthr-default.h if we have a thread file.
1379 gthread_flags=
1380 if test $thread_file != single; then
1381   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1382   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1383     rm -f gthr-default.h-t
1384   else
1385     mv -f gthr-default.h-t gthr-default.h
1386   fi
1387   gthread_flags=-DHAVE_GTHR_DEFAULT
1388 fi
1389 AC_SUBST(gthread_flags)
1390
1391 # --------
1392 # UNSORTED
1393 # --------
1394
1395 use_cxa_atexit=no
1396 if test x$enable___cxa_atexit = xyes || \
1397    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1398   if test x$host = x$target; then
1399     case $host in
1400       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1401       # keyed to flag_use_cxa_atexit
1402       *-*-mingw32*)
1403         use_cxa_atexit=yes
1404         ;;
1405       *)
1406         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1407           [echo "__cxa_atexit can't be enabled on this target"])
1408         ;;
1409     esac
1410   else
1411     # We can't check for __cxa_atexit when building a cross, so assume
1412     # it is available
1413     use_cxa_atexit=yes
1414   fi
1415   if test x$use_cxa_atexit = xyes; then
1416     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1417       [Define if you want to use __cxa_atexit, rather than atexit, to
1418       register C++ destructors for local statics and global objects.
1419       This is essential for fully standards-compliant handling of
1420       destructors, but requires __cxa_atexit in libc.])
1421   fi
1422 fi
1423
1424 use_getipinfo=yes
1425 if test x$with_system_libunwind = xyes; then
1426    if test x$host = x$target; then
1427      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1428    fi
1429 fi
1430 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1431 if test x$use_getipinfo = xyes; then
1432    AC_DEFINE(HAVE_GETIPINFO, 1,
1433         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1434 else
1435    echo "The system unwind library does not support _Unwind_GetIPInfo."
1436 fi
1437
1438 # Look for a file containing extra machine modes.
1439 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1440   extra_modes_file='$(srcdir)'/config/${extra_modes}
1441   AC_SUBST(extra_modes_file)
1442   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1443   [Define to the name of a file containing a list of extra machine modes
1444    for this architecture.])
1445 fi
1446
1447 # Convert extra_options into a form suitable for Makefile use.
1448 extra_opt_files=
1449 for f in $extra_options; do
1450   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1451 done
1452 AC_SUBST(extra_opt_files)
1453
1454 # auto-host.h is the file containing items generated by autoconf and is
1455 # the first file included by config.h.
1456 # If host=build, it is correct to have bconfig include auto-host.h
1457 # as well.  If host!=build, we are in error and need to do more
1458 # work to find out the build config parameters.
1459 if test x$host = x$build
1460 then
1461         build_auto=auto-host.h
1462 else
1463         # We create a subdir, then run autoconf in the subdir.
1464         # To prevent recursion we set host and build for the new
1465         # invocation of configure to the build for this invocation
1466         # of configure.
1467         tempdir=build.$$
1468         rm -rf $tempdir
1469         mkdir $tempdir
1470         cd $tempdir
1471         case ${srcdir} in
1472         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1473         *) realsrcdir=../${srcdir};;
1474         esac
1475         saved_CFLAGS="${CFLAGS}"
1476         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1477         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1478         ${realsrcdir}/configure \
1479                 --enable-languages=${enable_languages-all} \
1480                 --target=$target_alias --host=$build_alias --build=$build_alias
1481         CFLAGS="${saved_CFLAGS}"
1482
1483         # We just finished tests for the build machine, so rename
1484         # the file auto-build.h in the gcc directory.
1485         mv auto-host.h ../auto-build.h
1486         cd ..
1487         rm -rf $tempdir
1488         build_auto=auto-build.h
1489 fi
1490 AC_SUBST(build_subdir)
1491
1492 tm_file="${tm_file} defaults.h"
1493 tm_p_file="${tm_p_file} tm-preds.h"
1494 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1495 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1496 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1497 # put this back in temporarily.
1498 xm_file="auto-host.h ansidecl.h ${xm_file}"
1499
1500 # --------
1501 # UNSORTED
1502 # --------
1503
1504 changequote(,)dnl
1505 # Compile in configure arguments.
1506 if test -f configargs.h ; then
1507         # Being re-configured.
1508         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1509         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1510 else
1511         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1512 fi
1513
1514 # Double all backslashes and backslash all quotes to turn
1515 # gcc_config_arguments into a C string.
1516 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1517 $gcc_config_arguments
1518 EOF
1519 gcc_config_arguments_str=`cat conftest.out`
1520 rm -f conftest.out
1521
1522 cat > configargs.h <<EOF
1523 /* Generated automatically. */
1524 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1525 static const char thread_model[] = "$thread_file";
1526
1527 static const struct {
1528   const char *name, *value;
1529 } configure_default_options[] = $configure_default_options;
1530 EOF
1531 changequote([,])dnl
1532
1533 # Internationalization
1534 ZW_GNU_GETTEXT_SISTER_DIR
1535
1536 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1537 # -liconv on the link line twice.
1538 case "$LIBINTL" in *$LIBICONV*)
1539         LIBICONV= ;;
1540 esac
1541
1542 AC_ARG_ENABLE(secureplt,
1543 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1544 [], [])
1545
1546 AC_ARG_ENABLE(cld,
1547 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1548 [enable_cld=no])
1549
1550 # Windows32 Registry support for specifying GCC installation paths.
1551 AC_ARG_ENABLE(win32-registry,
1552 [  --disable-win32-registry
1553                           disable lookup of installation paths in the
1554                           Registry on Windows hosts
1555   --enable-win32-registry enable registry lookup (default)
1556   --enable-win32-registry=KEY
1557                           use KEY instead of GCC version as the last portion
1558                           of the registry key],,)
1559
1560 case $host_os in
1561   win32 | pe | cygwin* | mingw32* | uwin*)
1562     if test "x$enable_win32_registry" != xno; then
1563       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1564     fi
1565
1566     if test "x$enable_win32_registry" != xno; then
1567       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1568   [Define to 1 if installation paths should be looked up in the Windows
1569    Registry. Ignored on non-Windows hosts.])
1570
1571       if test "x$enable_win32_registry" != xyes \
1572          && test "x$enable_win32_registry" != x; then
1573         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1574   [Define to be the last component of the Windows registry key under which
1575    to look for installation paths.  The full key used will be
1576    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1577    The default is the GCC version number.])
1578       fi
1579     fi
1580   ;;
1581 esac
1582
1583 # Get an absolute path to the GCC top-level source directory
1584 holddir=`${PWDCMD-pwd}`
1585 cd $srcdir
1586 topdir=`${PWDCMD-pwd}`
1587 cd $holddir
1588
1589 # Conditionalize the makefile for this host machine.
1590 xmake_file=
1591 for f in ${host_xmake_file}
1592 do
1593         if test -f ${srcdir}/config/$f
1594         then
1595                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1596         fi
1597 done
1598
1599 # Conditionalize the makefile for this target machine.
1600 tmake_file_=
1601 for f in ${tmake_file}
1602 do
1603         if test -f ${srcdir}/config/$f
1604         then
1605                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1606         fi
1607 done
1608 tmake_file="${tmake_file_}"
1609
1610 # This is a terrible hack which will go away some day.
1611 host_cc_for_libada=${CC}
1612 AC_SUBST(host_cc_for_libada)
1613
1614 out_object_file=`basename $out_file .c`.o
1615
1616 tm_file_list="options.h"
1617 tm_include_list="options.h"
1618 for f in $tm_file; do
1619   case $f in
1620     ./* )
1621        f=`echo $f | sed 's/^..//'`
1622        tm_file_list="${tm_file_list} $f"
1623        tm_include_list="${tm_include_list} $f"
1624        ;;
1625     defaults.h )
1626        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1627        tm_include_list="${tm_include_list} $f"
1628        ;;
1629     * )
1630        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1631        tm_include_list="${tm_include_list} config/$f"
1632        ;;
1633   esac
1634 done
1635
1636 tm_p_file_list=
1637 tm_p_include_list=
1638 for f in $tm_p_file; do
1639   case $f in
1640     tm-preds.h )
1641        tm_p_file_list="${tm_p_file_list} $f"
1642        tm_p_include_list="${tm_p_include_list} $f"
1643        ;;
1644     * )
1645        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1646        tm_p_include_list="${tm_p_include_list} config/$f"
1647   esac
1648 done
1649
1650 xm_file_list=
1651 xm_include_list=
1652 for f in $xm_file; do
1653   case $f in
1654     ansidecl.h )
1655        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1656        xm_include_list="${xm_include_list} $f"
1657        ;;
1658     auto-host.h )
1659        xm_file_list="${xm_file_list} $f"
1660        xm_include_list="${xm_include_list} $f"
1661        ;;
1662     * )
1663        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1664        xm_include_list="${xm_include_list} config/$f"
1665        ;;
1666   esac
1667 done
1668
1669 host_xm_file_list=
1670 host_xm_include_list=
1671 for f in $host_xm_file; do
1672   case $f in
1673     ansidecl.h )
1674        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1675        host_xm_include_list="${host_xm_include_list} $f"
1676        ;;
1677     auto-host.h )
1678        host_xm_file_list="${host_xm_file_list} $f"
1679        host_xm_include_list="${host_xm_include_list} $f"
1680        ;;
1681     * )
1682        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1683        host_xm_include_list="${host_xm_include_list} config/$f"
1684        ;;
1685   esac
1686 done
1687
1688 build_xm_file_list=
1689 for f in $build_xm_file; do
1690   case $f in
1691     ansidecl.h )
1692        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1693        build_xm_include_list="${build_xm_include_list} $f"
1694        ;;
1695     auto-build.h | auto-host.h )
1696        build_xm_file_list="${build_xm_file_list} $f"
1697        build_xm_include_list="${build_xm_include_list} $f"
1698        ;;
1699     * )
1700        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1701        build_xm_include_list="${build_xm_include_list} config/$f"
1702        ;;
1703   esac
1704 done
1705
1706 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1707 # cross-compiler which does not use the native headers and libraries.
1708 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1709 CROSS=                                          AC_SUBST(CROSS)
1710 ALL=all.internal                                AC_SUBST(ALL)
1711 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1712
1713 if test "x$with_build_sysroot" != x; then
1714   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1715 else
1716   # This value is used, even on a native system, because
1717   # CROSS_SYSTEM_HEADER_DIR is just
1718   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1719   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1720 fi
1721
1722 if test x$host != x$target
1723 then
1724         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1725         ALL=all.cross
1726         SYSTEM_HEADER_DIR=$build_system_header_dir
1727         case "$host","$target" in
1728         # Darwin crosses can use the host system's libraries and headers,
1729         # because of the fat library support.  Of course, it must be the
1730         # same version of Darwin on both sides.  Allow the user to
1731         # just say --target=foo-darwin without a version number to mean
1732         # "the version on this system".
1733             *-*-darwin*,*-*-darwin*)
1734                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1735                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1736                 if test $hostos = $targetos -o $targetos = darwin ; then
1737                     CROSS=
1738                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1739                     with_headers=yes
1740                 fi
1741                 ;;
1742
1743             i?86-*-*,x86_64-*-* \
1744             | powerpc*-*-*,powerpc64*-*-*)
1745                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1746         esac
1747 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1748         SYSTEM_HEADER_DIR=$build_system_header_dir
1749 fi
1750
1751 # If this is a cross-compiler that does not
1752 # have its own set of headers then define
1753 # inhibit_libc
1754
1755 # If this is using newlib, without having the headers available now,
1756 # then define inhibit_libc in LIBGCC2_CFLAGS.
1757 # This prevents libgcc2 from containing any code which requires libc
1758 # support.
1759 : ${inhibit_libc=false}
1760 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1761        test x$with_newlib = xyes ; } &&
1762      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1763        inhibit_libc=true
1764 fi
1765 AC_SUBST(inhibit_libc)
1766
1767 # When building gcc with a cross-compiler, we need to adjust things so
1768 # that the generator programs are still built with the native compiler.
1769 # Also, we cannot run fixincludes or fix-header.
1770
1771 # These are the normal (build=host) settings:
1772 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1773 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1774 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1775 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1776
1777 # Possibly disable fixproto, on a per-target basis.
1778 case ${use_fixproto} in
1779   no)
1780     STMP_FIXPROTO=
1781     ;;
1782   yes)
1783     STMP_FIXPROTO=stmp-fixproto
1784     ;;
1785 esac
1786 AC_SUBST(STMP_FIXPROTO)
1787
1788 # And these apply if build != host, or we are generating coverage data
1789 if test x$build != x$host || test "x$coverage_flags" != x
1790 then
1791     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1792     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1793
1794     if test "x$TARGET_SYSTEM_ROOT" = x; then
1795         if test "x$STMP_FIXPROTO" != x; then
1796           STMP_FIXPROTO=stmp-install-fixproto
1797         fi
1798     fi
1799 fi
1800
1801 # Expand extra_headers to include complete path.
1802 # This substitutes for lots of t-* files.
1803 extra_headers_list=
1804 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1805 for file in ${extra_headers} ; do
1806   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1807 done
1808
1809 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1810 if test x"$use_gcc_tgmath" = xyes
1811 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1812 fi
1813
1814 # Define collect2 in Makefile.
1815 case $host_can_use_collect2 in
1816   no) collect2= ;;
1817   *) collect2='collect2$(exeext)' ;;
1818 esac
1819 AC_SUBST([collect2])
1820
1821 # Add a definition of USE_COLLECT2 if system wants one.
1822 case $use_collect2 in
1823   no) use_collect2= ;;
1824   "") ;;
1825   *)
1826     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1827     xm_defines="${xm_defines} USE_COLLECT2"
1828     case $host_can_use_collect2 in
1829       no)
1830         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1831         ;;
1832     esac
1833     ;;
1834 esac
1835
1836 # ---------------------------
1837 # Assembler & linker features
1838 # ---------------------------
1839
1840 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1841 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1842 # However when ld-new is first executed from the build tree, libtool will
1843 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1844 # to the build tree.  While doing this we need to use the previous-stage
1845 # linker, or we have an infinite loop.  The presence of a shell script as
1846 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1847 # the gcc/collect-ld script.  So we need to know how libtool works, or
1848 # exec-tool will fail.
1849
1850 m4_defun([_LT_CONFIG_COMMANDS], [])
1851 AC_PROG_LIBTOOL
1852 AC_SUBST(objdir)
1853 AC_SUBST(enable_fast_install)
1854
1855 # Identify the assembler which will work hand-in-glove with the newly
1856 # built GCC, so that we can examine its features.  This is the assembler
1857 # which will be driven by the driver program.
1858 #
1859 # If build != host, and we aren't building gas in-tree, we identify a
1860 # build->target assembler and hope that it will have the same features
1861 # as the host->target assembler we'll be using.
1862 gcc_cv_gas_major_version=
1863 gcc_cv_gas_minor_version=
1864 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1865
1866 m4_pattern_allow([AS_FOR_TARGET])dnl
1867 AS_VAR_SET_IF(gcc_cv_as,, [
1868 if test -x "$DEFAULT_ASSEMBLER"; then
1869         gcc_cv_as="$DEFAULT_ASSEMBLER"
1870 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1871      && test -f ../gas/Makefile \
1872      && test x$build = x$host; then
1873         gcc_cv_as=../gas/as-new$build_exeext
1874 elif test -x as$build_exeext; then
1875         # Build using assembler in the current directory.
1876         gcc_cv_as=./as$build_exeext
1877 elif test -x $AS_FOR_TARGET; then
1878         gcc_cv_as="$AS_FOR_TARGET"
1879 else
1880         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1881 fi])
1882
1883 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1884 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1885 case "$ORIGINAL_AS_FOR_TARGET" in
1886   ./as | ./as$build_exeext) ;;
1887   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1888 esac
1889
1890 AC_MSG_CHECKING(what assembler to use)
1891 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1892   # Single tree build which includes gas.  We want to prefer it
1893   # over whatever linker top-level may have detected, since
1894   # we'll use what we're building after installation anyway.
1895   AC_MSG_RESULT(newly built gas)
1896   in_tree_gas=yes
1897   _gcc_COMPUTE_GAS_VERSION
1898   in_tree_gas_is_elf=no
1899   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1900      || (grep 'obj_format = multi' ../gas/Makefile \
1901          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1902   then
1903     in_tree_gas_is_elf=yes
1904   fi
1905 else
1906   AC_MSG_RESULT($gcc_cv_as)
1907   in_tree_gas=no
1908 fi
1909
1910 # Identify the linker which will work hand-in-glove with the newly
1911 # built GCC, so that we can examine its features.  This is the linker
1912 # which will be driven by the driver program.
1913 #
1914 # If build != host, and we aren't building gas in-tree, we identify a
1915 # build->target linker and hope that it will have the same features
1916 # as the host->target linker we'll be using.
1917 gcc_cv_gld_major_version=
1918 gcc_cv_gld_minor_version=
1919 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1920 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1921
1922 AS_VAR_SET_IF(gcc_cv_ld,, [
1923 if test -x "$DEFAULT_LINKER"; then
1924         gcc_cv_ld="$DEFAULT_LINKER"
1925 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1926      && test -f ../ld/Makefile \
1927      && test x$build = x$host; then
1928         gcc_cv_ld=../ld/ld-new$build_exeext
1929 elif test -x collect-ld$build_exeext; then
1930         # Build using linker in the current directory.
1931         gcc_cv_ld=./collect-ld$build_exeext
1932 elif test -x $LD_FOR_TARGET; then
1933         gcc_cv_ld="$LD_FOR_TARGET"
1934 else
1935         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1936 fi])
1937
1938 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1939 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1940 case "$ORIGINAL_LD_FOR_TARGET" in
1941   ./collect-ld | ./collect-ld$build_exeext) ;;
1942   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1943 esac
1944
1945 AC_MSG_CHECKING(what linker to use)
1946 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1947         # Single tree build which includes ld.  We want to prefer it
1948         # over whatever linker top-level may have detected, since
1949         # we'll use what we're building after installation anyway.
1950         AC_MSG_RESULT(newly built ld)
1951         in_tree_ld=yes
1952         in_tree_ld_is_elf=no
1953         if (grep 'EMUL = .*elf' ../ld/Makefile \
1954             || grep 'EMUL = .*linux' ../ld/Makefile \
1955             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1956           in_tree_ld_is_elf=yes
1957         fi
1958         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1959         do
1960 changequote(,)dnl
1961                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1962                 if test x$gcc_cv_gld_version != x; then
1963                         break
1964                 fi
1965         done
1966         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1967         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1968 changequote([,])dnl
1969 else
1970         AC_MSG_RESULT($gcc_cv_ld)
1971         in_tree_ld=no
1972 fi
1973
1974 # Figure out what nm we will be using.
1975 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1976 AS_VAR_SET_IF(gcc_cv_nm,, [
1977 if test -f $gcc_cv_binutils_srcdir/configure.in \
1978      && test -f ../binutils/Makefile \
1979      && test x$build = x$host; then
1980         gcc_cv_nm=../binutils/nm-new$build_exeext
1981 elif test -x nm$build_exeext; then
1982         gcc_cv_nm=./nm$build_exeext
1983 elif test -x $NM_FOR_TARGET; then
1984         gcc_cv_nm="$NM_FOR_TARGET"
1985 else
1986         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1987 fi])
1988
1989 AC_MSG_CHECKING(what nm to use)
1990 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1991         # Single tree build which includes binutils.
1992         AC_MSG_RESULT(newly built nm)
1993         in_tree_nm=yes
1994 else
1995         AC_MSG_RESULT($gcc_cv_nm)
1996         in_tree_nm=no
1997 fi
1998
1999 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2000 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2001 case "$ORIGINAL_NM_FOR_TARGET" in
2002   ./nm | ./nm$build_exeext) ;;
2003   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2004 esac
2005
2006
2007 # Figure out what objdump we will be using.
2008 AS_VAR_SET_IF(gcc_cv_objdump,, [
2009 if test -f $gcc_cv_binutils_srcdir/configure.in \
2010      && test -f ../binutils/Makefile \
2011      && test x$build = x$host; then
2012         # Single tree build which includes binutils.
2013         gcc_cv_objdump=../binutils/objdump$build_exeext
2014 elif test -x objdump$build_exeext; then
2015         gcc_cv_objdump=./objdump$build_exeext
2016 elif test -x $OBJDUMP_FOR_TARGET; then
2017         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2018 else
2019         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2020 fi])
2021
2022 AC_MSG_CHECKING(what objdump to use)
2023 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2024         # Single tree build which includes binutils.
2025         AC_MSG_RESULT(newly built objdump)
2026 elif test x$gcc_cv_objdump = x; then
2027         AC_MSG_RESULT(not found)
2028 else
2029         AC_MSG_RESULT($gcc_cv_objdump)
2030 fi
2031
2032 # Figure out what assembler alignment features are present.
2033 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2034  [2,6,0],,
2035 [.balign 4
2036 .p2align 2],,
2037 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2038   [Define if your assembler supports .balign and .p2align.])])
2039
2040 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2041  [2,8,0],,
2042  [.p2align 4,,7],,
2043 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2044   [Define if your assembler supports specifying the maximum number
2045    of bytes to skip when using the GAS .p2align command.])])
2046
2047 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2048  [2,8,0],,
2049  [.literal16],,
2050 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2051   [Define if your assembler supports .literal16.])])
2052
2053 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2054  [elf,2,9,0],,
2055  [conftest_label1: .word 0
2056 .subsection -1
2057 conftest_label2: .word 0
2058 .previous],
2059  [if test x$gcc_cv_nm != x; then
2060     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2061     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2062     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2063     then :
2064     else gcc_cv_as_subsection_m1=yes
2065     fi
2066     rm -f conftest.nm1 conftest.nm2
2067   fi],
2068  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2069   [Define if your assembler supports .subsection and .subsection -1 starts
2070    emitting at the beginning of your section.])])
2071
2072 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2073  [2,2,0],,
2074  [      .weak foobar],,
2075 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2076
2077 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2078  [2,17,0],,
2079  [      .weakref foobar, barfnot],,
2080 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2081
2082 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2083  [2,15,91],,
2084  [      .SPACE $TEXT$
2085         .NSUBSPA $CODE$,COMDAT],,
2086 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2087
2088 # .hidden needs to be supported in both the assembler and the linker,
2089 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2090 # This is irritatingly difficult to feature test for; we have to check the
2091 # date string after the version number.  If we've got an in-tree
2092 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2093 # to be safe.
2094 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2095 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2096  [elf,2,13,0],,
2097 [       .hidden foobar
2098 foobar:])
2099
2100 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2101 [if test $in_tree_ld = yes ; then
2102   gcc_cv_ld_hidden=no
2103   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2104      && test $in_tree_ld_is_elf = yes; then
2105      gcc_cv_ld_hidden=yes
2106   fi
2107 else
2108   gcc_cv_ld_hidden=yes
2109   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2110   if echo "$ld_ver" | grep GNU > /dev/null; then
2111 changequote(,)dnl
2112     ld_vers=`echo $ld_ver | sed -n \
2113         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2114     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2115     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2116     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2117     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2118     if test 0"$ld_date" -lt 20020404; then
2119       if test -n "$ld_date"; then
2120         # If there was date string, but was earlier than 2002-04-04, fail
2121         gcc_cv_ld_hidden=no
2122       elif test -z "$ld_vers"; then
2123         # If there was no date string nor ld version number, something is wrong
2124         gcc_cv_ld_hidden=no
2125       else
2126         test -z "$ld_vers_patch" && ld_vers_patch=0
2127         if test "$ld_vers_major" -lt 2; then
2128           gcc_cv_ld_hidden=no
2129         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2130           gcc_cv_ld_hidden="no"
2131         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2132           gcc_cv_ld_hidden=no
2133         fi
2134       fi
2135 changequote([,])dnl
2136     fi
2137   else
2138     case "${target}" in
2139       hppa64*-*-hpux* | ia64*-*-hpux*)
2140         gcc_cv_ld_hidden=yes
2141         ;;
2142       *)
2143         gcc_cv_ld_hidden=no
2144         ;;
2145     esac
2146   fi
2147 fi])
2148 libgcc_visibility=no
2149 AC_SUBST(libgcc_visibility)
2150 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2151 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2152   libgcc_visibility=yes
2153   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2154   [Define if your assembler and linker support .hidden.])
2155 fi
2156
2157 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2158 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2159   [elf,2,11,0],,
2160 [       .data
2161         .uleb128 L2 - L1
2162 L1:
2163         .uleb128 1280
2164         .sleb128 -1010
2165 L2:],
2166  [# GAS versions before 2.11 do not support uleb128,
2167   # despite appearing to.
2168   # ??? There exists an elf-specific test that will crash
2169   # the assembler.  Perhaps it's better to figure out whether
2170   # arbitrary sections are supported and try the test.
2171   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2172   if echo "$as_ver" | grep GNU > /dev/null; then
2173 changequote(,)dnl
2174     as_vers=`echo $as_ver | sed -n \
2175         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2176     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2177     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2178 changequote([,])dnl
2179     if test $as_major -eq 2 && test $as_minor -lt 11
2180     then :
2181     else gcc_cv_as_leb128=yes
2182     fi
2183   fi],
2184   [AC_DEFINE(HAVE_AS_LEB128, 1,
2185     [Define if your assembler supports .sleb128 and .uleb128.])])
2186
2187 # GAS versions up to and including 2.11.0 may mis-optimize
2188 # .eh_frame data.
2189 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2190   [elf,2,12,0],,
2191 [       .text
2192 .LFB1:
2193         .4byte  0
2194 .L1:
2195         .4byte  0
2196 .LFE1:
2197         .section        .eh_frame,"aw",@progbits
2198 __FRAME_BEGIN__:
2199         .4byte  .LECIE1-.LSCIE1
2200 .LSCIE1:
2201         .4byte  0x0
2202         .byte   0x1
2203         .ascii "z\0"
2204         .byte   0x1
2205         .byte   0x78
2206         .byte   0x1a
2207         .byte   0x0
2208         .byte   0x4
2209         .4byte  1
2210         .p2align 1
2211 .LECIE1:
2212 .LSFDE1:
2213         .4byte  .LEFDE1-.LASFDE1
2214 .LASFDE1:
2215         .4byte  .LASFDE1-__FRAME_BEGIN__
2216         .4byte  .LFB1
2217         .4byte  .LFE1-.LFB1
2218         .byte   0x4
2219         .4byte  .LFE1-.LFB1
2220         .byte   0x4
2221         .4byte  .L1-.LFB1
2222 .LEFDE1:],
2223 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2224 cat > conftest.lit <<EOF
2225  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2226  0010 01000000 12000000 18000000 00000000  ................
2227  0020 08000000 04080000 0044               .........D      @&t@
2228 EOF
2229 cat > conftest.big <<EOF
2230  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2231  0010 00000001 00000012 00000018 00000000  ................
2232  0020 00000008 04000000 0844               .........D      @&t@
2233 EOF
2234   # If the assembler didn't choke, and we can objdump,
2235   # and we got the correct data, then succeed.
2236   # The text in the here-document typically retains its unix-style line
2237   # endings, while the output of objdump will use host line endings.
2238   # Therefore, use diff -b for the comparisons.
2239   if test x$gcc_cv_objdump != x \
2240   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2241      | tail -3 > conftest.got \
2242   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2243     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2244   then
2245     gcc_cv_as_eh_frame=yes
2246   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2247     gcc_cv_as_eh_frame=buggy
2248   else
2249     # Uh oh, what do we do now?
2250     gcc_cv_as_eh_frame=no
2251   fi])
2252
2253 if test $gcc_cv_as_eh_frame = buggy; then
2254   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2255   [Define if your assembler mis-optimizes .eh_frame data.])
2256 fi
2257
2258 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2259  [elf,2,12,0], [--fatal-warnings],
2260  [.section .rodata.str, "aMS", @progbits, 1])
2261 if test $gcc_cv_as_shf_merge = no; then
2262   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2263     [elf,2,12,0], [--fatal-warnings],
2264     [.section .rodata.str, "aMS", %progbits, 1])
2265 fi
2266 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2267   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2268 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2269
2270 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2271  [elf,2,16,0], [--fatal-warnings],
2272  [.section .text,"axG",@progbits,.foo,comdat])
2273 if test $gcc_cv_as_comdat_group = yes; then
2274   gcc_cv_as_comdat_group_percent=no
2275 else
2276  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2277    [elf,2,16,0], [--fatal-warnings],
2278    [.section .text,"axG",%progbits,.foo,comdat])
2279 fi
2280 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2281   comdat_group=yes
2282   if test 0"$ld_date" -lt 20050308; then
2283     if test -n "$ld_date"; then
2284       # If there was date string, but was earlier than 2005-03-08, fail
2285       comdat_group=no
2286     elif test "$ld_vers_major" -lt 2; then
2287       comdat_group=no
2288     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2289       comdat_group=no
2290     fi
2291   fi
2292 else
2293   # assume linkers other than GNU ld don't support COMDAT group
2294   comdat_group=no
2295 fi
2296 if test $comdat_group = no; then
2297   gcc_cv_as_comdat_group=no
2298   gcc_cv_as_comdat_group_percent=no
2299 fi
2300 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2301   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2302 [Define 0/1 if your assembler and linker support COMDAT groups.])
2303
2304 # Thread-local storage - the check is heavily parametrized.
2305 conftest_s=
2306 tls_first_major=
2307 tls_first_minor=
2308 tls_as_opt=
2309 case "$target" in
2310 changequote(,)dnl
2311   alpha*-*-*)
2312     conftest_s='
2313         .section ".tdata","awT",@progbits
2314 foo:    .long   25
2315         .text
2316         ldq     $27,__tls_get_addr($29)         !literal!1
2317         lda     $16,foo($29)                    !tlsgd!1
2318         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2319         ldq     $27,__tls_get_addr($29)         !literal!2
2320         lda     $16,foo($29)                    !tlsldm!2
2321         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2322         ldq     $1,foo($29)                     !gotdtprel
2323         ldah    $2,foo($29)                     !dtprelhi
2324         lda     $3,foo($2)                      !dtprello
2325         lda     $4,foo($29)                     !dtprel
2326         ldq     $1,foo($29)                     !gottprel
2327         ldah    $2,foo($29)                     !tprelhi
2328         lda     $3,foo($2)                      !tprello
2329         lda     $4,foo($29)                     !tprel'
2330         tls_first_major=2
2331         tls_first_minor=13
2332         tls_as_opt=--fatal-warnings
2333         ;;
2334   frv*-*-*)
2335     conftest_s='
2336         .section ".tdata","awT",@progbits
2337 x:      .long   25
2338         .text
2339         call    #gettlsoff(x)'
2340         tls_first_major=2
2341         tls_first_minor=14
2342         ;;
2343   hppa*-*-linux*)
2344     conftest_s='
2345 t1:     .reg    %r20
2346 t2:     .reg    %r21
2347 gp:     .reg    %r19
2348         .section ".tdata","awT",@progbits
2349 foo:    .long   25
2350         .text
2351         .align  4
2352         addil LT%foo-$tls_gdidx$,gp
2353         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2354         b __tls_get_addr
2355         nop
2356         addil LT%foo-$tls_ldidx$,gp
2357         b __tls_get_addr
2358         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2359         addil LR%foo-$tls_dtpoff$,%ret0
2360         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2361         mfctl %cr27,%t1
2362         addil LT%foo-$tls_ieoff$,gp
2363         ldw RT%foo-$tls_ieoff$(%r1),%t2
2364         add %t1,%t2,%t3
2365         mfctl %cr27,%t1
2366         addil LR%foo-$tls_leoff$,%t1
2367         ldo RR%foo-$tls_leoff$(%r1),%t2'
2368         tls_first_major=2
2369         tls_first_minor=15
2370         tls_as_opt=--fatal-warnings
2371         ;;
2372   arm*-*-*)
2373     conftest_s='
2374         .section ".tdata","awT",%progbits
2375 foo:    .long   25
2376         .text
2377 .word foo(gottpoff)
2378 .word foo(tpoff)
2379 .word foo(tlsgd)
2380 .word foo(tlsldm)
2381 .word foo(tlsldo)'
2382         tls_first_major=2
2383         tls_first_minor=17
2384         ;;
2385   i[34567]86-*-*)
2386     conftest_s='
2387         .section ".tdata","awT",@progbits
2388 foo:    .long   25
2389         .text
2390         movl    %gs:0, %eax
2391         leal    foo@TLSGD(,%ebx,1), %eax
2392         leal    foo@TLSLDM(%ebx), %eax
2393         leal    foo@DTPOFF(%eax), %edx
2394         movl    foo@GOTTPOFF(%ebx), %eax
2395         subl    foo@GOTTPOFF(%ebx), %eax
2396         addl    foo@GOTNTPOFF(%ebx), %eax
2397         movl    foo@INDNTPOFF, %eax
2398         movl    $foo@TPOFF, %eax
2399         subl    $foo@TPOFF, %eax
2400         leal    foo@NTPOFF(%ecx), %eax'
2401         tls_first_major=2
2402         tls_first_minor=14
2403         tls_as_opt=--fatal-warnings
2404         ;;
2405   x86_64-*-*)
2406     conftest_s='
2407         .section ".tdata","awT",@progbits
2408 foo:    .long   25
2409         .text
2410         movq    %fs:0, %rax
2411         leaq    foo@TLSGD(%rip), %rdi
2412         leaq    foo@TLSLD(%rip), %rdi
2413         leaq    foo@DTPOFF(%rax), %rdx
2414         movq    foo@GOTTPOFF(%rip), %rax
2415         movq    $foo@TPOFF, %rax'
2416         tls_first_major=2
2417         tls_first_minor=14
2418         tls_as_opt=--fatal-warnings
2419         ;;
2420   ia64-*-*)
2421     conftest_s='
2422         .section ".tdata","awT",@progbits
2423 foo:    data8   25
2424         .text
2425         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2426         addl    r17 = @ltoff(@dtprel(foo#)), gp
2427         addl    r18 = @ltoff(@tprel(foo#)), gp
2428         addl    r19 = @dtprel(foo#), gp
2429         adds    r21 = @dtprel(foo#), r13
2430         movl    r23 = @dtprel(foo#)
2431         addl    r20 = @tprel(foo#), gp
2432         adds    r22 = @tprel(foo#), r13
2433         movl    r24 = @tprel(foo#)'
2434         tls_first_major=2
2435         tls_first_minor=13
2436         tls_as_opt=--fatal-warnings
2437         ;;
2438   mips*-*-*)
2439     conftest_s='
2440         .section .tdata,"awT",@progbits
2441 x:
2442         .word 2
2443         .text
2444         addiu $4, $28, %tlsgd(x)
2445         addiu $4, $28, %tlsldm(x)
2446         lui $4, %dtprel_hi(x)
2447         addiu $4, $4, %dtprel_lo(x)
2448         lw $4, %gottprel(x)($28)
2449         lui $4, %tprel_hi(x)
2450         addiu $4, $4, %tprel_lo(x)'
2451         tls_first_major=2
2452         tls_first_minor=16
2453         tls_as_opt='-32 --fatal-warnings'
2454         ;;
2455   powerpc-*-*)
2456     conftest_s='
2457         .section ".tdata","awT",@progbits
2458         .align 2
2459 ld0:    .space 4
2460 ld1:    .space 4
2461 x1:     .space 4
2462 x2:     .space 4
2463 x3:     .space 4
2464         .text
2465         addi 3,31,ld0@got@tlsgd
2466         bl __tls_get_addr
2467         addi 3,31,x1@got@tlsld
2468         bl __tls_get_addr
2469         addi 9,3,x1@dtprel
2470         addis 9,3,x2@dtprel@ha
2471         addi 9,9,x2@dtprel@l
2472         lwz 9,x3@got@tprel(31)
2473         add 9,9,x@tls
2474         addi 9,2,x1@tprel
2475         addis 9,2,x2@tprel@ha
2476         addi 9,9,x2@tprel@l'
2477         tls_first_major=2
2478         tls_first_minor=14
2479         tls_as_opt="-a32 --fatal-warnings"
2480         ;;
2481   powerpc64-*-*)
2482     conftest_s='
2483         .section ".tdata","awT",@progbits
2484         .align 3
2485 ld0:    .space 8
2486 ld1:    .space 8
2487 x1:     .space 8
2488 x2:     .space 8
2489 x3:     .space 8
2490         .text
2491         addi 3,2,ld0@got@tlsgd
2492         bl .__tls_get_addr
2493         nop
2494         addi 3,2,ld1@toc
2495         bl .__tls_get_addr
2496         nop
2497         addi 3,2,x1@got@tlsld
2498         bl .__tls_get_addr
2499         nop
2500         addi 9,3,x1@dtprel
2501         bl .__tls_get_addr
2502         nop
2503         addis 9,3,x2@dtprel@ha
2504         addi 9,9,x2@dtprel@l
2505         bl .__tls_get_addr
2506         nop
2507         ld 9,x3@got@dtprel(2)
2508         add 9,9,3
2509         bl .__tls_get_addr
2510         nop'
2511         tls_first_major=2
2512         tls_first_minor=14
2513         tls_as_opt="-a64 --fatal-warnings"
2514         ;;
2515   s390-*-*)
2516     conftest_s='
2517         .section ".tdata","awT",@progbits
2518 foo:    .long   25
2519         .text
2520         .long   foo@TLSGD
2521         .long   foo@TLSLDM
2522         .long   foo@DTPOFF
2523         .long   foo@NTPOFF
2524         .long   foo@GOTNTPOFF
2525         .long   foo@INDNTPOFF
2526         l       %r1,foo@GOTNTPOFF(%r12)
2527         l       %r1,0(%r1):tls_load:foo
2528         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2529         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2530         tls_first_major=2
2531         tls_first_minor=14
2532         tls_as_opt="-m31 --fatal-warnings"
2533         ;;
2534   s390x-*-*)
2535     conftest_s='
2536         .section ".tdata","awT",@progbits
2537 foo:    .long   25
2538         .text
2539         .quad   foo@TLSGD
2540         .quad   foo@TLSLDM
2541         .quad   foo@DTPOFF
2542         .quad   foo@NTPOFF
2543         .quad   foo@GOTNTPOFF
2544         lg      %r1,foo@GOTNTPOFF(%r12)
2545         larl    %r1,foo@INDNTPOFF
2546         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2547         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2548         tls_first_major=2
2549         tls_first_minor=14
2550         tls_as_opt="-m64 -Aesame --fatal-warnings"
2551         ;;
2552   sh-*-* | sh[34]-*-*)
2553     conftest_s='
2554         .section ".tdata","awT",@progbits
2555 foo:    .long   25
2556         .text
2557         .long   foo@TLSGD
2558         .long   foo@TLSLDM
2559         .long   foo@DTPOFF
2560         .long   foo@GOTTPOFF
2561         .long   foo@TPOFF'
2562         tls_first_major=2
2563         tls_first_minor=13
2564         tls_as_opt=--fatal-warnings
2565         ;;
2566   sparc*-*-*)
2567     case "$target" in
2568       sparc*-sun-solaris2.[56789]*)
2569         # TLS was introduced in the Solaris 9 4/04 release but
2570         # we do not enable it by default on Solaris 9 either.
2571         if test "x$enable_tls" = xyes ; then
2572           on_solaris=yes
2573         else
2574           enable_tls=no;
2575         fi
2576         ;;
2577       sparc*-sun-solaris2.*)
2578         on_solaris=yes
2579         ;;
2580       *)
2581         on_solaris=no
2582         ;;
2583     esac
2584     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2585       conftest_s='
2586         .section ".tdata",#alloc,#write,#tls
2587 foo:    .long   25
2588         .text
2589         sethi   %tgd_hi22(foo), %o0
2590         add     %o0, %tgd_lo10(foo), %o1
2591         add     %l7, %o1, %o0, %tgd_add(foo)
2592         call    __tls_get_addr, %tgd_call(foo)
2593         sethi   %tldm_hi22(foo), %l1
2594         add     %l1, %tldm_lo10(foo), %l2
2595         add     %l7, %l2, %o0, %tldm_add(foo)
2596         call    __tls_get_addr, %tldm_call(foo)
2597         sethi   %tldo_hix22(foo), %l3
2598         xor     %l3, %tldo_lox10(foo), %l4
2599         add     %o0, %l4, %l5, %tldo_add(foo)
2600         sethi   %tie_hi22(foo), %o3
2601         add     %o3, %tie_lo10(foo), %o3
2602         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2603         add     %g7, %o2, %o4, %tie_add(foo)
2604         sethi   %tle_hix22(foo), %l1
2605         xor     %l1, %tle_lox10(foo), %o5
2606         ld      [%g7 + %o5], %o1'
2607         tls_first_major=0
2608         tls_first_minor=0
2609     else
2610       conftest_s='
2611         .section ".tdata","awT",@progbits
2612 foo:    .long   25
2613         .text
2614         sethi   %tgd_hi22(foo), %o0
2615         add     %o0, %tgd_lo10(foo), %o1
2616         add     %l7, %o1, %o0, %tgd_add(foo)
2617         call    __tls_get_addr, %tgd_call(foo)
2618         sethi   %tldm_hi22(foo), %l1
2619         add     %l1, %tldm_lo10(foo), %l2
2620         add     %l7, %l2, %o0, %tldm_add(foo)
2621         call    __tls_get_addr, %tldm_call(foo)
2622         sethi   %tldo_hix22(foo), %l3
2623         xor     %l3, %tldo_lox10(foo), %l4
2624         add     %o0, %l4, %l5, %tldo_add(foo)
2625         sethi   %tie_hi22(foo), %o3
2626         add     %o3, %tie_lo10(foo), %o3
2627         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2628         add     %g7, %o2, %o4, %tie_add(foo)
2629         sethi   %tle_hix22(foo), %l1
2630         xor     %l1, %tle_lox10(foo), %o5
2631         ld      [%g7 + %o5], %o1'
2632         tls_first_major=2
2633         tls_first_minor=14
2634         tls_as_opt="-32 --fatal-warnings"
2635       fi
2636         ;;
2637 changequote([,])dnl
2638 esac
2639 set_have_as_tls=no
2640 if test "x$enable_tls" = xno ; then
2641   : # TLS explicitly disabled.
2642 elif test "x$enable_tls" = xyes ; then
2643   set_have_as_tls=yes # TLS explicitly enabled.
2644 elif test -z "$tls_first_major"; then
2645   : # If we don't have a check, assume no support.
2646 else
2647   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2648   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2649   [set_have_as_tls=yes])
2650 fi
2651 if test $set_have_as_tls = yes ; then
2652   AC_DEFINE(HAVE_AS_TLS, 1,
2653             [Define if your assembler supports thread-local storage.])
2654 fi
2655
2656 # Target-specific assembler checks.
2657
2658 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2659 gcc_cv_ld_static_dynamic=no
2660 if test $in_tree_ld = yes ; then
2661   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2662     gcc_cv_ld_static_dynamic=yes
2663   fi
2664 elif test x$gcc_cv_ld != x; then
2665         # Check if linker supports -Bstatic/-Bdynamic option
2666         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2667           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2668                 gcc_cv_ld_static_dynamic=yes
2669         fi
2670 fi
2671 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2672         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2673 [Define if your linker supports -Bstatic/-Bdynamic option.])
2674 fi
2675 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2676
2677 if test x"$demangler_in_ld" = xyes; then
2678   AC_MSG_CHECKING(linker --demangle support)
2679   gcc_cv_ld_demangle=no
2680   if test $in_tree_ld = yes; then
2681     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2682       gcc_cv_ld_demangle=yes
2683     fi
2684   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2685     # Check if the GNU linker supports --demangle option
2686     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2687       gcc_cv_ld_demangle=yes
2688     fi
2689   fi
2690   if test x"$gcc_cv_ld_demangle" = xyes; then
2691     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2692 [Define if your linker supports --demangle option.])
2693   fi
2694   AC_MSG_RESULT($gcc_cv_ld_demangle)
2695 fi
2696
2697 case "$target" in
2698   # All TARGET_ABI_OSF targets.
2699   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2700     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2701         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2702 [       .set nomacro
2703         .text
2704         extbl   $3, $2, $3      !lituse_bytoff!1
2705         ldq     $2, a($29)      !literal!1
2706         ldq     $4, b($29)      !literal!2
2707         ldq_u   $3, 0($2)       !lituse_base!1
2708         ldq     $27, f($29)     !literal!5
2709         jsr     $26, ($27), f   !lituse_jsr!5
2710         ldah    $29, 0($26)     !gpdisp!3
2711         lda     $0, c($29)      !gprel
2712         ldah    $1, d($29)      !gprelhigh
2713         lda     $1, d($1)       !gprellow
2714         lda     $29, 0($29)     !gpdisp!3],,
2715     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2716   [Define if your assembler supports explicit relocations.])])
2717     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2718         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2719 [       .set nomacro
2720         .text
2721         ldq     $27, a($29)     !literal!1
2722         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2723     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2724   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2725     ;;
2726
2727   cris-*-*)
2728     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2729       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2730       [-no-mul-bug-abort], [.text],,
2731       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2732                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2733     ;;
2734
2735   sparc*-*-*)
2736     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2737       [.register %g2, #scratch],,
2738       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2739                 [Define if your assembler supports .register.])])
2740
2741     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2742       [-relax], [.text],,
2743       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2744                 [Define if your assembler supports -relax option.])])
2745
2746     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2747       gcc_cv_as_sparc_ua_pcrel,,
2748       [-K PIC],
2749 [.text
2750 foo:
2751         nop
2752 .data
2753 .align 4
2754 .byte 0
2755 .uaword %r_disp32(foo)],
2756       [if test x$gcc_cv_ld != x \
2757        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2758          gcc_cv_as_sparc_ua_pcrel=yes
2759        fi
2760        rm -f conftest],
2761       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2762                 [Define if your assembler and linker support unaligned PC relative relocs.])
2763
2764       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2765         gcc_cv_as_sparc_ua_pcrel_hidden,,
2766         [-K PIC],
2767 [.data
2768 .align 4
2769 .byte 0x31
2770 .uaword %r_disp32(foo)
2771 .byte 0x32, 0x33, 0x34
2772 .global foo
2773 .hidden foo
2774 foo:
2775 .skip 4],
2776         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2777          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2778          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2779             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2780             if $gcc_cv_objdump -R conftest 2> /dev/null \
2781                | grep 'DISP32' > /dev/null 2>&1; then
2782                 :
2783             else
2784                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2785             fi
2786          fi
2787          rm -f conftest],
2788          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2789                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2790     ]) # unaligned pcrel relocs
2791
2792     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2793       gcc_cv_as_sparc_offsetable_lo10,,
2794       [-xarch=v9],
2795 [.text
2796         or %g1, %lo(ab) + 12, %g1
2797         or %g1, %lo(ab + 12), %g1],
2798       [if test x$gcc_cv_objdump != x \
2799        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2800           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2801          gcc_cv_as_sparc_offsetable_lo10=yes
2802        fi],
2803        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2804                  [Define if your assembler supports offsetable %lo().])])
2805     ;;
2806
2807 changequote(,)dnl
2808   i[34567]86-*-* | x86_64-*-*)
2809 changequote([,])dnl
2810     case $target_os in
2811       cygwin* | pe | mingw32*)
2812         # Used for DWARF 2 in PE
2813         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2814           gcc_cv_as_ix86_pe_secrel32,
2815           [2,15,91],,
2816 [.text
2817 foo:    nop
2818 .data
2819         .secrel32 foo],
2820           [if test x$gcc_cv_ld != x \
2821            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2822              gcc_cv_as_ix86_pe_secrel32=yes
2823            fi
2824            rm -f conftest],
2825           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2826             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2827         ;;
2828     esac
2829
2830     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2831        gcc_cv_as_ix86_filds_fists,
2832       [2,9,0],, [filds mem; fists mem],,
2833       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2834         [Define if your assembler uses the new HImode fild and fist notation.])])
2835
2836     gcc_GAS_CHECK_FEATURE([cmov syntax],
2837       gcc_cv_as_ix86_cmov_sun_syntax,,,
2838       [cmovl.l %edx, %eax],,
2839       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2840         [Define if your assembler supports the Sun syntax for cmov.])])
2841
2842     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2843       gcc_cv_as_ix86_ffreep,,,
2844       [ffreep %st(1)],,
2845       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2846         [Define if your assembler supports the ffreep mnemonic.])])
2847
2848     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2849       gcc_cv_as_ix86_sahf,,,
2850       [sahf],,
2851       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2852         [Define if your assembler supports the sahf mnemonic.])])
2853
2854     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2855       gcc_cv_as_ix86_diff_sect_delta,,,
2856       [.section .rodata
2857 .L1:
2858         .long .L2-.L1
2859         .long .L3-.L1
2860         .text
2861 .L3:    nop
2862 .L2:    nop],,
2863       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2864         [Define if your assembler supports the subtraction of symbols in different sections.])])
2865
2866     # This one is used unconditionally by i386.[ch]; it is to be defined
2867     # to 1 if the feature is present, 0 otherwise.
2868     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2869         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2870 [       .text
2871 .L0:
2872         nop
2873         .data
2874         .long .L0@GOTOFF])
2875     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2876       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2877       [Define true if the assembler supports '.long foo@GOTOFF'.])
2878     ;;
2879
2880   ia64*-*-*)
2881     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2882         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2883 [       .text
2884         addl r15 = @ltoffx(x#), gp
2885         ;;
2886         ld8.mov r16 = [[r15]], x#],,
2887     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2888           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2889
2890     ;;
2891
2892   powerpc*-*-*)
2893     case $target in
2894       *-*-aix*) conftest_s='    .machine "pwr5"
2895         .csect .text[[PR]]
2896         mfcr 3,128';;
2897       *-*-darwin*)
2898         gcc_GAS_CHECK_FEATURE([.machine directive support],
2899           gcc_cv_as_machine_directive,,,
2900           [     .machine ppc7400])
2901         if test x$gcc_cv_as_machine_directive != xyes; then
2902           echo "*** This target requires an assembler supporting \".machine\"" >&2
2903           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2904           test x$build = x$target && exit 1
2905         fi
2906         conftest_s='    .text
2907         mfcr r3,128';;
2908       *) conftest_s='   .machine power4
2909         .text
2910         mfcr 3,128';;
2911     esac
2912
2913     gcc_GAS_CHECK_FEATURE([mfcr field support],
2914       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2915       [$conftest_s],,
2916       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2917           [Define if your assembler supports mfcr field.])])
2918
2919     case $target in
2920       *-*-aix*) conftest_s='    .machine "pwr5"
2921         .csect .text[[PR]]
2922         popcntb 3,3';;
2923       *) conftest_s='   .machine power5
2924         .text
2925         popcntb 3,3';;
2926     esac
2927
2928     gcc_GAS_CHECK_FEATURE([popcntb support],
2929       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2930       [$conftest_s],,
2931       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2932           [Define if your assembler supports popcntb field.])])
2933
2934     case $target in
2935       *-*-aix*) conftest_s='    .machine "pwr5x"
2936         .csect .text[[PR]]
2937         frin 1,1';;
2938       *) conftest_s='   .machine power5
2939         .text
2940         frin 1,1';;
2941     esac
2942
2943     gcc_GAS_CHECK_FEATURE([fp round support],
2944       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2945       [$conftest_s],,
2946       [AC_DEFINE(HAVE_AS_FPRND, 1,
2947           [Define if your assembler supports fprnd.])])
2948
2949     case $target in
2950       *-*-aix*) conftest_s='    .machine "pwr6"
2951         .csect .text[[PR]]
2952         mffgpr 1,3';;
2953       *) conftest_s='   .machine power6
2954         .text
2955         mffgpr 1,3';;
2956     esac
2957
2958     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2959       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2960       [$conftest_s],,
2961       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2962           [Define if your assembler supports mffgpr and mftgpr.])])
2963
2964     case $target in
2965       *-*-aix*) conftest_s='    .csect .text[[PR]]
2966 LCF..0:
2967         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2968       *-*-darwin*)
2969         conftest_s='    .text
2970 LCF0:
2971         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2972       *) conftest_s='   .text
2973 .LCF0:
2974         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2975     esac
2976
2977     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2978       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2979       [$conftest_s],,
2980       [AC_DEFINE(HAVE_AS_REL16, 1,
2981           [Define if your assembler supports R_PPC_REL16 relocs.])])
2982
2983     case $target in
2984       *-*-aix*) conftest_s='    .machine "pwr6"
2985         .csect .text[[PR]]
2986         cmpb 3,4,5';;
2987       *) conftest_s='   .machine power6
2988         .text
2989         cmpb 3,4,5';;
2990     esac
2991
2992     gcc_GAS_CHECK_FEATURE([compare bytes support],
2993       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2994       [$conftest_s],,
2995       [AC_DEFINE(HAVE_AS_CMPB, 1,
2996           [Define if your assembler supports cmpb.])])
2997
2998     case $target in
2999       *-*-aix*) conftest_s='    .machine "pwr6"
3000         .csect .text[[PR]]
3001         dadd 1,2,3';;
3002       *) conftest_s='   .machine power6
3003         .text
3004         dadd 1,2,3';;
3005     esac
3006
3007     gcc_GAS_CHECK_FEATURE([decimal float support],
3008       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
3009       [$conftest_s],,
3010       [AC_DEFINE(HAVE_AS_DFP, 1,
3011           [Define if your assembler supports DFP instructions.])])
3012
3013     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3014       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3015       [.gnu_attribute 4,1],,
3016       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3017           [Define if your assembler supports .gnu_attribute.])])
3018     ;;
3019
3020   mips*-*-*)
3021     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3022       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3023 [       lw $4,%gp_rel(foo)($4)],,
3024       [if test x$target_cpu_default = x
3025        then target_cpu_default=MASK_EXPLICIT_RELOCS
3026        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3027        fi])
3028     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3029       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3030       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3031                  [Define if the assembler understands -mno-shared.])])
3032
3033     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3034       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3035       [.gnu_attribute 4,1],,
3036       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3037           [Define if your assembler supports .gnu_attribute.])])
3038
3039     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3040       gcc_cv_as_mips_dtprelword, [2,18,0],,
3041       [.section .tdata,"awT",@progbits
3042 x:
3043         .word 2
3044         .text
3045         .dtprelword x+0x8000],,
3046       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3047           [Define if your assembler supports .dtprelword.])])
3048     ;;
3049 esac
3050
3051 # Mips and HP-UX need the GNU assembler.
3052 # Linux on IA64 might be able to use the Intel assembler.
3053
3054 case "$target" in
3055   mips*-*-* | *-*-hpux* )
3056     if test x$gas_flag = xyes \
3057        || test x"$host" != x"$build" \
3058        || test ! -x "$gcc_cv_as" \
3059        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3060       :
3061     else
3062       echo "*** This configuration requires the GNU assembler" >&2
3063       exit 1
3064     fi
3065     ;;
3066 esac
3067
3068 # ??? Not all targets support dwarf2 debug_line, even within a version
3069 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3070 # info to the output file.  So, as supported targets are added to gas 2.11,
3071 # add some instruction here to (also) show we expect this might work.
3072 # ??? Once 2.11 is released, probably need to add first known working
3073 # version to the per-target configury.
3074 case "$target" in
3075   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3076   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3077   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* \
3078   | spu-*-* | fido*-*-*)
3079     insn="nop"
3080     ;;
3081   ia64*-*-* | s390*-*-*)
3082     insn="nop 0"
3083     ;;
3084   mmix-*-*)
3085     insn="swym 0"
3086     ;;
3087 esac
3088 if test x"$insn" != x; then
3089  conftest_s="\
3090         .file 1 \"conftest.s\"
3091         .loc 1 3 0
3092         $insn"
3093  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3094   gcc_cv_as_dwarf2_debug_line,
3095   [elf,2,11,0],, [$conftest_s],
3096   [if test x$gcc_cv_objdump != x \
3097    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3098       | grep debug_line > /dev/null 2>&1; then
3099      gcc_cv_as_dwarf2_debug_line=yes
3100    fi])
3101
3102 # The .debug_line file table must be in the exact order that
3103 # we specified the files, since these indices are also used
3104 # by DW_AT_decl_file.  Approximate this test by testing if
3105 # the assembler bitches if the same index is assigned twice.
3106  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3107   gcc_cv_as_dwarf2_file_buggy,,,
3108 [       .file 1 "foo.s"
3109         .file 1 "bar.s"])
3110
3111  if test $gcc_cv_as_dwarf2_debug_line = yes \
3112  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3113         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3114   [Define if your assembler supports dwarf2 .file/.loc directives,
3115    and preserves file table indices exactly as given.])
3116  fi
3117
3118  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3119   gcc_cv_as_gdwarf2_flag,
3120   [elf,2,11,0], [--gdwarf2], [$insn],,
3121   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3122 [Define if your assembler supports the --gdwarf2 option.])])
3123
3124  gcc_GAS_CHECK_FEATURE([--gstabs option],
3125   gcc_cv_as_gstabs_flag,
3126   [elf,2,11,0], [--gstabs], [$insn],
3127   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3128    # and warns about it, but still exits successfully.  So check for
3129    # this.
3130    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3131    then :
3132    else gcc_cv_as_gstabs_flag=yes
3133    fi],
3134   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3135 [Define if your assembler supports the --gstabs option.])])
3136
3137  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3138   gcc_cv_as_debug_prefix_map_flag,
3139   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3140   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3141 [Define if your assembler supports the --debug-prefix-map option.])])
3142 fi
3143
3144 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3145  [gcc_cv_as_line_zero],
3146  [gcc_cv_as_line_zero=no
3147   if test $in_tree_gas = yes; then
3148     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3149   elif test "x$gcc_cv_as" != x; then
3150     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3151     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3152        test "x`cat conftest.out`" = x
3153     then
3154       gcc_cv_as_line_zero=yes
3155     else
3156       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3157       cat conftest.s >&AS_MESSAGE_LOG_FD
3158       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3159       cat conftest.out >&AS_MESSAGE_LOG_FD
3160     fi
3161     rm -f conftest.o conftest.s conftest.out
3162   fi])
3163 if test "x$gcc_cv_as_line_zero" = xyes; then
3164   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3165 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3166 fi
3167
3168 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3169 gcc_cv_ld_ro_rw_mix=unknown
3170 if test $in_tree_ld = yes ; then
3171   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3172      && test $in_tree_ld_is_elf = yes; then
3173     gcc_cv_ld_ro_rw_mix=read-write
3174   fi
3175 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3176   echo '.section myfoosect, "a"' > conftest1.s
3177   echo '.section myfoosect, "aw"' > conftest2.s
3178   echo '.byte 1' >> conftest2.s
3179   echo '.section myfoosect, "a"' > conftest3.s
3180   echo '.byte 0' >> conftest3.s
3181   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3182      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3183      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3184      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3185         conftest2.o conftest3.o > /dev/null 2>&1; then
3186     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3187                          | sed -e '/myfoosect/!d' -e N`
3188     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3189       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3190         gcc_cv_ld_ro_rw_mix=read-only
3191       else
3192         gcc_cv_ld_ro_rw_mix=read-write
3193       fi
3194     fi
3195   fi
3196 changequote(,)dnl
3197   rm -f conftest.* conftest[123].*
3198 changequote([,])dnl
3199 fi
3200 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3201         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3202   [Define if your linker links a mix of read-only
3203    and read-write sections into a read-write section.])
3204 fi
3205 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3206
3207 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3208 gcc_cv_ld_eh_frame_hdr=no
3209 if test $in_tree_ld = yes ; then
3210   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3211      && test $in_tree_ld_is_elf = yes; then
3212     gcc_cv_ld_eh_frame_hdr=yes
3213   fi
3214 elif test x$gcc_cv_ld != x; then
3215         # Check if linker supports --eh-frame-hdr option
3216         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3217                 gcc_cv_ld_eh_frame_hdr=yes
3218         fi
3219 fi
3220 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3221 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3222         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3223 [Define if your linker supports --eh-frame-hdr option.])
3224 fi
3225 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3226
3227 AC_MSG_CHECKING(linker position independent executable support)
3228 gcc_cv_ld_pie=no
3229 if test $in_tree_ld = yes ; then
3230   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3231      && test $in_tree_ld_is_elf = yes; then
3232     gcc_cv_ld_pie=yes
3233   fi
3234 elif test x$gcc_cv_ld != x; then
3235         # Check if linker supports -pie option
3236         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3237                 gcc_cv_ld_pie=yes
3238         fi
3239 fi
3240 if test x"$gcc_cv_ld_pie" = xyes; then
3241         AC_DEFINE(HAVE_LD_PIE, 1,
3242 [Define if your linker supports -pie option.])
3243 fi
3244 AC_MSG_RESULT($gcc_cv_ld_pie)
3245
3246 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3247 gcc_cv_ld_eh_gc_sections=no
3248 if test $in_tree_ld = yes ; then
3249   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3250      && test $in_tree_ld_is_elf = yes; then
3251     gcc_cv_ld_eh_gc_sections=yes
3252   fi
3253 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3254   cat > conftest.s <<EOF
3255         .section        .text
3256 .globl _start
3257         .type _start, @function
3258 _start:
3259         .long foo
3260         .size _start, .-_start
3261         .section        .text.foo,"ax",@progbits
3262         .type foo, @function
3263 foo:
3264         .long 0
3265         .size foo, .-foo
3266         .section        .gcc_except_table.foo,"a",@progbits
3267 .L0:
3268         .long 0
3269         .section        .eh_frame,"a",@progbits
3270         .long .L0
3271 EOF
3272   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3273     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3274          | grep "gc-sections option ignored" > /dev/null; then
3275       gcc_cv_ld_eh_gc_sections=no
3276     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3277       gcc_cv_ld_eh_gc_sections=yes
3278       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3279       if test x$gcc_cv_as_comdat_group != xyes; then
3280         gcc_cv_ld_eh_gc_sections=no
3281         cat > conftest.s <<EOF
3282         .section        .text
3283 .globl _start
3284         .type _start, @function
3285 _start:
3286         .long foo
3287         .size _start, .-_start
3288         .section        .gnu.linkonce.t.foo,"ax",@progbits
3289         .type foo, @function
3290 foo:
3291         .long 0
3292         .size foo, .-foo
3293         .section        .gcc_except_table.foo,"a",@progbits
3294 .L0:
3295         .long 0
3296         .section        .eh_frame,"a",@progbits
3297         .long .L0
3298 EOF
3299         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3300           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3301                | grep "gc-sections option ignored" > /dev/null; then
3302             gcc_cv_ld_eh_gc_sections=no
3303           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3304             gcc_cv_ld_eh_gc_sections=yes
3305           fi
3306         fi
3307       fi
3308     fi
3309   fi
3310   rm -f conftest.s conftest.o conftest
3311 fi
3312 case "$target" in
3313   hppa*-*-linux*)
3314     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3315     gcc_cv_ld_eh_gc_sections=no
3316     ;;
3317 esac
3318 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3319         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3320   [Define if your linker supports garbage collection of
3321    sections in presence of EH frames.])
3322 fi
3323 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3324
3325 # --------
3326 # UNSORTED
3327 # --------
3328
3329 AC_CACHE_CHECK(linker --as-needed support,
3330 gcc_cv_ld_as_needed,
3331 [gcc_cv_ld_as_needed=no
3332 if test $in_tree_ld = yes ; then
3333   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3334      && test $in_tree_ld_is_elf = yes; then
3335     gcc_cv_ld_as_needed=yes
3336   fi
3337 elif test x$gcc_cv_ld != x; then
3338         # Check if linker supports --as-needed and --no-as-needed options
3339         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3340                 gcc_cv_ld_as_needed=yes
3341         fi
3342 fi
3343 ])
3344 if test x"$gcc_cv_ld_as_needed" = xyes; then
3345         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3346 [Define if your linker supports --as-needed and --no-as-needed options.])
3347 fi
3348
3349 case "$target:$tm_file" in
3350   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3351     AC_CACHE_CHECK(linker support for omitting dot symbols,
3352     gcc_cv_ld_no_dot_syms,
3353     [gcc_cv_ld_no_dot_syms=no
3354     if test $in_tree_ld = yes ; then
3355       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3356         gcc_cv_ld_no_dot_syms=yes
3357       fi
3358     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3359       cat > conftest1.s <<EOF
3360         .text
3361         bl .foo
3362 EOF
3363       cat > conftest2.s <<EOF
3364         .section ".opd","aw"
3365         .align 3
3366         .globl foo
3367         .type foo,@function
3368 foo:
3369         .quad .LEfoo,.TOC.@tocbase,0
3370         .text
3371 .LEfoo:
3372         blr
3373         .size foo,.-.LEfoo
3374 EOF
3375       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3376          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3377          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3378         gcc_cv_ld_no_dot_syms=yes
3379       fi
3380       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3381     fi
3382     ])
3383     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3384       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3385     [Define if your PowerPC64 linker only needs function descriptor syms.])
3386     fi
3387     ;;
3388 esac
3389
3390 AC_CACHE_CHECK(linker --sysroot support,
3391   gcc_cv_ld_sysroot,
3392   [gcc_cv_ld_sysroot=no
3393   if test $in_tree_ld = yes ; then
3394       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3395         gcc_cv_ld_sysroot=yes
3396       fi
3397   elif test x$gcc_cv_ld != x; then
3398     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3399       gcc_cv_ld_sysroot=yes
3400     fi
3401   fi])
3402 if test x"$gcc_cv_ld_sysroot" = xyes; then
3403   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3404   [Define if your linker supports --sysroot.])
3405 fi
3406
3407 if test x$with_sysroot = x && test x$host = x$target \
3408    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3409    && test "$prefix" != "NONE"; then
3410   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3411 [Define to PREFIX/include if cpp should also search that directory.])
3412 fi
3413
3414 # Test for stack protector support in target C library.
3415 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3416       gcc_cv_libc_provides_ssp,
3417       [gcc_cv_libc_provides_ssp=no
3418     case "$target" in
3419        *-*-linux*)
3420       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3421         if test "x$with_sysroot" = x; then
3422           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3423         elif test "x$with_build_sysroot" != "x"; then
3424           glibc_header_dir="${with_build_sysroot}/usr/include"
3425         elif test "x$with_sysroot" = xyes; then
3426           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3427         else
3428           glibc_header_dir="${with_sysroot}/usr/include"
3429         fi
3430       else
3431         glibc_header_dir=/usr/include
3432       fi
3433       # glibc 2.4 and later provides __stack_chk_fail and
3434       # either __stack_chk_guard, or TLS access to stack guard canary.
3435       if test -f $glibc_header_dir/features.h \
3436          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3437             $glibc_header_dir/features.h > /dev/null; then
3438         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3439            $glibc_header_dir/features.h > /dev/null; then
3440           gcc_cv_libc_provides_ssp=yes
3441         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3442              $glibc_header_dir/features.h > /dev/null \
3443              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3444              $glibc_header_dir/features.h > /dev/null; then
3445           gcc_cv_libc_provides_ssp=yes
3446         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3447              $glibc_header_dir/features.h > /dev/null && \
3448              test -f $glibc_header_dir/bits/uClibc_config.h && \
3449              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3450              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3451           gcc_cv_libc_provides_ssp=yes
3452         fi
3453       fi
3454         ;;
3455        *-*-darwin*)
3456          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3457            [echo "no __stack_chk_fail on this target"])
3458         ;;
3459   *) gcc_cv_libc_provides_ssp=no ;;
3460     esac])
3461
3462 if test x$gcc_cv_libc_provides_ssp = xyes; then
3463   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3464             [Define if your target C library provides stack protector support])
3465 fi
3466
3467 # Check if TFmode long double should be used by default or not.
3468 # Some glibc targets used DFmode long double, but with glibc 2.4
3469 # and later they can use TFmode.
3470 case "$target" in
3471   powerpc*-*-linux* | \
3472   powerpc*-*-gnu* | \
3473   sparc*-*-linux* | \
3474   s390*-*-linux* | \
3475   alpha*-*-linux*)
3476     AC_ARG_WITH(long-double-128,
3477 [  --with-long-double-128  Use 128-bit long double by default.],
3478       gcc_cv_target_ldbl128="$with_long_double_128",
3479       [gcc_cv_target_ldbl128=no
3480       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3481         if test "x$with_sysroot" = x; then
3482           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3483         elif test "x$with_build_sysroot" != "x"; then
3484           glibc_header_dir="${with_build_sysroot}/usr/include"
3485         elif test "x$with_sysroot" = xyes; then
3486           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3487         else
3488           glibc_header_dir="${with_sysroot}/usr/include"
3489         fi
3490       else
3491         glibc_header_dir=/usr/include
3492       fi
3493 changequote(,)dnl
3494       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3495         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3496       && gcc_cv_target_ldbl128=yes
3497 changequote([,])dnl
3498       ])
3499     ;;
3500 esac
3501 if test x$gcc_cv_target_ldbl128 = xyes; then
3502   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3503             [Define if TFmode long double should be the default])
3504 fi
3505
3506 # Find out what GC implementation we want, or may, use.
3507 AC_ARG_WITH(gc,
3508 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3509                           with the compiler],
3510 [case "$withval" in
3511   page)
3512     GGC=ggc-$withval
3513     ;;
3514   zone)
3515     GGC=ggc-$withval
3516     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3517     ;;
3518   *)
3519     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3520     ;;
3521 esac],
3522 [GGC=ggc-page])
3523 AC_SUBST(GGC)
3524 echo "Using $GGC for garbage collection."
3525
3526 # Use the system's zlib library.
3527 zlibdir=-L../zlib
3528 zlibinc="-I\$(srcdir)/../zlib"
3529 AC_ARG_WITH(system-zlib,
3530 [  --with-system-zlib      use installed libz],
3531 zlibdir=
3532 zlibinc=
3533 )
3534 AC_SUBST(zlibdir)
3535 AC_SUBST(zlibinc)
3536
3537 dnl Very limited version of automake's enable-maintainer-mode
3538
3539 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3540   dnl maintainer-mode is disabled by default
3541   AC_ARG_ENABLE(maintainer-mode,
3542 [  --enable-maintainer-mode
3543                           enable make rules and dependencies not useful
3544                           (and sometimes confusing) to the casual installer],
3545       maintainer_mode=$enableval,
3546       maintainer_mode=no)
3547
3548 AC_MSG_RESULT($maintainer_mode)
3549
3550 if test "$maintainer_mode" = "yes"; then
3551   MAINT=''
3552 else
3553   MAINT='#'
3554 fi
3555 AC_SUBST(MAINT)dnl
3556
3557 # --------------
3558 # Language hooks
3559 # --------------
3560
3561 # Make empty files to contain the specs and options for each language.
3562 # Then add #include lines to for a compiler that has specs and/or options.
3563
3564 subdirs=
3565 lang_opt_files=
3566 lang_specs_files=
3567 lang_tree_files=
3568 # These (without "all_") are set in each config-lang.in.
3569 # `language' must be a single word so is spelled singularly.
3570 all_languages=
3571 all_compilers=
3572 all_outputs='Makefile gccbug libada-mk'
3573 # List of language makefile fragments.
3574 all_lang_makefrags=
3575 # List of language subdirectory makefiles.  Deprecated.
3576 all_lang_makefiles=
3577 # Additional files for gengtype
3578 all_gtfiles="$target_gtfiles"
3579
3580 # These are the languages that are set in --enable-languages,
3581 # and are available in the GCC tree.
3582 all_selected_languages=
3583
3584 # Add the language fragments.
3585 # Languages are added via two mechanisms.  Some information must be
3586 # recorded in makefile variables, these are defined in config-lang.in.
3587 # We accumulate them and plug them into the main Makefile.
3588 # The other mechanism is a set of hooks for each of the main targets
3589 # like `clean', `install', etc.
3590
3591 language_hooks="Make-hooks"
3592
3593 for lang in ${srcdir}/*/config-lang.in
3594 do
3595 changequote(,)dnl
3596         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3597
3598         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3599         if test "x$lang_alias" = x
3600         then
3601               echo "$lang doesn't set \$language." 1>&2
3602               exit 1
3603         fi
3604         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3605         subdirs="$subdirs $subdir"
3606
3607         # $gcc_subdir is where the gcc integration files are to be found
3608         # for a language, both for internal compiler purposes (compiler
3609         # sources implementing front-end to GCC tree converters), and for
3610         # build infrastructure purposes (Make-lang.in, etc.)
3611         #
3612         # This will be <subdir> (relative to $srcdir) if a line like
3613         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3614         # is found in <langdir>/config-lang.in, and will remain <langdir>
3615         # otherwise.
3616         #
3617         # Except for the language alias (fetched above), the regular
3618         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3619         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3620         # only this and the language alias.
3621
3622         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3623         if [ "$gcc_subdir" = "" ]; then
3624            gcc_subdir="$subdir"
3625         fi
3626
3627         case ",$enable_languages," in
3628         *,$lang_alias,*)
3629             all_selected_languages="$all_selected_languages $lang_alias"
3630             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3631                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3632             fi
3633             ;;
3634         esac
3635 changequote([,])dnl
3636
3637         language=
3638         boot_language=
3639         compilers=
3640         outputs=
3641         gtfiles=
3642         subdir_requires=
3643         . ${srcdir}/$gcc_subdir/config-lang.in
3644         if test "x$language" = x
3645         then
3646                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3647                 exit 1
3648         fi
3649
3650         ok=:
3651         case ",$enable_languages," in
3652                 *,$lang_alias,*) ;;
3653                 *)
3654                         for i in $subdir_requires; do
3655                                 test -f "${srcdir}/$i/config-lang.in" && continue
3656                                 ok=false
3657                                 break
3658                         done
3659                 ;;
3660         esac
3661         $ok || continue
3662
3663         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3664         if test -f $srcdir/$gcc_subdir/lang.opt; then
3665             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3666         fi
3667         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3668             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3669         fi
3670         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3671                 then all_lang_makefiles="$gcc_subdir/Makefile"
3672         fi
3673         all_languages="$all_languages $language"
3674         all_compilers="$all_compilers $compilers"
3675         all_outputs="$all_outputs $outputs"
3676         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3677 done
3678
3679 # Pick up gtfiles for c
3680 gtfiles=
3681 . ${srcdir}/c-config-lang.in
3682 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3683
3684 check_languages=
3685 for language in $all_selected_languages
3686 do
3687         check_languages="$check_languages check-$language"
3688 done
3689
3690 # We link each language in with a set of hooks, reached indirectly via
3691 # lang.${target}.  Only do so for selected languages.
3692
3693 rm -f Make-hooks
3694 touch Make-hooks
3695 target_list="all.cross start.encap rest.encap tags \
3696         install-common install-man install-info install-pdf dvi pdf \
3697         html uninstall info man srcextra srcman srcinfo \
3698         mostlyclean clean distclean maintainer-clean"
3699
3700 for t in $target_list
3701 do
3702         x=
3703         for lang in $all_selected_languages
3704         do
3705                 x="$x $lang.$t"
3706         done
3707         echo "lang.$t: $x" >> Make-hooks
3708 done
3709
3710 # --------
3711 # UNSORTED
3712 # --------
3713
3714 # Create .gdbinit.
3715
3716 echo "dir ." > .gdbinit
3717 echo "dir ${srcdir}" >> .gdbinit
3718 if test x$gdb_needs_out_file_path = xyes
3719 then
3720         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3721 fi
3722 if test "x$subdirs" != x; then
3723         for s in $subdirs
3724         do
3725                 echo "dir ${srcdir}/$s" >> .gdbinit
3726         done
3727 fi
3728 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3729
3730 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3731 AC_SUBST(gcc_tooldir)
3732 AC_SUBST(dollar)
3733
3734 # Find a directory in which to install a shared libgcc.
3735
3736 AC_ARG_ENABLE(version-specific-runtime-libs,
3737 [  --enable-version-specific-runtime-libs
3738                           specify that runtime libraries should be
3739                           installed in a compiler-specific directory])
3740
3741 AC_ARG_WITH(slibdir,
3742 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3743 slibdir="$with_slibdir",
3744 if test "${enable_version_specific_runtime_libs+set}" = set; then
3745   slibdir='$(libsubdir)'
3746 elif test "$host" != "$target"; then
3747   slibdir='$(build_tooldir)/lib'
3748 else
3749   slibdir='$(libdir)'
3750 fi)
3751 AC_SUBST(slibdir)
3752
3753 AC_ARG_WITH(datarootdir,
3754 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3755 datarootdir="\${prefix}/$with_datarootdir",
3756 datarootdir='$(prefix)/share')
3757 AC_SUBST(datarootdir)
3758
3759 AC_ARG_WITH(docdir,
3760 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3761 docdir="\${prefix}/$with_docdir",
3762 docdir='$(datarootdir)')
3763 AC_SUBST(docdir)
3764
3765 AC_ARG_WITH(htmldir,
3766 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3767 htmldir="\${prefix}/$with_htmldir",
3768 htmldir='$(docdir)')
3769 AC_SUBST(htmldir)
3770
3771 # Substitute configuration variables
3772 AC_SUBST(subdirs)
3773 AC_SUBST(srcdir)
3774 AC_SUBST(all_compilers)
3775 AC_SUBST(all_gtfiles)
3776 AC_SUBST(all_lang_makefrags)
3777 AC_SUBST(all_lang_makefiles)
3778 AC_SUBST(all_languages)
3779 AC_SUBST(all_selected_languages)
3780 AC_SUBST(build_exeext)
3781 AC_SUBST(build_install_headers_dir)
3782 AC_SUBST(build_xm_file_list)
3783 AC_SUBST(build_xm_include_list)
3784 AC_SUBST(build_xm_defines)
3785 AC_SUBST(build_file_translate)
3786 AC_SUBST(check_languages)
3787 AC_SUBST(cpp_install_dir)
3788 AC_SUBST(xmake_file)
3789 AC_SUBST(tmake_file)
3790 AC_SUBST(extra_gcc_objs)
3791 AC_SUBST(extra_headers_list)
3792 AC_SUBST(extra_objs)
3793 AC_SUBST(extra_parts)
3794 AC_SUBST(extra_passes)
3795 AC_SUBST(extra_programs)
3796 AC_SUBST(float_h_file)
3797 AC_SUBST(gcc_config_arguments)
3798 AC_SUBST(gcc_gxx_include_dir)
3799 AC_SUBST(host_exeext)
3800 AC_SUBST(host_xm_file_list)
3801 AC_SUBST(host_xm_include_list)
3802 AC_SUBST(host_xm_defines)
3803 AC_SUBST(out_host_hook_obj)
3804 AC_SUBST(install)
3805 AC_SUBST(lang_opt_files)
3806 AC_SUBST(lang_specs_files)
3807 AC_SUBST(lang_tree_files)
3808 AC_SUBST(local_prefix)
3809 AC_SUBST(md_file)
3810 AC_SUBST(objc_boehm_gc)
3811 AC_SUBST(out_file)
3812 AC_SUBST(out_object_file)
3813 AC_SUBST(thread_file)
3814 AC_SUBST(tm_file_list)
3815 AC_SUBST(tm_include_list)
3816 AC_SUBST(tm_defines)
3817 AC_SUBST(tm_p_file_list)
3818 AC_SUBST(tm_p_include_list)
3819 AC_SUBST(xm_file_list)
3820 AC_SUBST(xm_include_list)
3821 AC_SUBST(xm_defines)
3822 AC_SUBST(c_target_objs)
3823 AC_SUBST(cxx_target_objs)
3824 AC_SUBST(fortran_target_objs)
3825 AC_SUBST(target_cpu_default)
3826
3827 AC_SUBST_FILE(language_hooks)
3828
3829 # Echo link setup.
3830 if test x${build} = x${host} ; then
3831   if test x${host} = x${target} ; then
3832     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3833   else
3834     echo "Links are now set up to build a cross-compiler" 1>&2
3835     echo " from ${host} to ${target}." 1>&2
3836   fi
3837 else
3838   if test x${host} = x${target} ; then
3839     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3840     echo " for ${target}." 1>&2
3841   else
3842     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3843     echo " from ${host} to ${target}." 1>&2
3844   fi
3845 fi
3846
3847 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3848 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3849
3850 # Configure the subdirectories
3851 # AC_CONFIG_SUBDIRS($subdirs)
3852
3853 # Create the Makefile
3854 # and configure language subdirectories
3855 AC_CONFIG_FILES($all_outputs)
3856
3857 AC_CONFIG_COMMANDS([default],
3858 [
3859 case ${CONFIG_HEADERS} in
3860   *auto-host.h:config.in*)
3861   echo > cstamp-h ;;
3862 esac
3863 # Make sure all the subdirs exist.
3864 for d in $subdirs doc build
3865 do
3866     test -d $d || mkdir $d
3867 done
3868 ],
3869 [subdirs='$subdirs'])
3870 AC_OUTPUT