]>
Commit | Line | Data |
---|---|---|
953ff289 DN |
1 | dnl ---------------------------------------------------------------------- |
2 | dnl This whole bit snagged from libgfortran. | |
3 | ||
4 | dnl Check whether the target supports __sync_*_compare_and_swap. | |
5 | AC_DEFUN([LIBGOMP_CHECK_SYNC_BUILTINS], [ | |
6 | AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap], | |
7 | have_sync_builtins, [ | |
8 | AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);], | |
9 | have_sync_builtins=yes, have_sync_builtins=no)]) | |
10 | if test $have_sync_builtins = yes; then | |
11 | AC_DEFINE(HAVE_SYNC_BUILTINS, 1, | |
12 | [Define to 1 if the target supports __sync_*_compare_and_swap]) | |
13 | fi]) | |
14 | ||
15 | dnl Check whether the target supports hidden visibility. | |
16 | AC_DEFUN([LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY], [ | |
17 | AC_CACHE_CHECK([whether the target supports hidden visibility], | |
18 | have_attribute_visibility, [ | |
19 | save_CFLAGS="$CFLAGS" | |
20 | CFLAGS="$CFLAGS -Werror" | |
21 | AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }], | |
22 | [], have_attribute_visibility=yes, | |
23 | have_attribute_visibility=no) | |
24 | CFLAGS="$save_CFLAGS"]) | |
25 | if test $have_attribute_visibility = yes; then | |
26 | AC_DEFINE(HAVE_ATTRIBUTE_VISIBILITY, 1, | |
27 | [Define to 1 if the target supports __attribute__((visibility(...))).]) | |
28 | fi]) | |
29 | ||
30 | dnl Check whether the target supports dllexport | |
31 | AC_DEFUN([LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT], [ | |
32 | AC_CACHE_CHECK([whether the target supports dllexport], | |
33 | have_attribute_dllexport, [ | |
34 | save_CFLAGS="$CFLAGS" | |
35 | CFLAGS="$CFLAGS -Werror" | |
36 | AC_TRY_COMPILE([void __attribute__((dllexport)) foo(void) { }], | |
37 | [], have_attribute_dllexport=yes, | |
38 | have_attribute_dllexport=no) | |
39 | CFLAGS="$save_CFLAGS"]) | |
40 | if test $have_attribute_dllexport = yes; then | |
41 | AC_DEFINE(HAVE_ATTRIBUTE_DLLEXPORT, 1, | |
42 | [Define to 1 if the target supports __attribute__((dllexport)).]) | |
43 | fi]) | |
44 | ||
45 | dnl Check whether the target supports symbol aliases. | |
46 | AC_DEFUN([LIBGOMP_CHECK_ATTRIBUTE_ALIAS], [ | |
47 | AC_CACHE_CHECK([whether the target supports symbol aliases], | |
48 | have_attribute_alias, [ | |
49 | AC_TRY_LINK([ | |
953ff289 | 50 | void foo(void) { } |
8887708e | 51 | extern void bar(void) __attribute__((alias("foo")));], |
953ff289 DN |
52 | [bar();], have_attribute_alias=yes, have_attribute_alias=no)]) |
53 | if test $have_attribute_alias = yes; then | |
54 | AC_DEFINE(HAVE_ATTRIBUTE_ALIAS, 1, | |
55 | [Define to 1 if the target supports __attribute__((alias(...))).]) | |
56 | fi]) | |
57 | ||
58 | sinclude(../libtool.m4) | |
59 | dnl The lines below arrange for aclocal not to bring an installed | |
60 | dnl libtool.m4 into aclocal.m4, while still arranging for automake to | |
61 | dnl add a definition of LIBTOOL to Makefile.in. | |
62 | ifelse(,,,[AC_SUBST(LIBTOOL) | |
63 | AC_DEFUN([AM_PROG_LIBTOOL]) | |
64 | AC_DEFUN([AC_LIBTOOL_DLOPEN]) | |
65 | AC_DEFUN([AC_PROG_LD]) | |
66 | ]) | |
67 | ||
68 | dnl ---------------------------------------------------------------------- | |
69 | dnl This whole bit snagged from libstdc++-v3. | |
70 | ||
71 | dnl | |
72 | dnl LIBGOMP_ENABLE | |
73 | dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING) | |
74 | dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c) | |
75 | dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER) | |
76 | dnl | |
77 | dnl See docs/html/17_intro/configury.html#enable for documentation. | |
78 | dnl | |
79 | m4_define([LIBGOMP_ENABLE],[dnl | |
80 | m4_define([_g_switch],[--enable-$1])dnl | |
81 | m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl | |
82 | AC_ARG_ENABLE($1,_g_help, | |
83 | m4_bmatch([$5], | |
84 | [^permit ], | |
85 | [[ | |
86 | case "$enableval" in | |
87 | m4_bpatsubst([$5],[permit ])) ;; | |
88 | *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;; | |
89 | dnl Idea for future: generate a URL pointing to | |
90 | dnl "onlinedocs/configopts.html#whatever" | |
91 | esac | |
92 | ]], | |
93 | [^$], | |
94 | [[ | |
95 | case "$enableval" in | |
96 | yes|no) ;; | |
97 | *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;; | |
98 | esac | |
99 | ]], | |
100 | [[$5]]), | |
101 | [enable_]m4_bpatsubst([$1],-,_)[=][$2]) | |
102 | m4_undefine([_g_switch])dnl | |
103 | m4_undefine([_g_help])dnl | |
104 | ]) | |
105 | ||
106 | ||
107 | dnl | |
108 | dnl If GNU ld is in use, check to see if tricky linker opts can be used. If | |
109 | dnl the native linker is in use, all variables will be defined to something | |
110 | dnl safe (like an empty string). | |
111 | dnl | |
112 | dnl Defines: | |
113 | dnl SECTION_LDFLAGS='-Wl,--gc-sections' if possible | |
114 | dnl OPT_LDFLAGS='-Wl,-O1' if possible | |
115 | dnl LD (as a side effect of testing) | |
116 | dnl Sets: | |
117 | dnl with_gnu_ld | |
118 | dnl libgomp_gnu_ld_version (possibly) | |
119 | dnl | |
120 | dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will | |
121 | dnl set libgomp_gnu_ld_version to 12345. Zeros cause problems. | |
122 | dnl | |
123 | AC_DEFUN([LIBGOMP_CHECK_LINKER_FEATURES], [ | |
124 | # If we're not using GNU ld, then there's no point in even trying these | |
125 | # tests. Check for that first. We should have already tested for gld | |
126 | # by now (in libtool), but require it now just to be safe... | |
127 | test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS='' | |
128 | test -z "$OPT_LDFLAGS" && OPT_LDFLAGS='' | |
129 | AC_REQUIRE([AC_PROG_LD]) | |
130 | AC_REQUIRE([AC_PROG_AWK]) | |
131 | ||
132 | # The name set by libtool depends on the version of libtool. Shame on us | |
133 | # for depending on an impl detail, but c'est la vie. Older versions used | |
134 | # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on | |
135 | # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually | |
136 | # makes sense). We'll test with_gnu_ld everywhere else, so if that isn't | |
137 | # set (hence we're using an older libtool), then set it. | |
138 | if test x${with_gnu_ld+set} != xset; then | |
139 | if test x${ac_cv_prog_gnu_ld+set} != xset; then | |
140 | # We got through "ac_require(ac_prog_ld)" and still not set? Huh? | |
141 | with_gnu_ld=no | |
142 | else | |
143 | with_gnu_ld=$ac_cv_prog_gnu_ld | |
144 | fi | |
145 | fi | |
146 | ||
147 | # Start by getting the version number. I think the libtool test already | |
148 | # does some of this, but throws away the result. | |
149 | changequote(,) | |
150 | ldver=`$LD --version 2>/dev/null | head -1 | \ | |
151 | sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'` | |
152 | changequote([,]) | |
153 | libgomp_gnu_ld_version=`echo $ldver | \ | |
154 | $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'` | |
155 | ||
156 | # Set --gc-sections. | |
157 | if test "$with_gnu_ld" = "notbroken"; then | |
158 | # GNU ld it is! Joy and bunny rabbits! | |
159 | ||
160 | # All these tests are for C++; save the language and the compiler flags. | |
161 | # Need to do this so that g++ won't try to link in libstdc++ | |
162 | ac_test_CFLAGS="${CFLAGS+set}" | |
163 | ac_save_CFLAGS="$CFLAGS" | |
164 | CFLAGS='-x c++ -Wl,--gc-sections' | |
165 | ||
166 | # Check for -Wl,--gc-sections | |
167 | # XXX This test is broken at the moment, as symbols required for linking | |
168 | # are now in libsupc++ (not built yet). In addition, this test has | |
169 | # cored on solaris in the past. In addition, --gc-sections doesn't | |
170 | # really work at the moment (keeps on discarding used sections, first | |
171 | # .eh_frame and now some of the glibc sections for iconv). | |
172 | # Bzzzzt. Thanks for playing, maybe next time. | |
173 | AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections]) | |
174 | AC_TRY_RUN([ | |
175 | int main(void) | |
176 | { | |
177 | try { throw 1; } | |
178 | catch (...) { }; | |
179 | return 0; | |
180 | } | |
181 | ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes]) | |
182 | if test "$ac_test_CFLAGS" = set; then | |
183 | CFLAGS="$ac_save_CFLAGS" | |
184 | else | |
185 | # this is the suspicious part | |
186 | CFLAGS='' | |
187 | fi | |
188 | if test "$ac_sectionLDflags" = "yes"; then | |
189 | SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS" | |
190 | fi | |
191 | AC_MSG_RESULT($ac_sectionLDflags) | |
192 | fi | |
193 | ||
194 | # Set linker optimization flags. | |
195 | if test x"$with_gnu_ld" = x"yes"; then | |
196 | OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS" | |
197 | fi | |
198 | ||
199 | AC_SUBST(SECTION_LDFLAGS) | |
200 | AC_SUBST(OPT_LDFLAGS) | |
201 | ]) | |
202 | ||
203 | ||
204 | dnl | |
205 | dnl Add version tags to symbols in shared library (or not), additionally | |
206 | dnl marking other symbols as private/local (or not). | |
207 | dnl | |
208 | dnl --enable-symvers=style adds a version script to the linker call when | |
209 | dnl creating the shared library. The choice of version script is | |
210 | dnl controlled by 'style'. | |
211 | dnl --disable-symvers does not. | |
212 | dnl + Usage: LIBGOMP_ENABLE_SYMVERS[(DEFAULT)] | |
213 | dnl Where DEFAULT is either 'yes' or 'no'. Passing `yes' tries to | |
214 | dnl choose a default style based on linker characteristics. Passing | |
215 | dnl 'no' disables versioning. | |
216 | dnl | |
217 | AC_DEFUN([LIBGOMP_ENABLE_SYMVERS], [ | |
218 | ||
219 | LIBGOMP_ENABLE(symvers,yes,[=STYLE], | |
220 | [enables symbol versioning of the shared library], | |
221 | [permit yes|no|gnu]) | |
222 | ||
223 | # If we never went through the LIBGOMP_CHECK_LINKER_FEATURES macro, then we | |
224 | # don't know enough about $LD to do tricks... | |
225 | AC_REQUIRE([LIBGOMP_CHECK_LINKER_FEATURES]) | |
226 | # FIXME The following test is too strict, in theory. | |
227 | if test $enable_shared = no || | |
228 | test "x$LD" = x || | |
229 | test x$libgomp_gnu_ld_version = x; then | |
230 | enable_symvers=no | |
231 | fi | |
232 | ||
233 | # Check to see if libgcc_s exists, indicating that shared libgcc is possible. | |
234 | if test $enable_symvers != no; then | |
235 | AC_MSG_CHECKING([for shared libgcc]) | |
236 | ac_save_CFLAGS="$CFLAGS" | |
237 | CFLAGS=' -lgcc_s' | |
238 | AC_TRY_LINK(, [return 0;], libgomp_shared_libgcc=yes, libgomp_shared_libgcc=no) | |
239 | CFLAGS="$ac_save_CFLAGS" | |
240 | if test $libgomp_shared_libgcc = no; then | |
241 | cat > conftest.c <<EOF | |
242 | int main (void) { return 0; } | |
243 | EOF | |
244 | changequote(,)dnl | |
245 | libgomp_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \ | |
246 | -shared -shared-libgcc -o conftest.so \ | |
247 | conftest.c -v 2>&1 >/dev/null \ | |
248 | | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'` | |
249 | changequote([,])dnl | |
250 | rm -f conftest.c conftest.so | |
251 | if test x${libgomp_libgcc_s_suffix+set} = xset; then | |
252 | CFLAGS=" -lgcc_s$libgomp_libgcc_s_suffix" | |
253 | AC_TRY_LINK(, [return 0;], libgomp_shared_libgcc=yes) | |
254 | CFLAGS="$ac_save_CFLAGS" | |
255 | fi | |
256 | fi | |
257 | AC_MSG_RESULT($libgomp_shared_libgcc) | |
258 | fi | |
259 | ||
260 | # For GNU ld, we need at least this version. The format is described in | |
261 | # LIBGOMP_CHECK_LINKER_FEATURES above. | |
262 | libgomp_min_gnu_ld_version=21400 | |
263 | # XXXXXXXXXXX libgomp_gnu_ld_version=21390 | |
264 | ||
265 | # Check to see if unspecified "yes" value can win, given results above. | |
266 | # Change "yes" into either "no" or a style name. | |
267 | if test $enable_symvers = yes; then | |
268 | if test $with_gnu_ld = yes && | |
269 | test $libgomp_shared_libgcc = yes; | |
270 | then | |
271 | if test $libgomp_gnu_ld_version -ge $libgomp_min_gnu_ld_version ; then | |
272 | enable_symvers=gnu | |
273 | else | |
274 | # The right tools, the right setup, but too old. Fallbacks? | |
275 | AC_MSG_WARN(=== Linker version $libgomp_gnu_ld_version is too old for) | |
276 | AC_MSG_WARN(=== full symbol versioning support in this release of GCC.) | |
277 | AC_MSG_WARN(=== You would need to upgrade your binutils to version) | |
278 | AC_MSG_WARN(=== $libgomp_min_gnu_ld_version or later and rebuild GCC.) | |
279 | if test $libgomp_gnu_ld_version -ge 21200 ; then | |
280 | # Globbing fix is present, proper block support is not. | |
281 | dnl AC_MSG_WARN([=== Dude, you are soooo close. Maybe we can fake it.]) | |
282 | dnl enable_symvers=??? | |
283 | AC_MSG_WARN([=== Symbol versioning will be disabled.]) | |
284 | enable_symvers=no | |
285 | else | |
286 | # 2.11 or older. | |
287 | AC_MSG_WARN([=== Symbol versioning will be disabled.]) | |
288 | enable_symvers=no | |
289 | fi | |
290 | fi | |
291 | else | |
292 | # just fail for now | |
293 | AC_MSG_WARN([=== You have requested some kind of symbol versioning, but]) | |
294 | AC_MSG_WARN([=== either you are not using a supported linker, or you are]) | |
295 | AC_MSG_WARN([=== not building a shared libgcc_s (which is required).]) | |
296 | AC_MSG_WARN([=== Symbol versioning will be disabled.]) | |
297 | enable_symvers=no | |
298 | fi | |
299 | fi | |
300 | ||
301 | AM_CONDITIONAL(LIBGOMP_BUILD_VERSIONED_SHLIB, test $enable_symvers != no) | |
302 | AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers) | |
303 | ]) |