tests for --help (was: [PATCH 0/N] Fix --help output.)

[Ralf Wildenhues <Ralf dot Wildenhues at gmx dot de>]

Hi Ben,

* Ben Elliston wrote on Sun, Mar 01, 2009 at 10:52:07PM CET:
> > I have a set of patches to fix various related bugs in this area, but
> > I need help: how can I add test cases to the testsuite that just run the
> > compiler driver with some extra flags, and test its output against some
> > regexes, ideally multi-line?  I'm not very fluent in GCC dejagnu.
> 
> Take a look at testsuite/gcc.misc-tests/options.exp.  That may be
> sufficient, or could be adapted.

Thank you!  That helped me find more issues with my other proposed patch.

How about this?  OK for 4.5?

Do I need to take into account localization issues here?  If yes, how
would I go about it?

Here's how I tested it: with the compiler before my patch set, I get
these failures:

  Running /tmp/gcc/gcc/testsuite/gcc.misc-tests/help.exp ...
  FAIL: compiler driver --help option(s): --version
  FAIL: compiler driver -v --help option(s): are likely to\n  -std
  FAIL: compiler driver --help=joined option(s): Wformat=
  FAIL: compiler driver --help=separate option(s): -MF
  FAIL: compiler driver --help=warnings,joined option(s): Wtrigraphs
  FAIL: compiler driver --help=warnings,^joined option(s): Wformat=
  FAIL: compiler driver --help=^joined,separate option(s): --param 

                  === gcc Summary ===

  # of expected passes            54
  # of unexpected failures        7
  # of expected failures          4

while with trunk plus the proposed patch for PR 37805, things are as
expected.

(BTW, I did leave in copyright years from options.exp due to remaining
common ground.)

Cheers,
Ralf

gcc/testsuite/ChangeLog:
2009-03-05  Ralf Wildenhues  <Ralf.Wildenhues@gmx.de>

	* gcc.misc-tests/help.exp: New file.

diff --git a/gcc/testsuite/gcc.misc-tests/help.exp b/gcc/testsuite/gcc.misc-tests/help.exp
new file mode 100644
index 0000000..2027da5
--- /dev/null
+++ b/gcc/testsuite/gcc.misc-tests/help.exp
@@ -0,0 +1,123 @@
+# Copyright (C) 2005, 2007, 2009 Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with GCC; see the file COPYING3.  If not see
+# <http://www.gnu.org/licenses/>.
+
+# Run the LANGUAGE compiler with GCC_OPTIONS and inspect the compiler
+# output to make sure that they match the newline-separated patterns
+# in COMPILER_PATTERNS but not the patterns in COMPILER_NON_PATTERNS.
+# In case of failure, xfail if XFAIL is nonempty.
+
+proc check_for_help_options {language gcc_options compiler_patterns compiler_non_patterns xfail} {
+    set filename test-[pid]
+    set fd [open $filename.c w]
+    puts $fd "int main (void) \{ return 0; \}"
+    close $fd
+    remote_download host $filename.c
+
+    set test "compiler driver $gcc_options option(s):"
+    set gcc_options "\{additional_flags=$gcc_options\}"
+
+    switch "$language" {
+	"c" { set compiler cc1 }
+	default { error "unknown language" }
+    }
+    set gcc_output [gcc_target_compile $filename.c $filename.x executable $gcc_options]
+    remote_file build delete $filename.c $filename.x $filename.gcno
+
+    foreach pattern [split $compiler_patterns "\n"] {
+	if {$pattern ne ""} {
+	    if {[regexp -- "$pattern" $gcc_output]} {
+		pass "$test $pattern"
+	    } else {
+		if {$xfail ne ""} {
+		    xfail "$test $pattern"
+		} else {
+		    fail "$test $pattern"
+		}
+	    }
+	}
+    }
+    foreach pattern [split $compiler_non_patterns "\n"] {
+	if {$pattern ne ""} {
+	    if {![regexp -- "$pattern" $gcc_output]} {
+		pass "$test $pattern"
+	    } else {
+		if {$xfail ne ""} {
+		    xfail "$test $pattern"
+		} else {
+		    fail "$test $pattern"
+		}
+	    }
+	}
+    }
+    pass $test
+}
+
+# Document --version.  No undocumented switches in --help.
+check_for_help_options c {--help} {--version} {This switch lacks documentation} {}
+
+# No intermingled output; pick up help strings from duplicate option flags
+check_for_help_options c {-v --help} {} {
+[^\n]The following options
+-Wconversion[^\n]*lacks documentation
+"  -g  "
+} {}
+
+# There are still undocumented switches in -v --help.
+check_for_help_options c {-v --help} {} {This switch lacks documentation} {xfail}
+
+# Multiline conversion in optc-gen.
+check_for_help_options c {-v --help} {} {are likely to\n  -std} {}
+
+# --help= classes and qualifiers.
+check_for_help_options c {--help=optimizers} {-O} {  -g  } {}
+check_for_help_options c {--help=params} {maximum number of} {-Wunsafe-loop-optimizations} {}
+check_for_help_options c {--help=C} {-ansi} {-gnatO} {}
+check_for_help_options c {--help=C++} {-std=c\+\+} {-gnatO} {}
+check_for_help_options c {--help=common} {-dumpbase} {-gnatO} {}
+check_for_help_options c {--help=undocumented} {This switch lacks documentation} {} {}
+
+# undocumented flags are not yet consistently marked as such.
+check_for_help_options c {--help=^undocumented} {-Wall} {This switch lacks documentation} {xfail}
+
+# Examples from the manual.
+check_for_help_options c {--help=target,undocumented} {} {} {}
+check_for_help_options c {--help=target,optimizers} {} {} {}
+check_for_help_options c {--help=warnings,^joined,^undocumented} {} {} {}
+check_for_help_options c {-Q -O2 --help=optimizers} {
+-O
+-ftree-vectorize[^\n]*disabled
+} {  -g  } {}
+check_for_help_options c {-Q -O3 --help=optimizers} {
+-O
+-ftree-vectorize[^\n]*enabled
+} {  -g  } {}
+# Repeated --help=
+check_for_help_options c {--help=params --help=optimizers} {
+maximum number of
+-O
+} {} {}
+
+# PR 37805
+check_for_help_options c {--help=joined} {Wformat=} {-fstrict-prototype} {}
+check_for_help_options c {--help=separate} {-MF} {-fstrict-prototype} {}
+check_for_help_options c {--help=warnings,joined} {Wformat=} {Wtrigraphs} {}
+check_for_help_options c {--help=warnings,^joined} {Wtrigraphs} {Wformat=} {}
+check_for_help_options c {--help=joined,separate} {-I} {} {}
+check_for_help_options c {--help=^joined,separate} {--param } {} {}
+check_for_help_options c {--help=joined,^separate} {--help=} {} {}
+check_for_help_options c {--help=joined,undocumented} {} {} {}
+# Listing only excludes gives empty results.
+check_for_help_options c {--help=^joined,^separate} {} {} {}