This is the mail archive of the
gcc-patches@gcc.gnu.org
mailing list for the GCC project.
Nuke opts.sh, replace with four AWK files
- From: Kelley Cook <kcook at gcc dot gnu dot org>
- To: GCC Patches <gcc-patches at gcc dot gnu dot org>
- Cc: Neil Booth <neil at daikokuya dot co dot uk>
- Date: Thu, 17 Jun 2004 11:23:36 -0400
- Subject: Nuke opts.sh, replace with four AWK files
- Hop-count: 1
Neil's clever option collector, opts.sh is a layer of indirection which
makes editing and debugging the actual AWK code it uses difficult. So,
I broke out the generated code from that file into its four components.
opt-gather.awk which collects the data from *.opt into a sorted single
flatfile DB.
opth-gen.awk which creates the options.h file
optc-gen.awk which creates the options.c file
opt-functions.awk which contains Zdenek's recently created subroutines
The generated options.c and options.h are, besides an intentional
whitespace adjustment, identical to their previous incarnations.
OK to install?
Kelley Cook
2004-06-17 Kelley Cook <kcook@gcc.gnu.org>
* opts.sh: Delete. Break out generated code to next four files.
* opt-gather.awk: New file.
* optc-gen.awk: New file.
* opth-gen.awk: New file.
* opt-functions.awk: New common file.
* Makefile.in: Update for above.
* configure.ac: Update comment.
* configure: Regenerate.
diff -Nupd ../../gcc-orig/gcc/Makefile.in ./Makefile.in
--- ../../gcc-orig/gcc/Makefile.in 2004-06-11 19:41:08.000000000 -0400
+++ ./Makefile.in 2004-06-17 09:54:29.804993500 -0400
@@ -1511,13 +1511,21 @@ s-specs : Makefile
$(SHELL) $(srcdir)/../move-if-change tmp-specs.h specs.h
$(STAMP) s-specs
-options.c options.h: s-options ; @true
-s-options: $(lang_opt_files) $(srcdir)/opts.sh Makefile
- AWK=$(AWK) $(SHELL) $(srcdir)/opts.sh \
- '$(SHELL) $(srcdir)/../move-if-change' \
- options.c options.h $(lang_opt_files)
+optionlist: s-options ; @true
+s-options: $(lang_opt_files) Makefile $(srcdir)/opt-gather.awk
+ $(AWK) -f $(srcdir)/opt-gather.awk $(lang_opt_files) > tmp-optionlist
+ $(SHELL) $(srcdir)/../move-if-change tmp-optionlist optionlist
$(STAMP) s-options
+
+options.c: optionlist $(srcdir)/opt-functions.awk $(srcdir)/optc-gen.awk
+ $(AWK) -f $(srcdir)/opt-functions.awk -f $(srcdir)/optc-gen.awk \
+ -v header_name="options.h" < $< > $@
+
+options.h: optionlist $(srcdir)/opt-functions.awk $(srcdir)/opth-gen.awk
+ $(AWK) -f $(srcdir)/opt-functions.awk -f $(srcdir)/opth-gen.awk \
+ < $< > $@
+
options.o: options.c options.h opts.h intl.h
dumpvers: dumpvers.c
@@ -3009,6 +3017,7 @@ clean: mostlyclean lang.clean
-rm -f libgcc.a libgcc_eh.a libgcov.a
-rm -f libgcc_s$(SHLIB_EXT) libgcc_s$(SHLIB_EXT).1
-rm -f config.h tconfig.h bconfig.h tm_p.h tm.h
+ -rm -f options.c options.h optionlist
-rm -f cs-*
-rm -rf libgcc
-rm -f doc/*.dvi
diff -Nupd ../../gcc-orig/gcc/configure.ac ./configure.ac
--- ../../gcc-orig/gcc/configure.ac 2004-06-12 01:53:51.000000000 -0400
+++ ./configure.ac 2004-06-16 16:20:57.536236500 -0400
@@ -720,7 +720,7 @@ AC_PROG_MAKE_SET
# Find some useful tools
AC_PROG_AWK
-# We need awk to run opts.sh (to create options.c and options.h).
+# We need awk to create options.c and options.h.
# Bail out if it's missing.
case ${AWK} in
"") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
diff -Nupd ../../gcc-orig/gcc/opt-functions.awk ./opt-functions.awk
--- ../../gcc-orig/gcc/opt-functions.awk 1969-12-31 19:00:00.000000000 -0500
+++ ./opt-functions.awk 2004-06-17 09:57:20.502146000 -0400
@@ -0,0 +1,78 @@
+#!/bin/awk
+
+# Copyright (C) 2003,2004 Free Software Foundation, Inc.
+# Contributed by Kelley Cook, June 2004.
+# Original code from Neil Booth, May 2003.
+#
+# This program is free software; you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by the
+# Free Software Foundation; either version 2, or (at your option) any
+# later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+
+# Some common subroutines for use by opt[ch]-gen.awk.
+
+function switch_flags (flags)
+{
+ flags = " " flags " "
+ result = "0"
+ for (j = 0; j < n_langs; j++) {
+ regex = " " langs[j] " "
+ gsub ( "\\+", "\\+", regex )
+ if (flags ~ regex)
+ result = result " | " macros[j]
+ }
+ if (flags ~ " Common ") result = result " | CL_COMMON"
+ if (flags ~ " Joined ") result = result " | CL_JOINED"
+ if (flags ~ " JoinedOrMissing ") \
+ result = result " | CL_JOINED | CL_MISSING_OK"
+ if (flags ~ " Separate ") result = result " | CL_SEPARATE"
+ if (flags ~ " RejectNegative ") result = result " | CL_REJECT_NEGATIVE"
+ if (flags ~ " UInteger ") result = result " | CL_UINTEGER"
+ if (flags ~ " Undocumented ") result = result " | CL_UNDOCUMENTED"
+ if (flags ~ " Report ") result = result " | CL_REPORT"
+ sub( "^0 \\| ", "", result )
+ return result
+}
+
+function var_args(flags)
+{
+ if (flags !~ "Var\\(")
+ return ""
+ sub(".*Var\\(", "", flags)
+ sub("\\).*", "", flags)
+
+ return flags
+}
+function var_name(flags)
+{
+ s = var_args(flags)
+ if (s == "")
+ return "";
+ sub( ",.*", "", s)
+ return s
+}
+function var_set(flags)
+{
+ s = var_args(flags)
+ if (s !~ ",")
+ return "0, 0"
+ sub( "[^,]*,", "", s)
+ return "1, " s
+}
+function var_ref(flags)
+{
+ name = var_name(flags)
+ if (name == "")
+ return "0"
+ else
+ return "&" name
+}
diff -Nupd ../../gcc-orig/gcc/opt-gather.awk ./opt-gather.awk
--- ../../gcc-orig/gcc/opt-gather.awk 1969-12-31 19:00:00.000000000 -0500
+++ ./opt-gather.awk 2004-06-17 09:49:41.247190500 -0400
@@ -0,0 +1,56 @@
+#!/bin/awk
+
+# Copyright (C) 2003,2004 Free Software Foundation, Inc.
+# Contributed by Kelley Cook, June 2004.
+# Original code from Neil Booth, May 2003.
+#
+# This program is free software; you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by the
+# Free Software Foundation; either version 2, or (at your option) any
+# later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+
+# This Awk script takes a list of *.opt files and combines them into
+# a three-field sorted list suitable for input into opt[ch]-gen.awk.
+#
+# Usage: awk -f opt-gather.awk file1.opt [...] > outputfile
+
+function sort(ARRAY, ELEMENTS)
+{
+ for (i = 2; i <= ELEMENTS; ++i) {
+ for (j = i; ARRAY[j-1] > ARRAY[j]; --j) {
+ temp = ARRAY[j]
+ ARRAY[j] = ARRAY[j-1]
+ ARRAY[j-1] = temp
+ }
+ }
+ return
+}
+
+BEGIN { numrec = 0 }
+
+# Ignore comments and blank lines
+/^[ \t]*(;|$)/ { flag = 0; next }
+/^[^ \t]/ { if (flag == 0) {
+ record[++numrec] = $0
+ flag = 1 }
+ else {
+ record[numrec] = record[numrec] SUBSEP $0
+ }
+}
+
+# Sort it and output it
+END {
+ sort(record,numrec)
+
+ for (i = 1; i <= numrec; i++) {
+ print record[i] }
+}
diff -Nupd ../../gcc-orig/gcc/optc-gen.awk ./optc-gen.awk
--- ../../gcc-orig/gcc/optc-gen.awk 1969-12-31 19:00:00.000000000 -0500
+++ ./optc-gen.awk 2004-06-17 09:56:35.196548000 -0400
@@ -0,0 +1,146 @@
+#!/bin/awk
+
+# Copyright (C) 2003,2004 Free Software Foundation, Inc.
+# Contributed by Kelley Cook, June 2004.
+# Original code from Neil Booth, May 2003.
+#
+# This program is free software; you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by the
+# Free Software Foundation; either version 2, or (at your option) any
+# later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+
+# This Awk script reads in the option records generated from
+# opt-gather.awk, combines the flags of duplicat options and generates a
+# C file.
+#
+# This program uses functions from opt-functions.awk
+#
+# Usage: awk -f opt-functions.awk -f optc-gen.awk \
+# [-v header_name=header.h] < inputfile > options.c
+
+BEGIN {
+ n_opts = 0
+ n_langs = 0
+ quote = "\042"
+ comma = ","
+ FS=SUBSEP
+ # Default the name of header created from opth-gen.awk to options.h
+ if (header_name == "") header_name="options.h"
+}
+
+# Collect the text and flags of each option into an array
+ {
+ if ($1 == "Language") {
+ langs[n_langs] = $2
+ n_langs++;
+ }
+ else {
+ opts[n_opts] = $1
+ flags[n_opts] = $2
+ help[n_opts] = $3
+ n_opts++;
+ }
+ }
+
+# Dump that array of options into a C file.
+END {
+print "/* This file is auto-generated by opts.sh. */"
+print ""
+print "#include <intl.h>"
+print "#include " quote header_name quote
+print "#include " quote "opts.h" quote
+print ""
+
+for (i = 0; i < n_opts; i++) {
+ name = var_name(flags[i]);
+ if (name == "")
+ continue;
+
+ if (flags[i] ~ "VarExists")
+ continue;
+
+ if (flags[i] ~ "Init\\(")
+ {
+ init = flags[i];
+ sub(".*Init\\(","",init);
+ sub("\\).*","",init);
+ init = " = " init;
+ }
+ else
+ init = "";
+
+ printf ("/* Set by -%s.\n %s */\nint %s%s;\n\n",
+ opts[i], help[i], name,init)
+ }
+
+
+print "const char * const lang_names[] =\n{"
+for (i = 0; i < n_langs; i++) {
+ macros[i] = "CL_" langs[i]
+ gsub( "[^A-Za-z0-9_]", "X", macros[i] )
+ s = substr(" ", length (macros[i]))
+ print " " quote langs[i] quote ","
+ }
+
+print " 0\n};\n"
+print "const unsigned int cl_options_count = N_OPTS;\n"
+
+print "const struct cl_option cl_options[] =\n{"
+
+for (i = 0; i < n_opts; i++)
+ back_chain[i] = "N_OPTS";
+
+ for (i = 0; i < n_opts; i++) {
+ # Combine the flags of identical switches. Switches
+ # appear many times if they are handled by many front
+ # ends, for example.
+ while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
+ flags[i + 1] = flags[i] " " flags[i + 1];
+ i++;
+ }
+
+ len = length (opts[i]);
+ enum = "OPT_" opts[i]
+ if (opts[i] == "finline-limit=")
+ enum = enum "eq"
+ gsub ("[^A-Za-z0-9]", "_", enum)
+
+ # If this switch takes joined arguments, back-chain all
+ # subsequent switches to it for which it is a prefix. If
+ # a later switch S is a longer prefix of a switch T, T
+ # will be back-chained to S in a later iteration of this
+ # for() loop, which is what we want.
+ if (flags[i] ~ "Joined") {
+ for (j = i + 1; j < n_opts; j++) {
+ if (substr (opts[j], 1, len) != opts[i])
+ break;
+ back_chain[j] = enum;
+ }
+ }
+
+ s = substr(" ", length (opts[i]))
+ if (i + 1 == n_opts)
+ comma = ""
+
+ if (help[i] == "")
+ hlp = "0"
+ else
+ hlp = "N_(" quote help[i] quote ")";
+
+ printf(" { %c-%s%c,\n %s,\n %s, %u, %s, %s, %s }%s\n",
+ quote, opts[i], quote, hlp, back_chain[i], len,
+ switch_flags(flags[i]),
+ var_ref(flags[i]), var_set(flags[i]), comma)
+}
+
+print "};"
+}
diff -Nupd ../../gcc-orig/gcc/opth-gen.awk ./opth-gen.awk
--- ../../gcc-orig/gcc/opth-gen.awk 1969-12-31 19:00:00.000000000 -0500
+++ ./opth-gen.awk 2004-06-17 09:56:48.676065000 -0400
@@ -0,0 +1,130 @@
+#!/bin/awk
+
+# Copyright (C) 2003,2004 Free Software Foundation, Inc.
+# Contributed by Kelley Cook, June 2004.
+# Original code from Neil Booth, May 2003.
+#
+# This program is free software; you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by the
+# Free Software Foundation; either version 2, or (at your option) any
+# later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+
+# This Awk script reads in the option records generated from
+# opt-gather.awk, combines the flags of duplicate options and generates a
+# C header file.
+#
+# This program uses functions from opt-functions.awk
+# Usage: awk -f opt-functions.awk -f opth-gen.awk < inputfile > options.h
+
+BEGIN {
+ n_opts = 0
+ n_langs = 0
+ quote = "\042"
+ comma = ","
+ FS=SUBSEP
+}
+
+# Collect the text and flags of each option into an array
+ {
+ if ($1 == "Language") {
+ langs[n_langs] = $2
+ n_langs++;
+ }
+ else {
+ opts[n_opts] = $1
+ flags[n_opts] = $2
+ help[n_opts] = $3
+ n_opts++;
+ }
+ }
+
+# Dump out an enumeration into a .h file.
+# Combine the flags of duplicate options.
+END {
+print "/* This file is auto-generated by opts.sh. */"
+print ""
+print "#ifndef OPTIONS_H"
+print "#define OPTIONS_H"
+print ""
+
+for (i = 0; i < n_opts; i++) {
+ name = var_name(flags[i]);
+ if (name == "")
+ continue;
+
+ print "/* Set by -" opts[i] "."
+ print " " help[i] " */"
+ print "extern int " name ";"
+ print ""
+
+ }
+
+
+for (i = 0; i < n_langs; i++) {
+ macros[i] = "CL_" langs[i]
+ gsub( "[^A-Za-z0-9_]", "X", macros[i] )
+ s = substr(" ", length (macros[i]))
+ print "#define " macros[i] s " (1 << " i ")"
+ }
+
+print ""
+print "enum opt_code"
+print "{"
+
+for (i = 0; i < n_opts; i++)
+ back_chain[i] = "N_OPTS";
+
+ for (i = 0; i < n_opts; i++) {
+ # Combine the flags of identical switches. Switches
+ # appear many times if they are handled by many front
+ # ends, for example.
+ while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
+ flags[i + 1] = flags[i] " " flags[i + 1];
+ i++;
+ }
+
+ len = length (opts[i]);
+ enum = "OPT_" opts[i]
+ if (opts[i] == "finline-limit=")
+ enum = enum "eq"
+ gsub ("[^A-Za-z0-9]", "_", enum)
+
+ # If this switch takes joined arguments, back-chain all
+ # subsequent switches to it for which it is a prefix. If
+ # a later switch S is a longer prefix of a switch T, T
+ # will be back-chained to S in a later iteration of this
+ # for() loop, which is what we want.
+ if (flags[i] ~ "Joined") {
+ for (j = i + 1; j < n_opts; j++) {
+ if (substr (opts[j], 1, len) != opts[i])
+ break;
+ back_chain[j] = enum;
+ }
+ }
+
+ s = substr(" ", length (opts[i]))
+ if (i + 1 == n_opts)
+ comma = ""
+
+ if (help[i] == "")
+ hlp = "0"
+ else
+ hlp = "N_(\"" help[i] "\")";
+
+ print " " enum "," s "/* -" opts[i] " */"
+}
+
+print " N_OPTS"
+print "};"
+print ""
+print "#endif /* OPTIONS_H */"
+}
diff -Nupd ../../gcc-orig/gcc/opts.sh ./opts.sh
--- ../../gcc-orig/gcc/opts.sh 2004-06-11 19:41:08.000000000 -0400
+++ ./opts.sh 1969-12-31 19:00:00.000000000 -0500
@@ -1,241 +0,0 @@
-#!/bin/sh
-#
-# Copyright (C) 2003 Free Software Foundation, Inc.
-# Contributed by Neil Booth, May 2003.
-#
-# This program is free software; you can redistribute it and/or modify it
-# under the terms of the GNU General Public License as published by the
-# Free Software Foundation; either version 2, or (at your option) any
-# later version.
-#
-# This program is distributed in the hope that it will be useful,
-# but WITHOUT ANY WARRANTY; without even the implied warranty of
-# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
-# GNU General Public License for more details.
-#
-# You should have received a copy of the GNU General Public License
-# along with this program; if not, write to the Free Software
-# Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
-#
-# Usage: opts.sh moveifchange srcdir outfile.c outfile.h file1.opt [ ...]
-
-# Always operate in the C locale.
-LANG=C
-LANGUAGE=C
-LC_ALL=C
-export LANG LANGUAGE LC_ALL
-
-# Set AWK if environment has not already set it.
-AWK=${AWK-awk}
-
-SORT=sort # Could be /bin/sort or /usr/bin/sort
-
-MOVEIFCHANGE=$1; shift
-C_FILE=$1; shift
-H_FILE=$1; shift
-TMP_C_FILE=tmp-${C_FILE}
-TMP_H_FILE=tmp-${H_FILE}
-
-${AWK} '
- # Ignore comments and blank lines
- /^[ \t]*(;|$)/ { next }
- # Note that RS="" falls foul of gawk 3.1.2 bugs
- /^[^ \t]/ { record = $0
- do { getline tmp;
- if (!(tmp ~ "^[ \t]*(;|$)"))
- record = record "\034" tmp
- } while (tmp != "")
- print record
- }
-' "$@" | ${SORT} | ${AWK} '
- function switch_flags (flags, result)
- {
- flags = " " flags " "
- result = "0"
- for (j = 0; j < n_langs; j++) {
- regex = " " langs[j] " "
- gsub ( "\\+", "\\+", regex )
- if (flags ~ regex)
- result = result " | " macros[j]
- }
- if (flags ~ " Common ") result = result " | CL_COMMON"
- if (flags ~ " Joined ") result = result " | CL_JOINED"
- if (flags ~ " JoinedOrMissing ") \
- result = result " | CL_JOINED | CL_MISSING_OK"
- if (flags ~ " Separate ") result = result " | CL_SEPARATE"
- if (flags ~ " RejectNegative ") result = result " | CL_REJECT_NEGATIVE"
- if (flags ~ " UInteger ") result = result " | CL_UINTEGER"
- if (flags ~ " Undocumented ") result = result " | CL_UNDOCUMENTED"
- if (flags ~ " Report ") result = result " | CL_REPORT"
- sub( "^0 \\| ", "", result )
- return result
- }
- function var_args(flags)
- {
- if (flags !~ "Var\\(")
- return "";
- sub(".*Var\\(", "", flags);
- sub("\\).*", "", flags);
-
- return flags;
- }
- function var_name(flags)
- {
- s = var_args(flags);
- if (s == "")
- return "";
- sub( ",.*", "", s);
- return s;
- }
- function var_set(flags)
- {
- s = var_args(flags);
- if (s !~ ",")
- return "0, 0";
- sub( "[^,]*,", "", s);
- return "1, " s;
- }
- function var_ref(flags)
- {
- name = var_name(flags);
- if (name == "")
- return "0";
- else
- return "&" name;
- }
-
- BEGIN {
- FS = "\034"
- n_opts = 0
- n_langs = 0
- }
-
-# Collect the text and flags of each option into an array
- {
- if ($1 == "Language") {
- langs[n_langs] = $2
- n_langs++;
- } else {
- opts[n_opts] = $1
- flags[n_opts] = $2
- help[n_opts] = $3
- n_opts++;
- }
- }
-
-# Dump out an enumeration into a .h file, and an array of options into a
-# C file. Combine the flags of duplicate options.
- END {
- c_file = "'${TMP_C_FILE}'"
- h_file = "'${TMP_H_FILE}'"
- realh_file = "'${H_FILE}'"
- comma = ","
-
- print "/* This file is auto-generated by opts.sh. */\n" > c_file
- print "#include <intl.h>" >> c_file
- print "#include \"" realh_file "\"" >> c_file
- print "#include \"opts.h\"\n" >> c_file
-
- print "/* This file is auto-generated by opts.sh. */\n" > h_file
- print "#ifndef OPTIONS_H" >> h_file
- print "#define OPTIONS_H\n" >> h_file
-
- for (i = 0; i < n_opts; i++) {
- name = var_name(flags[i]);
- if (name == "")
- continue;
-
- printf ("/* Set by -%s.\n %s */\nextern int %s;\n\n",
- opts[i], help[i], name) >> h_file
-
- if (flags[i] ~ "VarExists")
- continue;
-
- if (flags[i] ~ "Init\\(")
- {
- init = flags[i];
- sub(".*Init\\(","",init);
- sub("\\).*","",init);
- init = " = " init;
- }
- else
- init = "";
-
- printf ("/* Set by -%s.\n %s */\nint %s%s;\n\n",
- opts[i], help[i], name,init) >> c_file
- }
-
-
- print "const char * const lang_names[] =\n{" >> c_file
- for (i = 0; i < n_langs; i++) {
- macros[i] = "CL_" langs[i]
- gsub( "[^A-Za-z0-9_]", "X", macros[i] )
- s = substr(" ", length (macros[i]))
- print "#define " macros[i] s " (1 << " i ")" >> h_file
- print " \"" langs[i] "\"," >> c_file
- }
-
- print " 0\n};\n" >> c_file
- print "const unsigned int cl_options_count = N_OPTS;\n" >> c_file
-
- print "const struct cl_option cl_options[] =\n{" >> c_file
-
- print "\nenum opt_code\n{" >> h_file
-
- for (i = 0; i < n_opts; i++)
- back_chain[i] = "N_OPTS";
-
- for (i = 0; i < n_opts; i++) {
- # Combine the flags of identical switches. Switches
- # appear many times if they are handled by many front
- # ends, for example.
- while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
- flags[i + 1] = flags[i] " " flags[i + 1];
- i++;
- }
-
- len = length (opts[i]);
- enum = "OPT_" opts[i]
- if (opts[i] == "finline-limit=")
- enum = enum "eq"
- gsub ("[^A-Za-z0-9]", "_", enum)
-
- # If this switch takes joined arguments, back-chain all
- # subsequent switches to it for which it is a prefix. If
- # a later switch S is a longer prefix of a switch T, T
- # will be back-chained to S in a later iteration of this
- # for() loop, which is what we want.
- if (flags[i] ~ "Joined") {
- for (j = i + 1; j < n_opts; j++) {
- if (substr (opts[j], 1, len) != opts[i])
- break;
- back_chain[j] = enum;
- }
- }
-
- s = substr(" ", length (opts[i]))
- if (i + 1 == n_opts)
- comma = ""
-
- if (help[i] == "")
- hlp = "0"
- else
- hlp = "N_(\"" help[i] "\")";
-
- printf(" %s,%s/* -%s */\n", enum, s, opts[i]) >> h_file
- printf(" { \"-%s\",\n %s,\n %s, %u, %s, %s, %s }%s\n",
- opts[i], hlp, back_chain[i], len,
- switch_flags(flags[i]),
- var_ref(flags[i]), var_set(flags[i]), comma) >> c_file
- }
-
- print " N_OPTS\n};\n" >> h_file
- print "#endif /* OPTIONS_H */" >> h_file
- print "};" >> c_file
- }
-'
-
-# Copy the newly generated files back to the correct names only if different.
-# This is to prevent a cascade of file rebuilds when not necessary.
-${MOVEIFCHANGE} ${TMP_H_FILE} ${H_FILE}
-${MOVEIFCHANGE} ${TMP_C_FILE} ${C_FILE}